Criar um rastreamento (Transact-SQL)

Artigo
11/24/2024

Aplica-se: SQL Server

Este tópico descreve como usar procedimentos armazenados para criar um rastreamento.

Para criar um rastreamento

Execute sp_trace_create com os parâmetros exigidos para criar um novo rastreamento. O novo rastreamento estará em um estado parado (status é 0).
Execute sp_trace_setevent com os parâmetros exigidos para selecionar os eventos e as colunas para rastrear.
Opcionalmente, execute sp_trace_setfilter para definir qualquer ou uma combinação de filtros.

sp_trace_setevent e sp_trace_setfilter só podem ser executados em rastreamentos existentes que estejam parados.

Importante

Ao contrário dos procedimentos armazenados comuns, os parâmetros de todos os procedimentos armazenados do SQL Server Profiler (sp_trace_xx) são estritamente tipados e não são compatíveis com a conversão automática de tipo de dados. Se esses parâmetros não forem chamados pelos tipos de dados com parâmetros de entrada corretos, como especificado na descrição do argumento, o procedimento armazenado retornará um erro.

Exemplos

O código a seguir demonstra a criação de um rastreamento usando Transact-SQL. Ele está em três partes: criação do rastreamento, população do arquivo de rastreamento e interrupção do rastreamento. Personalize o rastreamento adicionando os eventos que deseja rastrear. Para obter a lista de eventos e colunas, veja sp_trace_setevent (Transact-SQL).

R. Criar um rastreamento

O seguinte código cria um rastreamento, acrescenta eventos ao rastreamento e depois inicia o rastreamento:

DECLARE @RC int, @TraceID int, @on BIT  
EXEC @rc = sp_trace_create @TraceID output, 0, N'C:\SampleTrace'  
  
-- Select the return code to see if the trace creation was successful.  
SELECT RC = @RC, TraceID = @TraceID  
  
-- Set the events and data columns you need to capture.  
SELECT @on = 1  
  
-- 10 is RPC:Completed event. 1 is TextData column.   
EXEC sp_trace_setevent @TraceID, 10, 1, @on   
-- 13 is SQL:BatchStarting, 11 is LoginName  
EXEC sp_trace_setevent @TraceID, 13, 11, @on   
-- 13 is SQL:BatchStarting, 14 is StartTime  
EXEC sp_trace_setevent @TraceID, 13, 14, @on   
-- 12 is SQL:BatchCompleted, 15 is EndTime  
EXEC sp_trace_setevent @TraceID, 12, 15, @on   
-- 13 is SQL:BatchStarting, 1 is TextData  
EXEC sp_trace_setevent @TraceID, 13, 1, @on   
  
-- Set any filter. Not provided in this example  
--EXEC sp_trace_setfilter 1, 10, 0, 6, N'%Profiler%'  
  
-- Start Trace (status 1 = start)  
EXEC @RC = sp_trace_setstatus @TraceID, 1  
GO

B. Popular o arquivo de rastreamento

Agora que o rastreamento foi criado e iniciado, execute o código a seguir para popular o rastreamento com atividade.

SELECT * FROM master.sys.databases  
GO  
SELECT * FROM ::fn_trace_getinfo(default)  
GO

C. Parar o rastreamento

O rastreamento pode ser interrompido e reiniciado a qualquer momento. Neste exemplo, execute o código a seguir para interromper o rastreamento, fechar o rastreamento e excluir sua definição.

DECLARE @TraceID int  
-- Populate a variable with the trace_id of the current trace  
SELECT  @TraceID = TraceID FROM ::fn_trace_getinfo(default) WHERE VALUE = N'C:\SampleTrace.trc'  
  
-- First stop the trace.   
EXEC sp_trace_setstatus @TraceID, 0  
  
-- Close and then delete its definition from SQL Server.   
EXEC sp_trace_setstatus @TraceID, 2

D. Examinar o arquivo de rastreamento

Para examinar o arquivo de rastreamento, abra o arquivo SampleTrace.trc usando o SQL Server Profiler.

Confira também

Procedimentos armazenados do SQL Server Profiler (Transact-SQL)
sp_trace_create (Transact-SQL)
sp_trace_setevent (Transact-SQL)
sp_trace_setfilter (Transact-SQL)

Partilhar via