Поделиться через

Escape-последовательности для значений даты, времени и отметок времени

  • Статья

ODBC определяет escape-последовательности для литерала даты, времени и метки времени. Синтаксис этих escape-последовательностей выглядит следующим образом:

  
{d 'value'}  
{t 'value'}  
{ts 'value'}

В нотации BNF синтаксис выглядит следующим образом:

ODBC-date-time-escape ::=  
     ODBC-date-escape  
     | ODBC-time-escape  
     | ODBC-timestamp-escape

ODBC-date-escape ::=  
     ODBC-esc-initiator d 'date-value' ODBC-esc-terminator

ODBC-time-escape ::=  
     ODBC-esc-initiator t 'time-value' ODBC-esc-terminator

ODBC-timestamp-escape ::=  
     ODBC-esc-initiator ts 'timestamp-value' ODBC-esc-terminator

ODBC-esc-initiator ::= {  

ODBC-esc-terminator ::= }  

date-value ::=   
     years-value date-separator months-value date-separator days-value

time-value ::=   
     hours-value time-separator minutes-value time-separator seconds-value

timestamp-value ::= date-value timestamp-separator time-value

date-separator ::= -  

time-separator ::= :  

timestamp-separator ::=  
     (The blank character)

years-value ::= digit digit digit digit

months-value ::= digit digit

days-value ::= digit digit

hours-value ::= digit digit

minutes-value ::= digit digit

seconds-value ::= digit digit[.digit...]

Замечания

Escape-последовательности даты, времени и метки времени поддерживаются, если типы данных даты, времени и метки времени поддерживаются источником данных. Приложение должно вызывать SQLGetTypeInfo , чтобы определить, поддерживаются ли эти типы данных.