Como fazer várias solicitações da Web em paralelo usando Async e Await (Visual Basic)

Artigo
03/13/2024

Em um método assíncrono, as tarefas são iniciadas quando são criadas. O operador Await é aplicado à tarefa no ponto do método em que o processamento não pode continuar até que a tarefa seja concluída. Muitas vezes, uma tarefa é aguardada assim que é criada, como mostra o exemplo a seguir.

Dim result = Await someWebAccessMethodAsync(url)

No entanto, você pode separar a criação da tarefa da espera da tarefa se o programa tiver outro trabalho a realizar que não dependa da conclusão da tarefa.

' The following line creates and starts the task.
Dim myTask = someWebAccessMethodAsync(url)

' While the task is running, you can do other work that does not depend
' on the results of the task.
' . . . . .

' The application of Await suspends the rest of this method until the task is
' complete.
Dim result = Await myTask

Entre iniciar uma tarefa e aguardá-la, você pode iniciar outras tarefas. As tarefas adicionais são executadas implicitamente em paralelo, mas nenhum thread adicional é criado.

O programa a seguir inicia três downloads assíncronos da Web e, em seguida, aguarda-os na ordem em que são chamados. Observe, quando você executa o programa, que as tarefas nem sempre terminam na ordem em que são criadas e aguardadas. Eles começam a ser executados quando são criados, e uma ou mais das tarefas podem ser concluídas antes que o método atinja as expressões de espera.

Nota

Para concluir este projeto, você deve ter o Visual Studio 2012 ou superior e o .NET Framework 4.5 ou superior instalado no seu computador.

Para obter outro exemplo que inicia várias tarefas ao mesmo tempo, consulte Como: Estender o passo a passo assíncrono usando Task.WhenAll (Visual Basic).

Você pode baixar o código para este exemplo de Exemplos de código do desenvolvedor.

Para configurar o projeto

Para configurar um aplicativo WPF, conclua as etapas a seguir. Você pode encontrar instruções detalhadas para estas etapas em Passo a passo: Acessando a Web usando Async e Await (Visual Basic).
- Crie um aplicativo WPF que contenha uma caixa de texto e um botão. Nomeie o botão startButtone nomeie a caixa resultsTextBoxde texto .
- Adicione uma referência para System.Net.Http.
- No arquivo MainWindow.xaml.vb, adicione uma Imports instrução para System.Net.Http.

Para adicionar o código

Na janela de design, MainWindow.xaml, clique duas vezes no botão para criar o startButton_Click manipulador de eventos no MainWindow.xaml.vb.
Copie o código a seguir e cole-o no corpo do startButton_Click MainWindow.xaml.vb.
```
resultsTextBox.Clear()
Await CreateMultipleTasksAsync()
resultsTextBox.Text &= vbCrLf & "Control returned to button1_Click."
```
O código chama um método assíncrono, CreateMultipleTasksAsync, que conduz o aplicativo.

Adicione os seguintes métodos de suporte ao projeto:

ProcessURLAsync usa um HttpClient método para baixar o conteúdo de um site como uma matriz de bytes. O método de suporte, em seguida, ProcessURLAsync exibe e retorna o comprimento da matriz.
DisplayResults exibe o número de bytes na matriz de bytes para cada URL. Esta exibição mostra quando o download de cada tarefa terminou.

Copie os seguintes métodos e cole-os após o manipulador de startButton_Click eventos no MainWindow.xaml.vb.

Private Async Function ProcessURLAsync(url As String, client As HttpClient) As Task(Of Integer)

    Dim byteArray = Await client.GetByteArrayAsync(url)
    DisplayResults(url, byteArray)
    Return byteArray.Length
End Function

Private Sub DisplayResults(url As String, content As Byte())

    ' Display the length of each website. The string format
    ' is designed to be used with a monospaced font, such as
    ' Lucida Console or Global Monospace.
    Dim bytes = content.Length
    ' Strip off the "https://".
    Dim displayURL = url.Replace("https://", "")
    resultsTextBox.Text &= String.Format(vbCrLf & "{0,-58} {1,8}", displayURL, bytes)
End Sub

Finalmente, defina o método CreateMultipleTasksAsync, que executa as seguintes etapas.

