Геопространственные визуализации

Область применения: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Геопространственные данные можно визуализировать с помощью оператора отрисовки в обозревателе компьютеров Kusto. Чтобы скачать Обозреватель классических приложений Kusto, см. статью о установке и пользовательском интерфейсе Kusto.Explorer.

Дополнительные сведения о геопространственной кластеризации см. в разделе "Геопространственный кластеризация".

Визуализация точек на карте

Вы можете визуализировать точки с помощью столбцов [Долгота, Широта] или столбца GeoJSON. Использование столбца рядов является необязательным. Пара [долгота, широта] определяет каждую точку в этом порядке.

Пример. Визуализация точек на карте

Следующий пример находит события storm и визуализирует 100 на карте.

StormEvents
| take 100
| project BeginLon, BeginLat
| render scatterchart with (kind = map)

Пример. Визуализация нескольких точек на карте

В следующем примере визуализируется несколько рядов точек, где пара [Долгота, Широта] определяет каждую точку, а третий столбец определяет ряд. В этом примере используется EventTypeряд.

StormEvents
| take 100
| project BeginLon, BeginLat, EventType
| render scatterchart with (kind = map)

Пример. Визуализация ряда точек данных с несколькими столбцами

В следующем примере показано, как визуализировать ряд точек на карте. Если в результате имеется несколько столбцов, необходимо указать столбцы, которые будут использоваться для xcolumn (долгота), ycolumn (Широта) и ряда.

StormEvents
| take 100
| render scatterchart with (kind = map, xcolumn = BeginLon, ycolumns = BeginLat, series = EventType)

Пример. Визуализация точек на карте, определенной динамическими значениями GeoJSON

В следующем примере визуализируется точки на карте с помощью динамических значений GeoJSON для определения точек.

StormEvents
| project BeginLon, BeginLat
| summarize by hash=geo_point_to_s2cell(BeginLon, BeginLat, 5)
| project geo_s2cell_to_central_point(hash)
| render scatterchart with (kind = map)

Визуализация пирогов или пузырьков на карте

Вы можете визуализировать пироги или пузырьки с помощью столбцов [Долгота, Широта] или столбца GeoJSON. Эти визуализации можно создавать с помощью цветов или числовых осей.

Пример. Визуализация круговой диаграммы по расположению

В следующем примере показаны события storm, агрегированные ячейкой S2. Диаграмма объединяет события в круговых диаграммах по расположению.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), EventType, count_
| render piechart with (kind = map) // pie map rendering available only in Kusto Explorer desktop

Пример. Визуализация пузырьков с помощью цветовой оси

В следующем примере показаны события storm, агрегированные ячейкой S2. Диаграмма объединяет события в пузырьках по расположению. Так как цветовая ось ("count") одинакова для всех событий, render оператор создает пузырьки.

StormEvents
| project BeginLon, BeginLat, EventType
| where geo_point_in_circle(BeginLon, BeginLat, real(-81.3891), 28.5346, 1000 * 100)
| summarize count() by EventType, hash = geo_point_to_s2cell(BeginLon, BeginLat)
| project geo_s2cell_to_central_point(hash), count_
| extend Events = "count"
| render piechart with (kind = map) // pie map rendering available only in Kusto Explorer desktop

Связанный контент

• Геопространственный кластеризация
• Оператор отрисовки
• Аналитика данных для автопарков испытаний (вариант использования геопространственного кластеризации)
• Сведения об архитектуре Azure для геопространственной обработки и аналитики данных