sp_addlogreader_agent (Transact-SQL)

Aplica-se a: SQL Server Instância Gerenciada de SQL do Azure

Adiciona um Log Leitor Agent a um determinado banco de dados. Esse procedimento armazenado é executado no Publicador, no banco de dados publicador.

Convenções de sintaxe de Transact-SQL

Sintaxe

sp_addlogreader_agent
    [ [ @job_login = ] N'job_login' ]
    [ , [ @job_password = ] N'job_password' ]
    [ , [ @job_name = ] N'job_name' ]
    [ , [ @publisher_security_mode = ] publisher_security_mode ]
    [ , [ @publisher_login = ] N'publisher_login' ]
    [ , [ @publisher_password = ] N'publisher_password' ]
    [ , [ @publisher = ] N'publisher' ]
[ ; ]

Argumentos

@job_login [ = ] N'job_login'

O logon da conta do Windows sob a qual o agente é executado. @job_login é nvarchar(257), com um padrão de NULL. Essa conta do Windows sempre é usada para conexões de agente com o Distribuidor. Na Instância Gerenciada de SQL do Azure, use uma conta do SQL Server.

@job_password [ = ] N'job_password'

A senha da conta do Windows sob a qual o agente é executado. @job_password é sysname, com um padrão de NULL.

@job_name [ = ] N'job_name'

O nome de um trabalho de agente existente. @job_name é sysname, com um padrão de NULL. Esse parâmetro só é especificado quando o agente é iniciado usando um trabalho existente em vez de um trabalho recém-criado (o padrão).

@publisher_security_mode [ = ] publisher_security_mode

O modo de segurança usado pelo agente ao se conectar ao Publicador. @publisher_security_mode é smallint, com um padrão de 1. Um valor de 0 deve ser especificado para Publicadores não-SQL Server. Os seguintes valores definem o modo de segurança:

• 0 especifica a autenticação do SQL Server.
• 1 especifica a autenticação do Windows.
• 2 especifica a autenticação de senha do Microsoft Entra a partir do SQL Server 2022 (16.x) 6.
• 3 especifica a autenticação integrada do Microsoft Entra a partir do SQL Server 2022 (16.x) 6.
• 4 especifica a autenticação de token do Microsoft Entra a partir do SQL Server 2022 (16.x) 6.

@publisher_login [ = ] N'publisher_login'

O logon usado na conexão com o Publicador. @publisher_login é sysname, com um padrão de NULL. @publisher_login deve ser especificado quando @publisher_security_mode é 0. Se @publisher_login for NULL e @publisher_security_mode for 1, a conta do Windows especificada em @job_login será usada ao se conectar ao Publicador.

@publisher_password [ = ] N'publisher_password'

A senha usada ao se conectar ao Publicador. @publisher_password é sysname, com um padrão de NULL.

@publisher [ = ] N'editor'

O nome do Publicador que não é do SQL Server. @publisher é sysname, com um padrão de NULL.

Valores do código de retorno

0 (sucesso) ou 1 (falha).

Comentários

sp_addlogreader_agent é usado na replicação transacional.

Você deve executar sp_addlogreader_agent para adicionar um agente Leitor de Log se tiver atualizado um banco de dados que estava habilitado para replicação para esta versão do SQL Server antes da criação de uma publicação que usava o banco de dados.

Permissões

Somente membros da função de servidor fixa sysadmin ou da função de banco de dados fixa db_owner podem executar sp_addlogreader_agento .

Exemplos

-- To avoid storing the login and password in the script file, the values 
-- are passed into SQLCMD as scripting variables. For information about 
-- how to use scripting variables on the command line and in SQL Server
-- Management Studio, see the "Executing Replication Scripts" section in
-- the topic "Programming Replication Using System Stored Procedures".

DECLARE @publicationDB AS sysname;
DECLARE @publication AS sysname;
DECLARE @login AS sysname;
DECLARE @password AS sysname;
SET @publicationDB = N'AdventureWorks'; 
SET @publication = N'AdvWorksProductTran'; 
-- Windows account used to run the Log Reader and Snapshot Agents.
SET @login = $(Login); 
-- This should be passed at runtime.
SET @password = $(Password); 

-- Enable transactional or snapshot replication on the publication database.
EXEC sp_replicationdboption 
    @dbname=@publicationDB, 
    @optname=N'publish',
    @value = N'true';

-- Execute sp_addlogreader_agent to create the agent job. 
EXEC sp_addlogreader_agent 
    @job_login = @login, 
    @job_password = @password,
    -- Explicitly specify the use of Windows Integrated Authentication (default) 
    -- when connecting to the Publisher.
    @publisher_security_mode = 1;

-- Create a new transactional publication with the required properties. 
EXEC sp_addpublication 
    @publication = @publication, 
    @status = N'active',
    @allow_push = N'true',
    @allow_pull = N'true',
    @independent_agent = N'true';

-- Create a new snapshot job for the publication, using a default schedule.
EXEC sp_addpublication_snapshot 
    @publication = @publication, 
    @job_login = @login, 
    @job_password = @password,
    -- Explicitly specify the use of Windows Integrated Authentication (default) 
    -- when connecting to the Publisher.
    @publisher_security_mode = 1;
GO

Conteúdo relacionado

• Criar uma publicação
• sp_addpublication (Transact-SQL)
• sp_changelogreader_agent (Transact-SQL)
• Procedimentos armazenados de replicação (Transact-SQL)