Coleções (Visual Basic)

Para muitos aplicativos, você deseja criar e gerenciar grupos de objetos relacionados. Há duas maneiras de agrupar objetos: criando matrizes de objetos e criando coleções de objetos.

As matrizes são mais úteis para criar e trabalhar com um número fixo de objetos fortemente tipados. Para obter informações sobre matrizes, consulte Matrizes.

As coleções fornecem uma maneira mais flexível de trabalhar com grupos de objetos. Ao contrário das matrizes, o grupo de objetos com o qual você trabalha pode crescer e diminuir dinamicamente à medida que as necessidades do aplicativo mudam. Para algumas coleções, você pode atribuir uma chave a qualquer objeto colocado na coleção para que possa recuperar rapidamente o objeto usando a chave.

Uma coleção é uma classe, portanto, você deve declarar uma instância da classe antes de poder adicionar elementos a essa coleção.

Se sua coleção contiver elementos de apenas um tipo de dados, você poderá usar uma das classes no System.Collections.Generic namespace. Uma coleção genérica impõe segurança de tipo para que nenhum outro tipo de dados possa ser adicionado a ela. Quando você recupera um elemento de uma coleção genérica, não é necessário determinar seu tipo de dados ou convertê-lo.

Usando uma coleção simples

Os exemplos nesta seção usam a classe genérica List<T> , que permite que você trabalhe com uma lista fortemente tipada de objetos.

O exemplo a seguir cria uma lista de cadeias de caracteres e, em seguida, itera através das cadeias de caracteres usando um For Each... Próxima declaração.

' Create a list of strings.
Dim salmons As New List(Of String)
salmons.Add("chinook")
salmons.Add("coho")
salmons.Add("pink")
salmons.Add("sockeye")

' Iterate through the list.
For Each salmon As String In salmons
    Console.Write(salmon & " ")
Next
'Output: chinook coho pink sockeye

Se o conteúdo de uma coleção for conhecido antecipadamente, você poderá usar um inicializador de coleção para inicializar a coleção. Para obter mais informações, consulte Inicializadores de coleção.

O exemplo a seguir é o mesmo do exemplo anterior, exceto que um inicializador de coleção é usado para adicionar elementos à coleção.

' Create a list of strings by using a
' collection initializer.
Dim salmons As New List(Of String) From
    {"chinook", "coho", "pink", "sockeye"}

For Each salmon As String In salmons
    Console.Write(salmon & " ")
Next
'Output: chinook coho pink sockeye

Você pode usar um ... Próxima instrução em vez de uma For Each instrução para iterar através de uma coleção. Para fazer isso, acesse os elementos da coleção pela posição do índice. O índice dos elementos começa em 0 e termina na contagem de elementos menos 1.

O exemplo a seguir itera pelos elementos de uma coleção usando For…Next em vez de For Each.

Dim salmons As New List(Of String) From
    {"chinook", "coho", "pink", "sockeye"}

For index = 0 To salmons.Count - 1
    Console.Write(salmons(index) & " ")
Next
'Output: chinook coho pink sockeye

O exemplo a seguir remove um elemento da coleção especificando o objeto a ser removido.

' Create a list of strings by using a
' collection initializer.
Dim salmons As New List(Of String) From
    {"chinook", "coho", "pink", "sockeye"}

' Remove an element in the list by specifying
' the object.
salmons.Remove("coho")

For Each salmon As String In salmons
    Console.Write(salmon & " ")
Next
'Output: chinook pink sockeye

O exemplo a seguir remove elementos de uma lista genérica. Em vez de uma For Each declaração, um ... A próxima instrução que itera em ordem decrescente é usada. Isso ocorre porque o método faz com que os RemoveAt elementos após um elemento removido tenham um valor de índice mais baixo.

Dim numbers As New List(Of Integer) From
    {0, 1, 2, 3, 4, 5, 6, 7, 8, 9}

' Remove odd numbers.
For index As Integer = numbers.Count - 1 To 0 Step -1
    If numbers(index) Mod 2 = 1 Then
        ' Remove the element by specifying
        ' the zero-based index in the list.
        numbers.RemoveAt(index)
    End If
Next

