Partilhar via

geo_azimuth()

  • Artigo

Aplica-se a: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Calcula o ângulo no sentido horário em radianos entre a linha do ponto1 ao norte verdadeiro e uma linha do ponto1 ao ponto2 na Terra.

Sintaxe

geo_azimuth(,p1_longitude p1_latitude,p2_longitude p2_latitude,)

Saiba mais sobre as convenções de sintaxe.

Parâmetros

Nome Digitar Obrigatória Descrição
p1_longitude real ✔️ O valor da longitude em graus da primeira coordenada geoespacial. Um valor válido está no intervalo [-180, +180].
p1_latitude real ✔️ O valor da latitude em graus da primeira coordenada geoespacial. Um valor válido está no intervalo [-90, +90].
p2_longitude real ✔️ O valor de longitude em graus da segunda coordenada geoespacial. Um valor válido está no intervalo [-180, +180].
p2_latitude real ✔️ O valor da latitude em graus da segunda coordenada geoespacial. Um valor válido está no intervalo [-90, +90].

Devoluções

Um ângulo em radianos entre a reta do ponto p1 ao norte verdadeiro e a linha [p1, p2]. O ângulo é medido no sentido horário.

Observação

  • As coordenadas geoespaciais são interpretadas como representadas pelo sistema de referência de coordenadas WGS-84 .
  • O dado geodésico usado para medir a distância na Terra é uma esfera. As arestas de linha são geodésicas na esfera.
  • Azimute 0 pontos ao norte. Azimute Pi / 2 aponta para o leste. Azimute Pi aponta para o sul. Azimute 3Pi / 2 pontos a oeste.
  • Se as coordenadas forem inválidas, a consulta produzirá um resultado nulo.
  • Se point1 for igual a point2, a consulta produzirá um resultado nulo.
  • Se point1 e point2 forem antípodas, a consulta produzirá um resultado nulo.

Exemplos

O exemplo a seguir calcula o azimute em radianos.

print azimuth_in_radians = geo_azimuth(5, 10, 10, -40)

Saída

azimuth_in_radians
3.05459939796449

O exemplo a seguir calcula o azimute em graus.

let azimuth_in_radians = geo_azimuth(5, 10, 10, -40);
print azimuth_in_degrees = degrees(azimuth_in_radians);

Saída

azimuth_in_degrees
175.015653606568

O exemplo a seguir considera um caminhão que emite telemetria de sua localização enquanto viaja e procura sua direção de deslocamento.

let get_direction = (azimuth:real)
{
    let pi = pi();
    iff(azimuth < pi/2,   "North-East",
    iff(azimuth < pi,     "South-East",
    iff(azimuth < 3*pi/2, "South-West",
                          "North-West")));
};
datatable(timestamp:datetime, lng:real, lat:real)
[
    datetime(2024-01-01T00:01:53.048506Z), -115.4036607693417, 36.40551631046261,
    datetime(2024-01-01T00:02:53.048506Z), -115.3256807623232, 36.34102142760111,
    datetime(2024-01-01T00:03:53.048506Z), -115.2732290602112, 36.28458914829917,
    datetime(2024-01-01T00:04:53.048506Z), -115.2513186233914, 36.27622394664352,
    datetime(2024-01-01T00:05:53.048506Z), -115.2352055633212, 36.27545547038515,
    datetime(2024-01-01T00:06:53.048506Z), -115.1894341934856, 36.28266934431671,
    datetime(2024-01-01T00:07:53.048506Z), -115.1054318118468, 36.28957085435267,
    datetime(2024-01-01T00:08:53.048506Z), -115.0648614339413, 36.28110743285072,
    datetime(2024-01-01T00:09:53.048506Z), -114.9858032867736, 36.29780696509714,
    datetime(2024-01-01T00:10:53.048506Z), -114.9016966527561, 36.36556196813566,
]
| sort by timestamp asc 
| extend prev_lng = prev(lng), prev_lat = prev(lat)
| where isnotnull(prev_lng) and isnotnull(prev_lat)
| extend direction = get_direction(geo_azimuth(prev_lng, prev_lat, lng, lat))
| project direction, lng, lat
| render scatterchart with (kind = map)

Saída

Azimute entre dois locais consecutivos.

O exemplo a seguir retorna true porque o primeiro ponto é igual ao segundo ponto.

print is_null = isnull(geo_azimuth(5, 10, 5, 10))

Saída

is_null
true