Создание управляемой файловой системы Lustre Azure с помощью Terraform

В этой статье вы используете Terraform для создания файловой системы Azure Managed Lustre .

Terraform поддерживает определение, предварительный просмотр и развертывание облачной инфраструктуры. С помощью Terraform можно создавать файлы конфигурации с применением синтаксиса HCL. Синтаксис HCL позволяет указать поставщика облачных служб, например Azure, и элементы, составляющие облачную инфраструктуру. После создания файлов конфигурации создается план выполнения, который позволяет предварительно просматривать изменения инфраструктуры до их развертывания. После проверки изменений примените план выполнения для развертывания инфраструктуры.

Вы узнаете, как выполнять следующие задачи:

Необходимые компоненты

• Установка и настройка Terraform

Реализация кода Terraform

1. Создайте каталог, в котором необходимо протестировать пример кода Terraform и сделать его текущим каталогом.

2. Создайте файл с именем providers.tf и вставьте следующий код:

   terraform {
     required_version = ">=1.0"
   
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   
   provider "azurerm" {
     features {}
   }
   

3. Создайте файл с именем main.tf и вставьте следующий код:

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     location = var.resource_group_location
     name     = random_pet.rg_name.id
   }
   
   resource "random_string" "azurerm_virtual_network_name" {
     length  = 13
     lower   = true
     numeric = false
     special = false
     upper   = false
   }
   
   resource "azurerm_virtual_network" "example" { 
     name = coalesce(var.virtual_network_name, "vnet-${random_string.azurerm_virtual_network_name.result}")
     resource_group_name = azurerm_resource_group.rg.name
     address_space = ["10.0.0.0/16"] 
     location = azurerm_resource_group.rg.location 
   }
   
   resource "random_string" "azurerm_subnet_name" {
     length  = 13
     lower   = true
     numeric = false
     special = false
     upper   = false
   }
   
   resource "azurerm_subnet" "example" { 
     name = coalesce(var.subnet_name, "subnet-${random_string.azurerm_subnet_name.result}")
     resource_group_name = azurerm_resource_group.rg.name 
     virtual_network_name = azurerm_virtual_network.example.name 
     address_prefixes = ["10.0.2.0/24"]
   }
   
   resource "random_string" "azurerm_amlfs_name" {
     length  = 13
     lower   = true
     numeric = false
     special = false
     upper   = false
   }
   
   resource "azurerm_managed_lustre_file_system" "example" { 
     name = coalesce(var.amlfs_name, "amlfs-${random_string.azurerm_amlfs_name.result}")
     resource_group_name = azurerm_resource_group.rg.name
     location = azurerm_resource_group.rg.location 
     sku_name = var.amlfs_sku_name
     subnet_id = azurerm_subnet.example.id 
     storage_capacity_in_tb = var.amlfs_storage_capacity_in_tb 
     zones = ["1"] 
     maintenance_window {
       day_of_week = var.amlfs_maintenance_day_of_week
       time_of_day_in_utc = var.amlfs_maintenance_time_of_day
     }
   }
   

4. Создайте файл с именем variables.tf и вставьте следующий код:

   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
   }
   
   variable "resource_group_location" {
     type        = string
     default     = "eastus"
     description = "Location of the resource group."
   }
   
   variable "virtual_network_name" {
     type        = string
     description = "The name of the virtual network resource. The value will be randomly generated if blank."
     default     = ""
   }
   
   variable "subnet_name" {
     type        = string
     description = "The name of the virtual network subnet. The value will be randomly generated if blank."
     default     = ""
   }
   
   variable "amlfs_name" {
     type        = string
     description = "The name of the Manage Lustre file system resource. The value will be randomly generated if blank."
     default     = ""
   }
   
   variable "amlfs_sku_name" {
     type        = string
     default     = "AMLFS-Durable-Premium-40"
     validation {
       condition     = contains(["AMLFS-Durable-Premium-40", "AMLFS-Durable-Premium-125", "AMLFS-Durable-Premium-250", "AMLFS-Durable-Premium-500"], var.amlfs_sku_name)
       error_message = "The SKU value must be one of the following: AMLFS-Durable-Premium-40, AMLFS-Durable-Premium-125, AMLFS-Durable-Premium-250, AMLFS-Durable-Premium-500."
     }
     description = "SKU name for the Azure Managed Lustre file system."
   }
   
   variable "amlfs_storage_capacity_in_tb" {
     type        = number
     default     = 48
     description = "The size of the Managed Lustre file system, in TiB. This might be rounded up."
   }
   
   variable "amlfs_maintenance_day_of_week" {
     type        = string
     default     = "Saturday"
     validation {
       condition     = contains(["Sunday", "Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday"], var.amlfs_maintenance_day_of_week)
       error_message = "The maintenance day of week value must be one of the following: Sunday, Monday, Tuesday, Wednesday, Thursday, Friday, Saturday."
     }
     description = "Day of the week on which the maintenance window will occur."
   }
   
   variable "amlfs_maintenance_time_of_day" {
     type        = string
     default     = "02:00"
     description = "The time of day (in UTC) to start the maintenance window."
   }
   