' Iterate through the list.
' A lambda expression is placed in the ForEach method
' of the List(T) object.
numbers.ForEach(
    Sub(number) Console.Write(number & " "))
' Output: 0 2 4 6 8

Para o tipo de elementos no List<T>, você também pode definir sua própria classe. No exemplo a seguir, a Galaxy classe usada pelo List<T> é definida no código.

Private Sub IterateThroughList()
    Dim theGalaxies As New List(Of Galaxy) From
        {
            New Galaxy With {.Name = "Tadpole", .MegaLightYears = 400},
            New Galaxy With {.Name = "Pinwheel", .MegaLightYears = 25},
            New Galaxy With {.Name = "Milky Way", .MegaLightYears = 0},
            New Galaxy With {.Name = "Andromeda", .MegaLightYears = 3}
        }

    For Each theGalaxy In theGalaxies
        With theGalaxy
            Console.WriteLine(.Name & "  " & .MegaLightYears)
        End With
    Next

    ' Output:
    '  Tadpole  400
    '  Pinwheel  25
    '  Milky Way  0
    '  Andromeda  3
End Sub

Public Class Galaxy
    Public Property Name As String
    Public Property MegaLightYears As Integer
End Class

Tipos de Coleções

Muitas coleções comuns são fornecidas pelo .NET Framework. Cada tipo de coleção é projetado para uma finalidade específica.

Algumas das classes de coleção comuns são descritas nesta seção:

• System.Collections.Generic Aulas

• System.Collections.Concurrent Aulas

• System.Collections Aulas

• Classe Visual Basic Collection

System.Collections.Generic Classes

Você pode criar uma coleção genérica usando uma das classes no System.Collections.Generic namespace. Uma coleção genérica é útil quando cada item da coleção tem o mesmo tipo de dados. Uma coleção genérica impõe uma digitação forte, permitindo que apenas o tipo de dados desejado seja adicionado.

A tabela a seguir lista algumas das classes usadas com freqüência do System.Collections.Generic namespace:

Para obter informações adicionais, consulte Tipos de coleção comumente usados, Selecionando uma classe de coleção e System.Collections.Generic.

System.Collections.Concurrent Classes

No .NET Framework 4 ou mais recente, as coleções no System.Collections.Concurrent namespace fornecem operações eficientes e seguras para threads para acessar itens de coleção de vários threads.

As classes no System.Collections.Concurrent namespace devem ser usadas em vez dos tipos correspondentes nos System.Collections.Generic namespaces e System.Collections sempre que vários threads estiverem acessando a coleção simultaneamente. Para obter mais informações, consulte Coleções Thread-Safe e System.Collections.Concurrent.

Algumas classes incluídas no System.Collections.Concurrent namespace são BlockingCollection<T>, ConcurrentDictionary<TKey,TValue>, ConcurrentQueue<T>e ConcurrentStack<T>.

System.Collections Classes

As classes no System.Collections namespace não armazenam elementos como objetos especificamente tipados, mas como objetos do tipo Object.

Sempre que possível, você deve usar as coleções genéricas no System.Collections.Generic namespace ou no System.Collections.Concurrent namespace em vez dos tipos herdados no System.Collections namespace.

A tabela a seguir lista algumas das classes usadas com freqüência no System.Collections namespace:

O System.Collections.Specialized namespace fornece classes de coleção especializadas e fortemente tipadas, como coleções somente de cadeia de caracteres e dicionários híbridos e de lista vinculada.

Classe de coleção do Visual Basic

Você pode usar a classe Visual Basic Collection para acessar um item de coleção usando um índice numérico ou uma String chave. Você pode adicionar itens a um objeto de coleção com ou sem especificar uma chave. Se você adicionar um item sem uma chave, deverá usar seu índice numérico para acessá-lo.

A classe Visual Basic Collection armazena todos os seus elementos como tipo Object, para que você possa adicionar um item de qualquer tipo de dados. Não há nenhuma salvaguarda contra a adição de tipos de dados inadequados.

Quando você usa a classe Visual Basic Collection , o primeiro item em uma coleção tem um índice de 1. Isso difere das classes de coleção do .NET Framework, para as quais o índice inicial é 0.

