Consultas para a tabela WVDConnectionNetworkData

Artigo
11/05/2024

Para obter informações sobre como usar essas consultas no portal do Azure, consulte o tutorial do Log Analytics. Para a API REST, consulte Consulta.

Tempo médio de ida e volta ao longo do tempo

Exiba um gráfico do tempo de ida e volta (em milissegundos) em todas as conexões em intervalos de 10 minutos nos percentis 10, 50 e 90.

WVDConnectionNetworkData
| summarize percentiles(EstRoundTripTimeInMs, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart

BW médio em todas as conexões

Exibe um gráfico de largura de banda (em quilobytes por segundo) em todas as conexões em intervalos de 10 minutos nos percentis 10, 50 e 90.

WVDConnectionNetworkData
| summarize percentiles(EstAvailableBandwidthKBps, 90, 50, 10) by bin(TimeGenerated,10m)
| render timechart

Top 10 usuários com o maior tempo de ida e volta

Retorna uma lista dos 10 principais usuários com o maior tempo médio de ida e volta (em milissegundos).

WVDConnectionNetworkData
| join kind=leftouter 
(
    WVDConnections
    | where State == "Completed"
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgRTT=round(avg(EstRoundTripTimeInMs)), RTT_P95=percentile(EstRoundTripTimeInMs, 95) by UserName
| top 10 by AvgRTT desc

Top 10 usuários com menor largura de banda

Retorna uma lista dos 10 principais usuários com a menor largura de banda média (em Kilobytes por segundo).

WVDConnectionNetworkData
| join kind=inner 
(
    WVDConnections
    | where State == "Completed"
    | distinct CorrelationId, UserName
) on CorrelationId
| summarize AvgBW=avg(EstAvailableBandwidthKBps), BW_P95=percentile(EstAvailableBandwidthKBps,95) by UserName
| top 10 by AvgBW asc

Resumo do tempo de ida e volta e largura de banda

Retorna os percentis 90 para tempo de ida e volta (em milissegundos) e largura de banda (em quilobytes) para cada conexão, juntamente com detalhes adicionais da conexão.

WVDConnectionNetworkData
| summarize RTTP90=percentile(EstRoundTripTimeInMs,90), BWP90=percentile(EstAvailableBandwidthKBps,90), StartTime=min(TimeGenerated), EndTime=max(TimeGenerated) by CorrelationId
| join kind=inner
(
    WVDConnections
    | where State == "Connected"
    | extend Protocol = iif(UdpUse in ("0", "<>"), "TCP", "UDP")
) on CorrelationId
| project CorrelationId, StartTime, EndTime, UserName, SessionHostName, RTTP90, BWP90, Protocol, ClientOS, ClientType, ClientVersion, ConnectionType, ResourceAlias, SessionHostSxSStackVersion

Partilhar via