Método Session.Enumerate

Enumera uma tabela, uma coleta de dados ou um recurso de log. Para criar uma consulta, inclua um parâmetro de filtro e um parâmetro de dialeto em uma enumeração. Você também pode usar um objeto ResourceLocator para criar consultas. Para obter mais informações, consulte Enumerando ou listando todas as instâncias de um recurso.

Sintaxe

Session.Enumerate( _
  ByVal resourceUri, _
  [ ByVal filter ], _
  [ ByVal dialect ], _
  [ ByVal flags ] _
)

Parâmetros

resourceUri [in]

O identificador do recurso a ser recuperado.

Esse parâmetro pode conter um dos seguintes:

• O URI do recurso.

  strResourceUri = "http://schemas.microsoft.com/" _ 
      & "wbem/wsman/1/wmi/root/cimv2/Win32_Service"
  

• Um objeto ResourceLocator .

• Uma referência de ponto de extremidade de endereçamento WS , conforme descrito no padrão de protocolo WS-Management. Para obter mais informações sobre a especificação pública do protocolo WS-Management, consulte Página de índice de especificações de gerenciamento.

filtro [in, opcional]

Um filtro que define quais itens no recurso são retornados pela enumeração . Quando o recurso é enumerado, somente os itens que correspondem aos critérios de filtro são retornados. Incluir um parâmetro de filtro e um parâmetro dialeto em uma enumeração converte a enumeração em uma consulta. Para obter um exemplo, consulte Consultando instâncias específicas de um recurso.

Se você tiver um objeto ResourceLocator para o parâmetro resourceURI , esse parâmetro não deverá ser usado.

dialeto [in, opcional]

O idioma usado pelo filtro. O WQL, um subconjunto de SQL usado pelo WMI, é a única linguagem com suporte.

Se você tiver um objeto ResourceLocator para o parâmetro resourceURI , esse parâmetro não deverá ser usado.

sinalizadores [in, opcional]

Um parâmetro que deve conter um sinalizador na enumeração __WSManEnumFlags . Para obter mais informações, consulte Constantes de enumeração.

Valor retornado

Um objeto Enumerador que contém os resultados da enumeração.

Comentários

Para obter mais informações sobre como limitar chamadas de rede durante uma enumeração, consulte a propriedade BatchItems .

Lembre-se de que se os sinalizadores incluírem as Constantes de EnumeraçãoWSManFlagHierarchyDeepBasePropsOnly ou WSManFlagHierarchyShallow , o serviço de Gerenciamento Remoto do Windows retornará o código de erro ERROR_WSMAN_POLYMORPHISM_MODE_UNSUPPORTED.

Se um filtro for especificado, ele deverá ser um documento válido em relação ao esquema do recurso. O parâmetro dialeto é opcional. No entanto, se a cadeia de caracteres de filtro começar com <, mas não for um fragmento XML, inclua o parâmetro dialeto ou defina o sinalizador WSManFlagNonXmlText no parâmetro flags . Para obter mais informações, consulte Constantes de enumeração.

O método C++ correspondente é IWSManSession::Enumerate.

Exemplos

O exemplo de código VBScript a seguir enumera as instâncias de Win32_LogicalDisk em um computador remoto especificado pelo nome de domínio totalmente qualificado (servername.domain.com). Lembre-se de que liberar o objeto de enumeração limpa as solicitações de enumeração pendentes. A sub-rotina DisplayOutput usa o arquivo de transformação XML da ferramenta de linha de comando winrm (WsmTxt.xsl) para gerar os dados em um formulário tabular.

Const RemoteComputer = "servername.domain.com"
Set objWsman = CreateObject( "WSMan.Automation" )

Set objSession = objWsman.CreateSession( "https://" & REMOTECOMPUTER )

strResource = "http://schemas.microsoft.com/wbem/wsman/1/" &_
              "wmi/root/cimv2/Win32_LogicalDisk"

Set objResultSet = objSession.Enumerate( strResource )

While Not objResultSet.AtEndOfStream
 
 DisplayOutput( objResultSet.ReadItem ) 

Wend

'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************
Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" ) 
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile ) 
End Sub

Requisitos

Confira também

Session

Consultando instâncias específicas de um recurso

BatchItems

Resourcelocator