Sempre que possível, você deve usar as coleções genéricas no System.Collections.Generic namespace ou no System.Collections.Concurrent namespace em vez da classe Visual Basic Collection .

Para obter mais informações, veja Collection.

Implementando uma coleção de pares chave/valor

A Dictionary<TKey,TValue> coleção genérica permite que você acesse elementos em uma coleção usando a chave de cada elemento. Cada adição ao dicionário consiste em um valor e sua chave associada. Recuperar um valor usando sua chave é rápido porque a classe é implementada Dictionary como uma tabela de hash.

O exemplo a seguir cria uma Dictionary coleção e itera pelo dicionário usando uma For Each instrução.

Private Sub IterateThroughDictionary()
    Dim elements As Dictionary(Of String, Element) = BuildDictionary()

    For Each kvp As KeyValuePair(Of String, Element) In elements
        Dim theElement As Element = kvp.Value

        Console.WriteLine("key: " & kvp.Key)
        With theElement
            Console.WriteLine("values: " & .Symbol & " " &
                .Name & " " & .AtomicNumber)
        End With
    Next
End Sub

Private Function BuildDictionary() As Dictionary(Of String, Element)
    Dim elements As New Dictionary(Of String, Element)

    AddToDictionary(elements, "K", "Potassium", 19)
    AddToDictionary(elements, "Ca", "Calcium", 20)
    AddToDictionary(elements, "Sc", "Scandium", 21)
    AddToDictionary(elements, "Ti", "Titanium", 22)

    Return elements
End Function

Private Sub AddToDictionary(ByVal elements As Dictionary(Of String, Element),
ByVal symbol As String, ByVal name As String, ByVal atomicNumber As Integer)
    Dim theElement As New Element

    theElement.Symbol = symbol
    theElement.Name = name
    theElement.AtomicNumber = atomicNumber

    elements.Add(Key:=theElement.Symbol, value:=theElement)
End Sub

Public Class Element
    Public Property Symbol As String
    Public Property Name As String
    Public Property AtomicNumber As Integer
End Class

Para usar um inicializador de coleção para criar a Dictionary coleção, você pode substituir os BuildDictionary métodos e pelo método a AddToDictionary seguir.

Private Function BuildDictionary2() As Dictionary(Of String, Element)
    Return New Dictionary(Of String, Element) From
        {
            {"K", New Element With
                {.Symbol = "K", .Name = "Potassium", .AtomicNumber = 19}},
            {"Ca", New Element With
                {.Symbol = "Ca", .Name = "Calcium", .AtomicNumber = 20}},
            {"Sc", New Element With
                {.Symbol = "Sc", .Name = "Scandium", .AtomicNumber = 21}},
            {"Ti", New Element With
                {.Symbol = "Ti", .Name = "Titanium", .AtomicNumber = 22}}
        }
End Function

O exemplo a seguir usa o método e a ContainsKeyItem[] propriedade de Dictionary para localizar rapidamente um item por chave. A Item propriedade permite que você acesse um item na elements coleção usando o elements(symbol) código no Visual Basic.

Private Sub FindInDictionary(ByVal symbol As String)
    Dim elements As Dictionary(Of String, Element) = BuildDictionary()

    If elements.ContainsKey(symbol) = False Then
        Console.WriteLine(symbol & " not found")
    Else
        Dim theElement = elements(symbol)
        Console.WriteLine("found: " & theElement.Name)
    End If
End Sub

O exemplo a seguir usa o TryGetValue método localizar rapidamente um item por chave.

Private Sub FindInDictionary2(ByVal symbol As String)
    Dim elements As Dictionary(Of String, Element) = BuildDictionary()

    Dim theElement As Element = Nothing
    If elements.TryGetValue(symbol, theElement) = False Then
        Console.WriteLine(symbol & " not found")
    Else
        Console.WriteLine("found: " & theElement.Name)
    End If
End Sub

Usando o LINQ para acessar uma coleção

LINQ (Language-Integrated Query) pode ser usado para acessar coleções. As consultas LINQ fornecem recursos de filtragem, ordenação e agrupamento. Para obter mais informações, consulte Introdução ao LINQ no Visual Basic.

