Frågor för tabellen ACSSMSIncomingOperations

Information om hur du använder dessa frågor i Azure Portal finns i Log Analytics-självstudien. Information om REST-API:et finns i Fråga.

Visa en lista över distinkta SMS-åtgärder

Returnerar alla distinkta kombinationer av SMS-åtgärder och versionspar.

ACSSMSIncomingOperations
| distinct OperationName, OperationVersion 
| limit 100

Beräkna varaktighetsprocentiler för SMS-åtgärden

Beräknar den 90:e, 95:e och 99:e percentilen av körningens varaktighet i millisekunder för varje SMS-åtgärd. Det kan anpassas för att köras för en enda åtgärd eller för andra percentiler.

ACSSMSIncomingOperations
// where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's duration percentiles
| summarize percentiles(DurationMs, 90, 95, 99) by OperationName, OperationVersion // calculate 90th, 95th, and 99th percentiles of each Operation
| limit 100

De 5 främsta IP-adresserna per SMS-åtgärd

För varje SMS-åtgärd hämtar du de 5 IP-adresser som har kallat den åtgärden mest.

ACSSMSIncomingOperations
// | where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's count
| top-nested of OperationName by dummy=max(0), // For all the Operations...
  top-nested 5 of CallerIpAddress by count() // List the IP address that have called that operation the most
| project-away dummy // Remove dummy line from the result set
| limit 100

SMS-driftfel

Visa en lista över alla SMS-fel som sorteras efter rekency.

ACSSMSIncomingOperations
| where ResultType == "Failed"
| project TimeGenerated, OperationName, OperationVersion, ResultSignature, ResultDescription
| order by TimeGenerated desc
| limit 100

Antal SMS-åtgärdsresultat

Räkna vilka typer av returnerade resultat som returneras för varje SMS-åtgärd.

ACSSMSIncomingOperations
| summarize Count = count() by OperationName, ResultType //, ResultSignature // This can also be uncommented to determine the count of each ResultSignature for each ResultType 
| order by OperationName asc, Count desc
| limit 100