Método Session.Invoke

Invoca um método e retorna resultados da chamada de método.

Sintaxe

Session.Invoke( _
  ByVal actionUri, _
  ByVal resourceUri, _
  ByVal parameters, _
  [ ByVal flags ] _
)

Parâmetros

actionUri [in]

O URI do método a ser invocado.

resourceUri [in]

O identificador do recurso a ser recuperado.

Esse parâmetro pode conter um dos seguintes:

• URI com ou sem seletores. No exemplo a seguir do Visual Basic Scripting Edition (VBScript), a chave é especificada por Win32_Service?Name=winmgmt.

  strResourceUri = "http://schemas.microsoft.com/wbem/wsman/1/" _ 
     & "Win32_Service?Name=winmgmt"
  

• Objeto ResourceLocator que pode conter seletores, fragmentos ou opções.

• Referência de ponto de extremidade de endereçamento WS, conforme descrito no padrão WS-Management Protocol. Para obter mais informações sobre a especificação pública do protocolo WS-Management, consulte Página de índice de especificações de gerenciamento.

parâmetros [in]

A representação XML da entrada para o método . Essa cadeia de caracteres deve ser fornecida ou esse método falhará.

sinalizadores [in, opcional]

Reservado. Deve ser definido como 0.

Valor retornado

A representação XML da saída do método.

Exemplos

O exemplo de código VBScript a seguir inicia um processo de Calc.exe. O parâmetro strInputParameters contém os parâmetros de entrada no formato XML. O único parâmetro de entrada necessário para o método Create da classe Win32_Process WMI é a linha de comando a ser executada.

Set objWsman = CreateObject( "WSMan.Automation" )
If objWsman is Nothing Then
    WScript.Echo "Failed to create WSMAN Automation object"
    WScript.Quit
End If 

Set objSession = objWsman.CreateSession
If objSession is Nothing Then
    WScript.Echo "Failed to create WSMAN Session object"
    WScript.Quit
End If 

strResource = "http://schemas.microsoft.com/wbem/wsman/1/" & _
    "wmi/root/cimv2/Win32_Process"

strInputParameters = "<p:Create_INPUT " & _
    "xmlns:p=""http://schemas.microsoft.com/wbem/wsman/1/wmi/root/cimv2/Win32_Process"">" & _
    "<p:CommandLine>" & "calc.exe" & _
    "</p:CommandLine>" & _
    "</p:Create_INPUT>"

strOutputParameters = objSession.Invoke( "Create", _
    strResource, strInputParameters )

DisplayOutput( strOutputParameters )

'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************
Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" ) 
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile ) 
End Sub

O exemplo de código VBScript a seguir chama o método Session.Invoke para executar o método StopService de Win32_Service. O método StopService não tem parâmetros de entrada. No entanto, o método Invoke requer uma cadeia de caracteres XML no parâmetro parameters .

Option Explicit

Dim objWsman
Dim objSession
Dim strResponse
Dim strActionURI
Dim strInputXml
Dim strResourceURI
Dim strMethodName

set objWsman = CreateObject("Wsman.Automation")
set objSession = objWsman.CreateSession
strResourceURI = "http://schemas.microsoft.com/wbem/wsman/1/"_
    & "wmi/root/cimv2/Win32_Service?Name=w32time"
strMethodName = "StopService"
strActionURI = strMethodName                                      

strInputXml = "<p:StopService_INPUT " _
    & "xmlns:p=""http://schemas.microsoft.com/wbem/wsman/1/"_
    & "wmi/root/cimv2/Win32_Service""/>"

strResponse = objSession.Invoke(strMethodName, strResourceURI, strInputXml)

call DisplayOutput(strResponse)
 
strMethodName = "StartService" 
strActionURI = strResourceURI & "/" & strMethodName  
strInputXml = "<p:StartService_INPUT " _
    & "xmlns:p=""http://schemas.microsoft.com/wbem/wsman/1/"_
    & "wmi/root/cimv2/Win32_Service""/>"
strResponse = objSession.Invoke(strMethodName, _
    strResourceURI, strInputXml)

call DisplayOutput(strResponse)

 
'****************************************************
' Displays WinRM XML message using built-in XSL
'****************************************************

Sub DisplayOutput( strWinRMXml )
    Dim xmlFile, xslFile
    Set xmlFile = CreateObject( "MSXml2.DOMDocument.3.0" )    
    Set xslFile = CreateObject( "MSXml2.DOMDocument.3.0" )
    xmlFile.LoadXml( strWinRMXml )
    xslFile.Load( "WsmTxt.xsl" )
    Wscript.Echo xmlFile.TransformNode( xslFile )           
End Sub

Requisitos

Confira também

Session