O exemplo a seguir executa uma consulta LINQ em relação a um arquivo List. A consulta LINQ retorna uma coleção diferente que contém os resultados.

Private Sub ShowLINQ()
    Dim elements As List(Of Element) = BuildList()

    ' LINQ Query.
    Dim subset = From theElement In elements
                  Where theElement.AtomicNumber < 22
                  Order By theElement.Name

    For Each theElement In subset
        Console.WriteLine(theElement.Name & " " & theElement.AtomicNumber)
    Next

    ' Output:
    '  Calcium 20
    '  Potassium 19
    '  Scandium 21
End Sub

Private Function BuildList() As List(Of Element)
    Return New List(Of Element) From
        {
            {New Element With
                {.Symbol = "K", .Name = "Potassium", .AtomicNumber = 19}},
            {New Element With
                {.Symbol = "Ca", .Name = "Calcium", .AtomicNumber = 20}},
            {New Element With
                {.Symbol = "Sc", .Name = "Scandium", .AtomicNumber = 21}},
            {New Element With
                {.Symbol = "Ti", .Name = "Titanium", .AtomicNumber = 22}}
        }
End Function

Public Class Element
    Public Property Symbol As String
    Public Property Name As String
    Public Property AtomicNumber As Integer
End Class

Classificando uma coleção

O exemplo a seguir ilustra um procedimento para classificar uma coleção. O exemplo classifica instâncias da Car classe que são armazenadas em um List<T>arquivo . A Car classe implementa a IComparable<T> interface, que requer que o CompareTo método seja implementado.

Cada chamada para o CompareTo método faz uma única comparação que é usada para classificação. O código escrito pelo usuário no CompareTo método retorna um valor para cada comparação do objeto atual com outro objeto. O valor retornado é menor que zero se o objeto atual for menor que o outro objeto, maior que zero se o objeto atual for maior que o outro objeto e zero se eles forem iguais. Isso permite que você defina no código os critérios para maior que, menor que e igual.

ListCars No método, a cars.Sort() instrução classifica a lista. Essa chamada para o Sort método do faz com que o List<T>CompareTo método seja chamado automaticamente para os Car objetos no List.

Public Sub ListCars()

    ' Create some new cars.
    Dim cars As New List(Of Car) From
    {
        New Car With {.Name = "car1", .Color = "blue", .Speed = 20},
        New Car With {.Name = "car2", .Color = "red", .Speed = 50},
        New Car With {.Name = "car3", .Color = "green", .Speed = 10},
        New Car With {.Name = "car4", .Color = "blue", .Speed = 50},
        New Car With {.Name = "car5", .Color = "blue", .Speed = 30},
        New Car With {.Name = "car6", .Color = "red", .Speed = 60},
        New Car With {.Name = "car7", .Color = "green", .Speed = 50}
    }

    ' Sort the cars by color alphabetically, and then by speed
    ' in descending order.
    cars.Sort()

    ' View all of the cars.
    For Each thisCar As Car In cars
        Console.Write(thisCar.Color.PadRight(5) & " ")
        Console.Write(thisCar.Speed.ToString & " ")
        Console.Write(thisCar.Name)
        Console.WriteLine()
    Next

    ' Output:
    '  blue  50 car4
    '  blue  30 car5
    '  blue  20 car1
    '  green 50 car7
    '  green 10 car3
    '  red   60 car6
    '  red   50 car2
End Sub

Public Class Car
    Implements IComparable(Of Car)

    Public Property Name As String
    Public Property Speed As Integer
    Public Property Color As String

    Public Function CompareTo(ByVal other As Car) As Integer _
        Implements System.IComparable(Of Car).CompareTo
        ' A call to this method makes a single comparison that is
        ' used for sorting.

        ' Determine the relative order of the objects being compared.
        ' Sort by color alphabetically, and then by speed in
        ' descending order.

        ' Compare the colors.
        Dim compare As Integer
        compare = String.Compare(Me.Color, other.Color, True)

        ' If the colors are the same, compare the speeds.
        If compare = 0 Then
            compare = Me.Speed.CompareTo(other.Speed)

            ' Use descending order for speed.
            compare = -compare
        End If

        Return compare
    End Function
