Guia de início rápido: criar um cluster de VM do Windows no Azure usando o Terraform

Aplica-se a: ✔️ VMs do Windows

Este artigo mostra como criar um cluster de VM do Windows (contendo três instâncias de VM do Windows) no Azure usando o Terraform.

Pré-requisitos

• Instalar e configurar o Terraform

Implementar o código Terraform

1. Crie um diretório no qual testar o código Terraform de exemplo e torná-lo o diretório atual.

2. Crie um arquivo chamado providers.tf e insira o seguinte código:

   terraform {
     required_version = ">=1.0"
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   provider "azurerm" {
     features {}
   }
   

3. Crie um arquivo chamado main.tf e insira o seguinte código:

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     name     = random_pet.rg_name.id
     location = var.resource_group_location
   }
   
   resource "random_string" "windows_server_vm_hostname" {
     length  = 8
     lower   = true
     upper   = false
     special = false
   }
   
   resource "random_pet" "windows_server_public_ip_dns" {
     prefix = "dns"
   }
   
   resource "random_password" "password" {
     length  = 16
     special = true
     lower   = true
     upper   = true
     numeric = true
   }
   
   # The following module is a Terraform Verified Module. 
   # For more information about Verified Modules, see 
   # https://github.com/azure/terraform-azure-modules/
   module "windows_server" {
     count                         = 3 # Define 3 Windows Server VMs
     source                        = "Azure/compute/azurerm"
     resource_group_name           = azurerm_resource_group.rg.name
     vnet_subnet_id                = module.network.vnet_subnets[0]
     is_windows_image              = true
     vm_hostname                   = "vm-${random_string.windows_server_vm_hostname.result}-${count.index}"
     delete_os_disk_on_termination = true
     admin_password                = random_password.password.result
     vm_os_simple                  = "WindowsServer"
     public_ip_dns                 = ["${random_pet.windows_server_public_ip_dns.id}-${count.index}"]
   }
   
   # The following module is a Terraform Verified Module. 
   # For more information about Verified Modules, see 
   # https://github.com/azure/terraform-azure-modules/
   module "network" {
     source              = "Azure/network/azurerm"
     resource_group_name = azurerm_resource_group.rg.name
     version             = "5.2.0"
     subnet_prefixes     = ["10.0.1.0/24"]
     subnet_names        = ["subnet1"]
     use_for_each        = true
   }
   

4. Crie um arquivo chamado variables.tf e insira o seguinte código:

   variable "resource_group_location" {
     type        = string
     default     = "eastus"
     description = "Location for all resources."
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random value so name is unique in your Azure subscription."
   }
   

5. Crie um arquivo chamado outputs.tf e insira o seguinte código:

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "windows_vm_public_names" {
     value = module.windows_server[*].public_ip_dns_name
   }
   
   output "vm_public_ip_addresses" {
     value = module.windows_server[*].public_ip_address
   }
   
   output "vm_private_ip_addresses" {
     value = module.windows_server[*].network_interface_private_ip
   }
   
   output "vm_hostnames" {
     value = module.windows_server[*].vm_names
   }
   

Inicializar o Terraform

Execute terraform init para inicializar a implantação do Terraform. Este comando baixa o provedor do Azure necessário para gerenciar seus recursos do Azure.

terraform init -upgrade

Pontos principais:

• O -upgrade parâmetro atualiza os plug-ins de provedor necessários para a versão mais recente que está em conformidade com as restrições de versão da configuração.

Criar um plano de execução do Terraform

Execute o plano de terraforma para criar um plano de execução.

terraform plan -out main.tfplan

Pontos principais:

• O terraform plan comando cria um plano de execução, mas não o executa. Em vez disso, ele determina quais ações são necessárias para criar a configuração especificada em seus arquivos de configuração. Esse padrão permite que você verifique se o plano de execução corresponde às suas expectativas antes de fazer quaisquer alterações nos recursos reais.
• O parâmetro opcional -out permite especificar um arquivo de saída para o plano. O uso do -out parâmetro garante que o plano revisado seja exatamente o que é aplicado.

Aplicar um plano de execução Terraform

Execute terraform apply para aplicar o plano de execução à sua infraestrutura de nuvem.

terraform apply main.tfplan

Pontos principais:

• O comando de exemplo terraform apply pressupõe que você executou terraform plan -out main.tfplananteriormente o .
• Se você especificou um nome de arquivo diferente para o -out parâmetro, use esse mesmo nome de arquivo na chamada para terraform apply.
• Se você não usou o -out parâmetro, ligue terraform apply sem nenhum parâmetro.

As informações de custo não são apresentadas durante o processo de criação da máquina virtual para o Terraform como é para o portal do Azure. Se você quiser saber mais sobre como o custo funciona para máquinas virtuais, consulte a página Visão geral da otimização de custos.

Verificar os resultados

Clean up resources (Limpar recursos)

Quando você não precisar mais dos recursos criados via Terraform, execute as seguintes etapas:

1. Execute o plano de terraforma e especifique o destroy sinalizador.

   terraform plan -destroy -out main.destroy.tfplan
   

   Pontos principais:

   • O terraform plan comando cria um plano de execução, mas não o executa. Em vez disso, ele determina quais ações são necessárias para criar a configuração especificada em seus arquivos de configuração. Esse padrão permite que você verifique se o plano de execução corresponde às suas expectativas antes de fazer quaisquer alterações nos recursos reais.
   • O parâmetro opcional -out permite especificar um arquivo de saída para o plano. O uso do -out parâmetro garante que o plano revisado seja exatamente o que é aplicado.

2. Execute terraform apply para aplicar o plano de execução.

   terraform apply main.destroy.tfplan
   

Solucionar problemas do Terraform no Azure

Solucionar problemas comuns ao usar o Terraform no Azure

Próximos passos