O método declara um HttpClient objeto, que você precisa acessar o método GetByteArrayAsync em ProcessURLAsync.
O método cria e inicia três tarefas do tipo Task<TResult>, onde TResult é um inteiro. À medida que cada tarefa termina, DisplayResults exibe o URL da tarefa e o comprimento do conteúdo baixado. Como as tarefas estão sendo executadas de forma assíncrona, a ordem em que os resultados aparecem pode diferir da ordem em que foram declarados.
O método aguarda a conclusão de cada tarefa. Cada Await operador suspende a execução até CreateMultipleTasksAsync que a tarefa esperada seja concluída. O operador também recupera o valor de retorno da chamada para ProcessURLAsync de cada tarefa concluída.
Quando as tarefas foram concluídas e os valores inteiros foram recuperados, o método soma os comprimentos dos sites e exibe o resultado.

Copie o método a seguir e cole-o em sua solução.

Private Async Function CreateMultipleTasksAsync() As Task

    ' Declare an HttpClient object, and increase the buffer size. The
    ' default buffer size is 65,536.
    Dim client As HttpClient =
        New HttpClient() With {.MaxResponseContentBufferSize = 1000000}

    ' Create and start the tasks. As each task finishes, DisplayResults
    ' displays its length.
    Dim download1 As Task(Of Integer) =
        ProcessURLAsync("https://msdn.microsoft.com", client)
    Dim download2 As Task(Of Integer) =
        ProcessURLAsync("https://msdn.microsoft.com/library/hh156528(VS.110).aspx", client)
    Dim download3 As Task(Of Integer) =
        ProcessURLAsync("https://msdn.microsoft.com/library/67w7t67f.aspx", client)

    ' Await each task.
    Dim length1 As Integer = Await download1
    Dim length2 As Integer = Await download2
    Dim length3 As Integer = Await download3

    Dim total As Integer = length1 + length2 + length3

    ' Display the total count for all of the websites.
    resultsTextBox.Text &= String.Format(vbCrLf & vbCrLf &
                                         "Total bytes returned:  {0}" & vbCrLf, total)
End Function

Escolha a tecla F5 para executar o programa e, em seguida, escolha o botão Iniciar .

Execute o programa várias vezes para verificar se as três tarefas nem sempre terminam na mesma ordem e se a ordem em que terminam não é necessariamente a ordem em que são criadas e aguardadas.

Exemplo

O código a seguir contém o exemplo completo.

' Add the following Imports statements, and add a reference for System.Net.Http.
Imports System.Net.Http

Class MainWindow

    Async Sub startButton_Click(sender As Object, e As RoutedEventArgs) Handles startButton.Click
        resultsTextBox.Clear()
        Await CreateMultipleTasksAsync()
        resultsTextBox.Text &= vbCrLf & "Control returned to button1_Click."
    End Sub

    Private Async Function CreateMultipleTasksAsync() As Task

        ' Declare an HttpClient object, and increase the buffer size. The
        ' default buffer size is 65,536.
        Dim client As HttpClient =
            New HttpClient() With {.MaxResponseContentBufferSize = 1000000}

        ' Create and start the tasks. As each task finishes, DisplayResults
        ' displays its length.
        Dim download1 As Task(Of Integer) =
            ProcessURLAsync("https://msdn.microsoft.com", client)
        Dim download2 As Task(Of Integer) =
            ProcessURLAsync("https://msdn.microsoft.com/library/hh156528(VS.110).aspx", client)
        Dim download3 As Task(Of Integer) =
            ProcessURLAsync("https://msdn.microsoft.com/library/67w7t67f.aspx", client)

        ' Await each task.
        Dim length1 As Integer = Await download1
        Dim length2 As Integer = Await download2
        Dim length3 As Integer = Await download3

        Dim total As Integer = length1 + length2 + length3

        ' Display the total count for all of the websites.
        resultsTextBox.Text &= String.Format(vbCrLf & vbCrLf &
                                             "Total bytes returned:  {0}" & vbCrLf, total)
    End Function

    Private Async Function ProcessURLAsync(url As String, client As HttpClient) As Task(Of Integer)

        Dim byteArray = Await client.GetByteArrayAsync(url)
        DisplayResults(url, byteArray)
        Return byteArray.Length
    End Function

    Private Sub DisplayResults(url As String, content As Byte())

        ' Display the length of each website. The string format
        ' is designed to be used with a monospaced font, such as
        ' Lucida Console or Global Monospace.
        Dim bytes = content.Length
        ' Strip off the "https://".
        Dim displayURL = url.Replace("https://", "")
        resultsTextBox.Text &= String.Format(vbCrLf & "{0,-58} {1,8}", displayURL, bytes)
    End Sub
End Class

Partilhar via

Como fazer várias solicitações da Web em paralelo usando Async e Await (Visual Basic)

Para configurar o projeto

Para adicionar o código

Exemplo

Consulte também

Recursos adicionais