End Class

Definindo uma coleção personalizada

Você pode definir uma coleção implementando a IEnumerable<T> interface ou IEnumerable . Para obter informações adicionais, consulte Enumerando uma coleção.

Embora você possa definir uma coleção personalizada, geralmente é melhor usar as coleções incluídas no .NET Framework, que são descritas em Tipos de coleções anteriormente neste tópico.

O exemplo a seguir define uma classe de coleção personalizada chamada AllColors. Esta classe implementa a IEnumerable interface, que requer que o GetEnumerator método seja implementado.

O GetEnumerator método retorna uma instância da ColorEnumerator classe. ColorEnumeratorImplementa a IEnumerator interface, que requer que a propriedadeMoveNext, o método e Reset o Current método sejam implementados.

Public Sub ListColors()
    Dim colors As New AllColors()

    For Each theColor As Color In colors
        Console.Write(theColor.Name & " ")
    Next
    Console.WriteLine()
    ' Output: red blue green
End Sub

' Collection class.
Public Class AllColors
    Implements System.Collections.IEnumerable

    Private _colors() As Color =
    {
        New Color With {.Name = "red"},
        New Color With {.Name = "blue"},
        New Color With {.Name = "green"}
    }

    Public Function GetEnumerator() As System.Collections.IEnumerator _
        Implements System.Collections.IEnumerable.GetEnumerator

        Return New ColorEnumerator(_colors)

        ' Instead of creating a custom enumerator, you could
        ' use the GetEnumerator of the array.
        'Return _colors.GetEnumerator
    End Function

    ' Custom enumerator.
    Private Class ColorEnumerator
        Implements System.Collections.IEnumerator

        Private _colors() As Color
        Private _position As Integer = -1

        Public Sub New(ByVal colors() As Color)
            _colors = colors
        End Sub

        Public ReadOnly Property Current() As Object _
            Implements System.Collections.IEnumerator.Current
            Get
                Return _colors(_position)
            End Get
        End Property

        Public Function MoveNext() As Boolean _
            Implements System.Collections.IEnumerator.MoveNext
            _position += 1
            Return (_position < _colors.Length)
        End Function

        Public Sub Reset() Implements System.Collections.IEnumerator.Reset
            _position = -1
        End Sub
    End Class
End Class

' Element class.
Public Class Color
    Public Property Name As String
End Class

Iteradores

Um iterador é usado para executar uma iteração personalizada sobre uma coleção. Um iterador pode ser um método ou um get acessador. Um iterador usa uma instrução Yield para retornar cada elemento da coleção, um de cada vez.

Você chama um iterador usando um For Each... Próxima declaração. Cada iteração do For Each loop chama o iterador. Quando uma Yield instrução é alcançada no iterador, uma expressão é retornada e o local atual no código é mantido. A execução é reiniciada a partir desse local na próxima vez que o iterador for chamado.

Para obter mais informações, consulte Iteradores (Visual Basic).

O exemplo a seguir usa um método iterator. O método iterator tem uma Yield instrução que está dentro de um For... Próximo ciclo. ListEvenNumbers No método, cada iteração do For Each corpo da instrução cria uma chamada para o método iterator, que prossegue para a próxima Yield instrução.

Public Sub ListEvenNumbers()
    For Each number As Integer In EvenSequence(5, 18)
        Console.Write(number & " ")
    Next
    Console.WriteLine()
    ' Output: 6 8 10 12 14 16 18
End Sub

Private Iterator Function EvenSequence(
ByVal firstNumber As Integer, ByVal lastNumber As Integer) _
As IEnumerable(Of Integer)

' Yield even numbers in the range.
    For number = firstNumber To lastNumber
        If number Mod 2 = 0 Then
            Yield number
        End If
    Next
End Function

Consulte também

• Inicializadores de coleção
• Conceitos de programação (Visual Basic)
• Declaração Estrita de Opção
• LINQ to Objects (Visual Basic)
• LINQ paralelo (PLINQ)
• Coleções e Estruturas de Dados
• Selecionando uma classe de coleção
• Comparações e classificações dentro de coleções
• Quando usar coleções genéricas