Поделиться через

geo_azimuth()

  • Статья

Область применения: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Вычисляет по часовой стрелке угол в радианах между линией от точки1 до истинного севера и линией от точки1 до точки2 на Земле.

Синтаксис

geo_azimuth(,p1_longitude p1_latitude,p2_longitude p2_latitude,)

Дополнительные сведения о соглашениях синтаксиса.

Параметры

Имя (название) Type Обязательно Описание
p1_longitude real ✔️ Значение долготы в градусах первой геопространственной координаты. Допустимое значение находится в диапазоне [-180, +180].
p1_latitude real ✔️ Значение широты в градусах первой геопространственной координаты. Допустимое значение находится в диапазоне [-90, +90].
p2_longitude real ✔️ Значение долготы в градусах второй геопространственной координаты. Допустимое значение находится в диапазоне [-180, +180].
p2_latitude real ✔️ Значение широты в градусах второй геопространственной координаты. Допустимое значение находится в диапазоне [-90, +90].

Возвраты

Угол в радианах между линией от точки p1 до истинного севера и линии [p1, p2]. Угол измеряется по часовой стрелке.

Примечание.

  • Геопространственные координаты интерпретируются как представленные эталонной системой координат WGS-84 .
  • Геостатический datum , используемый для измерения расстояния на Земле является сферой. Границы линии — геодесик на сфере.
  • Азимут 0 точек на север. Азимут Пи/2 точки на востоке. Азимут Пи указывает на юг. Азимут 3Pi/2 точки запад.
  • Если координаты недопустимы, запрос создаст результат NULL.
  • Если точка1 равна точке 2, запрос создаст результат NULL.
  • Если точка1 и точка2 являются антиподальными, запрос создаст результат NULL.

Примеры

В следующем примере вычисляется азимут в радианах.

print azimuth_in_radians = geo_azimuth(5, 10, 10, -40)

Выходные данные

azimuth_in_radians
3.05459939796449

В следующем примере вычисляется азимут в градусах.

let azimuth_in_radians = geo_azimuth(5, 10, 10, -40);
print azimuth_in_degrees = degrees(azimuth_in_radians);

Выходные данные

azimuth_in_degrees
175.015653606568

В следующем примере рассматривается грузовик, который выдает данные телеметрии своего расположения во время путешествия и ищет направление движения.

let get_direction = (azimuth:real)
{
    let pi = pi();
    iff(azimuth < pi/2,   "North-East",
    iff(azimuth < pi,     "South-East",
    iff(azimuth < 3*pi/2, "South-West",
                          "North-West")));
};
datatable(timestamp:datetime, lng:real, lat:real)
[
    datetime(2024-01-01T00:01:53.048506Z), -115.4036607693417, 36.40551631046261,
    datetime(2024-01-01T00:02:53.048506Z), -115.3256807623232, 36.34102142760111,
    datetime(2024-01-01T00:03:53.048506Z), -115.2732290602112, 36.28458914829917,
    datetime(2024-01-01T00:04:53.048506Z), -115.2513186233914, 36.27622394664352,
    datetime(2024-01-01T00:05:53.048506Z), -115.2352055633212, 36.27545547038515,
    datetime(2024-01-01T00:06:53.048506Z), -115.1894341934856, 36.28266934431671,
    datetime(2024-01-01T00:07:53.048506Z), -115.1054318118468, 36.28957085435267,
    datetime(2024-01-01T00:08:53.048506Z), -115.0648614339413, 36.28110743285072,
    datetime(2024-01-01T00:09:53.048506Z), -114.9858032867736, 36.29780696509714,
    datetime(2024-01-01T00:10:53.048506Z), -114.9016966527561, 36.36556196813566,
]
| sort by timestamp asc 
| extend prev_lng = prev(lng), prev_lat = prev(lat)
| where isnotnull(prev_lng) and isnotnull(prev_lat)
| extend direction = get_direction(geo_azimuth(prev_lng, prev_lat, lng, lat))
| project direction, lng, lat
| render scatterchart with (kind = map)

Выходные данные

Азимут между двумя последовательными расположениями.

Следующий пример возвращается true , так как первая точка равна второй точке.

print is_null = isnull(geo_azimuth(5, 10, 5, 10))

Выходные данные

is_null
true