arg_min() (агрегатная функция)

Область применения: ✅Microsoft Fabric✅

Находит строку в таблице, которая сводит к минимуму указанное выражение. Он возвращает все столбцы входной таблицы или указанные столбцы.

Устаревшие псевдонимы: argmin()

Синтаксис

arg_min ( ExprToMinimize,* | ExprToReturn [, ...])

Дополнительные сведения о соглашениях синтаксиса.

Параметры

Обработка NULL

Если ExprToMinimize имеет значение NULL для всех строк в таблице, выбирается одна строка в таблице. В противном случае строки, в которых ExprToMinimize имеет значение NULL, игнорируются.

Возвраты

Возвращает строку в таблице, которая сводит к минимуму ExprToMinimize, а также значения столбцов, указанных в ExprToReturn. Используйте или * возвращает всю строку.

Примеры

Найдите минимальную широту события шторма в каждом состоянии.

StormEvents 
| summarize arg_min(BeginLat, BeginLocation) by State

Выходные данные

Показанная таблица результатов содержит только первые 10 строк.

Найдите первое событие с прямой смертью в каждом состоянии, показывающее все столбцы.

Запрос сначала фильтрует события, чтобы включить только те, где была по крайней мере одна прямая смерть. Затем запрос возвращает всю строку с наименьшим значением для StartTime.

StormEvents
| where DeathsDirect > 0
| summarize arg_min(StartTime, *) by State

Выходные данные

Показанная таблица результатов содержит только первые 10 строк и первые 3 столбца.

В следующем примере показана обработка значений NULL.

datatable(Fruit: string, Color: string, Version: int) [
    "Apple", "Red", 1,
    "Apple", "Green", int(null),
    "Banana", "Yellow", int(null),
    "Banana", "Green", int(null),
    "Pear", "Brown", 1,
    "Pear", "Green", 2,
]
| summarize arg_min(Version, *) by Fruit

Выходные данные

Сравнение с min()

Функция arg_min() отличается от функции min(). Функция arg_min() позволяет возвращать дополнительные столбцы вместе с минимальным значением, а min() возвращает только минимальное значение.

Примеры

arg_min()

Найдите первое событие с прямой смертью, отображая все столбцы в таблице.

Запрос сначала фильтрует события, чтобы включить только те, где была по крайней мере одна прямая смерть. Затем запрос возвращает всю строку с наименьшим значением для StartTime.

StormEvents
| where DeathsDirect > 0
| summarize arg_min(StartTime, *)

Таблица результатов возвращает все столбцы для строки, содержащей наименьшее значение в указанном выражении.

min()

Найдите первое событие с прямой смертью.

Запрос фильтрует события, чтобы включить только те, где есть по крайней мере одна прямая смерть, а затем возвращает минимальное значение для StartTime.

StormEvents
| where DeathsDirect > 0
| summarize min(StartTime)

Таблица результатов возвращает наименьшее значение только в определенном столбце.

Связанный контент

• min function
• max function
• avg function
• функция процентиля
• мин функции