Пошаговое руководство. Реализация IEnumerable(Of T) в Visual Basic

В Visual Basic в меню Файл последовательно выберите пункты Создать и Проект.

Убедитесь, что в диалоговом окне Новый проект в области Типы проектов выбран пункт Windows.В области Шаблоны выберите пункт Библиотека классов.В поле Имя введите StreamReaderEnumerable и нажмите кнопку ОК.Появится новый проект.

В обозревателе решений щелкните правой кнопкой мыши файл Class1.vb и выберите команду Переименовать.Переименуйте файл в StreamReaderEnumerable.vb и нажмите клавишу ВВОД.При переименовании файла класс также будет переименован в StreamReaderEnumerable.Этот класс будет реализовывать интерфейс IEnumerable(Of String).

Щелкните правой кнопкой мыши проект StreamReaderEnumerable, выберите команду Добавить и пункт Создать элемент.Выберите шаблон Класс.В поле Имя введите StreamReaderEnumerator.vb и нажмите кнопку ОК.

Откройте файл StreamReaderEnumerable.vb.

В строке после Public Class StreamReaderEnumerable введите следующее и нажмите клавишу ВВОД.

Implements IEnumerable(Of String)

Visual Basic автоматически заполняет класс членами, необходимыми для интерфейса IEnumerable(Of String).

Этот перечислимый класс будет читать строки текстового файла одну за другой.Добавьте в класс следующий код, чтобы предоставить открытый конструктор, который принимает путь к файлу в качестве входного параметра.

Private _filePath As String

Public Sub New(ByVal filePath As String)
    _filePath = filePath
End Sub

Реализация метода GetEnumerator интерфейса IEnumerable(Of String) будет возвращать новый экземпляр класса StreamReaderEnumerator.Реализацию метода GetEnumerator интерфейса IEnumerable можно сделать закрытой (Private), поскольку требуется предоставить доступ только членам интерфейса IEnumerable(Of String).Замените код, созданный Visual Basic для методов GetEnumerator, следующим кодом.

Public Function GetEnumerator() As IEnumerator(Of String) _
    Implements IEnumerable(Of String).GetEnumerator

    Return New StreamReaderEnumerator(_filePath)
End Function

Private Function GetEnumerator1() As IEnumerator _
    Implements IEnumerable.GetEnumerator

    Return Me.GetEnumerator()
End Function

Откройте файл StreamReaderEnumerator.vb.

В строке после Public Class StreamReaderEnumerator введите следующее и нажмите клавишу ВВОД.

Implements IEnumerator(Of String)

Visual Basic автоматически заполняет класс членами, необходимыми для интерфейса IEnumerator(Of String).

Класс перечислителя открывает текстовый файл и выполняет файловые операции ввода-вывода, считывая строки из файла.Добавьте в класс следующий код, чтобы предоставить открытый конструктор, который принимает путь к файлу как входной параметр и открывает текстовый файл для чтения.

Private _sr As IO.StreamReader

Public Sub New(ByVal filePath As String)
    _sr = New IO.StreamReader(filePath)
End Sub

Свойства Current для интерфейсов IEnumerator(Of String) и IEnumerator возвращают текущий элемент из текстового файла в качестве объекта типа String.Реализацию свойства Current интерфейса IEnumerator можно сделать закрытой (Private), поскольку требуется предоставить доступ только членам интерфейса IEnumerator(Of String).Замените код, созданный Visual Basic для свойств Current, следующим кодом.

Private _current As String

Public ReadOnly Property Current() As String _
    Implements IEnumerator(Of String).Current

    Get
        If _sr Is Nothing OrElse _current Is Nothing Then
            Throw New InvalidOperationException()
        End If

        Return _current
    End Get
End Property

Private ReadOnly Property Current1() As Object _
    Implements IEnumerator.Current

    Get
        Return Me.Current
    End Get
End Property

Метод MoveNext интерфейса IEnumerator переходит к следующему элементу в текстовом файле и обновляет значение, возвращаемое свойством Current.Если элементов для чтения не осталось, метод MoveNext возвращает значение False; в противном случае метод MoveNext возвращает значение True.Добавьте следующий код в метод MoveNext.

Public Function MoveNext() As Boolean _
    Implements System.Collections.IEnumerator.MoveNext

    _current = _sr.ReadLine()
    If _current Is Nothing Then Return False
    Return True
End Function

Метод Reset интерфейса IEnumerator дает итератору команду перейти в начало текстового файла и очищает значение текущего элемента.Добавьте следующий код в метод Reset.

Public Sub Reset() _
    Implements System.Collections.IEnumerator.Reset

    _sr.DiscardBufferedData()
    _sr.BaseStream.Seek(0, IO.SeekOrigin.Begin)
    _current = Nothing
End Sub

Метод Dispose интерфейса IEnumerator гарантирует, что все неуправляемые ресурсы будут освобождены до уничтожения итератора.Дескриптор файла, используемый объектом StreamReader, является неуправляемым ресурсом, который должен быть закрыт до уничтожения экземпляра итератора.Замените код, созданный Visual Basic для метода Dispose, следующим кодом.

Private disposedValue As Boolean = False

Protected Overridable Sub Dispose(ByVal disposing As Boolean)
    If Not Me.disposedValue Then
        If disposing Then
            ' Dispose of managed resources.
        End If
        _current = Nothing
        _sr.Close()
        _sr.Dispose()
    End If

    Me.disposedValue = True
End Sub

Public Sub Dispose() Implements IDisposable.Dispose
    Dispose(True)
    GC.SuppressFinalize(Me)
End Sub

Protected Overrides Sub Finalize()
    Dispose(False)
End Sub