Instrução LET

Aplica-se a: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Uma let instrução é usada para definir um nome de variável igual a uma expressão ou função ou para criar exibições.

As instruções let são úteis para:

• Dividir uma expressão complexa em várias partes, cada uma representada por uma variável.
• Definir constantes fora do corpo da consulta para facilitar a leitura.
• Definir uma variável uma vez e usá-la várias vezes em uma consulta.

Se a variável anteriormente representasse outro valor, por exemplo, em instruções aninhadas, a instrução let mais interna se aplicará.

Para otimizar vários usos da instrução let em uma única consulta, confira Otimizar consultas que usam expressões nomeadas.

Sintaxe: expressões escalares ou tabulares

letNome = Expressão

Saiba mais sobre as convenções de sintaxe.

Parâmetros

Sintaxe: exibição ou função

letNome = [view] ([ Parâmetros ] ) { FunctionBody }

Saiba mais sobre as convenções de sintaxe.

Parâmetros

Exemplos

Definir valores escalares

O exemplo a seguir usa uma instrução de expressão escalar.

let n = 10;  // number
let place = "Dallas";  // string
let cutoff = ago(62d); // datetime 
Events 
| where timestamp > cutoff 
    and city == place 
| take n

O exemplo a seguir associa o nome some number usando a notação ['name'] e, em seguida, o usa em uma instrução de expressão tabular.

let ['some number'] = 20;
range y from 0 to ['some number'] step 5

Criar uma função definida pelo usuário com cálculo escalar

Esse exemplo usa a instrução let com argumentos para o cálculo escalar. A consulta define a função MultiplyByN para multiplicar dois números.

let MultiplyByN = (val:long, n:long) { val * n };
range x from 1 to 5 step 1 
| extend result = MultiplyByN(x, 5)

Saída

Criar uma função definida pelo usuário que corta a entrada

O exemplo a seguir remove os itens à esquerda e à direita da entrada.

let TrimOnes = (s:string) { trim("1", s) };
range x from 10 to 15 step 1 
| extend result = TrimOnes(tostring(x))

Saída

Usar múltiplas instruções let

Este exemplo define duas instruções let nas quais uma instrução (foo2) usa outra (foo1).

let foo1 = (_start:long, _end:long, _step:long) { range x from _start to _end step _step};
let foo2 = (_step:long) { foo1(1, 100, _step)};
foo2(2) | count

Saída

Criar uma exibição ou tabela virtual

Este exemplo mostra como usar uma instrução let para criar uma viewou tabela virtual.

let Range10 = view () { range MyColumn from 1 to 10 step 1 };
let Range20 = view () { range MyColumn from 1 to 20 step 1 };
search MyColumn == 5

Saída

Usar uma função materialize

A função materialize() permite que você armazene em cache os resultados da subconsulta durante o tempo da execução da consulta. Quando você usa a função materialize(), os dados são armazenados em cache e qualquer invocação subsequente do resultado usa dados armazenados em cache.

let totalPagesPerDay = PageViews
| summarize by Page, Day = startofday(Timestamp)
| summarize count() by Day;
let materializedScope = PageViews
| summarize by Page, Day = startofday(Timestamp);
let cachedResult = materialize(materializedScope);
cachedResult
| project Page, Day1 = Day
| join kind = inner
(
    cachedResult
    | project Page, Day2 = Day
)
on Page
| where Day2 > Day1
| summarize count() by Day1, Day2
| join kind = inner
    totalPagesPerDay
on $left.Day1 == $right.Day
| project Day1, Day2, Percentage = count_*100.0/count_1

Saída

Usar instruções let aninhadas

Instruções let aninhadas são permitidas, inclusive dentro de uma expressão de função definida pelo usuário. Os argumentos e as instruções let se aplicam ao escopo atual e interno do corpo da função.

let start_time = ago(5h); 
let end_time = start_time + 2h; 
T | where Time > start_time and Time < end_time | ...

Argumento tabular com esquema

O exemplo a seguir especifica que o parâmetro tabela T precisa ter uma coluna State do tipo string. A tabela T talvez pode incluir outras colunas, mas elas não podem ser referenciadas na função StateState porque não são declaradas.

let StateState=(T: (State: string)) { T | extend s_s=strcat(State, State) };
StormEvents
| invoke StateState()
| project State, s_s

Saída

Argumento tabular com curinga

O parâmetro de tabela T pode ter qualquer esquema, e a função CountRecordsInTable funcionará.

let CountRecordsInTable=(T: (*)) { T | count };
StormEvents | invoke CountRecordsInTable()

Saída