Поделиться через

Практическое руководство. Определение оператора преобразования (Visual Basic)

  • Статья

Если вы определили класс или структуру, можно определить оператор преобразования типов между типом класса или структуры и другим типом данных (напримерInteger, или DoubleString).

Определите преобразование типов как процедуру функции CType в классе или структуре. Все процедуры преобразования должны быть Public Shared, и каждый из них должен указывать расширение или сужение.

Определение оператора класса или структуры также называется перегрузкой оператора.

Пример

В следующем примере определяются операторы преобразования между структурой, называемой digit и а Byte.

Public Structure digit
Private dig As Byte
    Public Sub New(ByVal b As Byte)
        If (b < 0 OrElse b > 9) Then Throw New System.ArgumentException(
            "Argument outside range for Byte")
        Me.dig = b
    End Sub
    Public Shared Widening Operator CType(ByVal d As digit) As Byte
        Return d.dig
    End Operator
    Public Shared Narrowing Operator CType(ByVal b As Byte) As digit
        Return New digit(b)
    End Operator
End Structure

Вы можете протестировать структуру digit с помощью следующего кода.

Public Sub consumeDigit()
    Dim d1 As New digit(4)
    Dim d2 As New digit(7)
    Dim d3 As digit = CType(CByte(3), digit)
    Dim s As String = "Initial 4 generates " & CStr(CType(d1, Byte)) &
          vbCrLf & "Initial 7 generates " & CStr(CType(d2, Byte)) &
          vbCrLf & "Converted 3 generates " & CStr(CType(d3, Byte))
    Try
        Dim d4 As digit
        d4 = CType(CType(d1, Byte) + CType(d2, Byte), digit)
    Catch e4 As System.Exception
        s &= vbCrLf & "4 + 7 generates " & """" & e4.Message & """"
    End Try
    Try
        Dim d5 As digit = CType(CByte(10), digit)
    Catch e5 As System.Exception
        s &= vbCrLf & "Initial 10 generates " & """" & e5.Message & """"
    End Try
    MsgBox(s)
End Sub

См. также