5. Создайте файл с именем outputs.tf и вставьте следующий код:

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "virtual_network_name" {
     value = azurerm_virtual_network.example.name
   }
   
   output "subnet_name" {
     value = azurerm_subnet.example.name
   }
   
   output "managed_lustre_file_system_name" {
     value = azurerm_managed_lustre_file_system.example.name
   }
   
   output "amlfs_sku_name" {
     value = azurerm_managed_lustre_file_system.example.sku_name
   }
   
   output "amlfs_storage_capacity_in_tb" {
     value = azurerm_managed_lustre_file_system.example.storage_capacity_in_tb
   }
   

Инициализация Terraform

Запустите terraform init, чтобы инициализировать развертывание Terraform. Эта команда скачивает поставщик Azure, необходимый для управления ресурсами Azure.

terraform init -upgrade

Основные моменты:

• Параметр -upgrade обновляет необходимые подключаемые модули поставщика до последней версии, которая соответствует ограничениям версии конфигурации.

Создание плана выполнения Terraform

Чтобы создать план выполнения, выполните terraform plan.

terraform plan -out main.tfplan

Основные моменты:

• Команда terraform plan создает план выполнения, но не выполняет его. Вместо этого она определяет, какие действия необходимы для создания конфигурации, заданной в файлах конфигурации. Этот шаблон позволяет проверить, соответствует ли план выполнения вашим ожиданиям, прежде чем вы начнете вносить изменения в фактические ресурсы.
• Необязательный параметр -out позволяет указать выходной файл для плана. Использование параметра -out гарантирует, что проверяемый план полностью соответствует применяемому.

Применение плана выполнения Terraform

Выполните terraform apply, чтобы применить план выполнения к вашей облачной инфраструктуре.

terraform apply main.tfplan

Основные моменты:

• В примере terraform apply команды предполагается, что вы ранее выполнили.terraform plan -out main.tfplan
• Если для параметра -out указано другое имя файла, используйте то же имя в вызове к terraform apply.
• Если вы не использовали параметр -out, вызовите terraform apply без параметров.

Проверка результатов

Очистка ресурсов

Если вам больше не нужны ресурсы, созданные через Terraform, выполните следующие действия:

1. Выполните команду terraform plan и укажите флаг destroy.

   terraform plan -destroy -out main.destroy.tfplan
   

   Основные моменты:

   • Команда terraform plan создает план выполнения, но не выполняет его. Вместо этого она определяет, какие действия необходимы для создания конфигурации, заданной в файлах конфигурации. Этот шаблон позволяет проверить, соответствует ли план выполнения вашим ожиданиям, прежде чем вы начнете вносить изменения в фактические ресурсы.
   • Необязательный параметр -out позволяет указать выходной файл для плана. Использование параметра -out гарантирует, что проверяемый план полностью соответствует применяемому.

2. Выполните команду terraform apply, чтобы применить план выполнения.

   terraform apply main.destroy.tfplan
   

Устранение неполадок с Terraform в Azure

Ознакомьтесь с распространенными проблемами при использовании Terraform в Azure.

Связанный контент

• Общие сведения об Управляемом Lustre в Azure