Öğretici: Yaygın işleçleri öğrenme

Şunlar için geçerlidir: ✅Microsoft Fabric✅

Kusto Sorgu Dili (KQL), Azure Veri Gezgini, Azure İzleyici Log Analytics, Azure Sentinel ve daha fazlasında sorgu yazmak için kullanılır. Bu öğretici, verilerinize erişmek ve bunları analiz etmek için kullanılan temel KQL işleçlerine giriş niteliğindedir.

Azure İzleyici'de günlükleri sorgulama hakkında daha ayrıntılı yönergeler için bkz . Günlük sorgularını kullanmaya başlama.

Bu öğreticide aşağıdakilerin nasıl yapılacağını öğreneceksiniz:

Önkoşullar

Aşağıdaki sorguları çalıştırmak için örnek verilere erişimi olan bir sorgu ortamına ihtiyacınız vardır. Aşağıdakilerden birini kullanabilirsiniz:

Satırları say

Tablodaki storm kayıtlarının sayısını bulmak için count işlecini StormEvents kullanarak başlayın.

StormEvents 
| count

Çıktı

Veri örneğine bakın

Verileri algılamak için take işlecini kullanarak kayıtların bir örneğini görüntüleyin. Bu işleç tablodan belirtilen sayıda rastgele satır döndürür. Bu, genel veri yapısını ve içeriğini önizlemek için yararlı olabilir.

StormEvents 
| take 5

Aşağıdaki tabloda döndürülen 22 sütundan yalnızca beşi gösterilmektedir. Çıkışın tamamını görmek için sorguyu çalıştırın.

Sütunların alt kümesini seçme

Görünümü basitleştirmek ve sütunların belirli bir alt kümesini seçmek için proje işlecini kullanın. Kullanmak project genellikle tüm sütunları görüntülemekten daha verimlidir ve okunmasını kolaylaştırır.

StormEvents
| take 5
| project State, EventType, DamageProperty

Çıktı

Benzersiz değerleri listeleme

Önceki sorgunun sonuçlarına bağlı olarak birden çok tür fırtına olduğu görülüyor. Benzersiz fırtına türlerinin tümünü listelemek için distinct işlecini kullanın.

StormEvents 
| distinct EventType

Tabloda 46 tür fırtına vardır. Burada bunlardan 10'unun bir örneği verilmiştir.

Sonuçları sıralama

Texas'ta en çok hasara neden olan en çok zarar veren taşkınları görüntülemek için sıralama işlecini kullanarak satırları sütuna göre DamageProperty azalan düzende düzenleyin. Varsayılan sıralama düzeni azalan düzendedir. Artan düzende sıralamak için belirtin asc.

StormEvents
| where State == 'TEXAS' and EventType == 'Flood'
| sort by DamageProperty
| project StartTime, EndTime, State, EventType, DamageProperty

Çıktı

Koşula göre filtrele

Where işleci belirli ölçütlere göre veri satırlarını filtreler.

Aşağıdaki sorgu belirli bir State içindeki fırtına olaylarını EventTypearar.

StormEvents
| where State == 'TEXAS' and EventType == 'Flood'
| project StartTime, EndTime, State, EventType, DamageProperty

Bu koşullara uyan 146 olay vardır. Burada 5 örnek verilmiştir.

Tarih ve saat aralığına göre filtreleme

Verileri belirli bir zaman aralığına göre filtrelemek için işleç arasındaki kullanın.

Aşağıdaki sorgu, 1 Ağustos 2007 ile 30 Ağustos 2007 arasındaki tüm fırtına olaylarını ve bunların durumlarını, olay türlerini, başlangıç ve bitiş saatlerini bulur. Sonuçlar daha sonra başlangıç zamanına göre artan düzende sıralanır.

StormEvents
| where StartTime between (datetime(2007-08-01 00:00:00) .. datetime(2007-08-30 23:59:59))
| project State, EventType, StartTime, EndTime
| sort by StartTime asc 

Çıktı

İlk n satırı alma

Üst işleç, belirtilen sütuna göre sıralanmış ilk n satırı döndürür.

Aşağıdaki sorgu, en çok zarar gören özelliğe neden olan beş Texas selini döndürür.

StormEvents
| where State == 'TEXAS' and EventType == 'Flood'
| top 5 by DamageProperty
| project StartTime, EndTime, State, EventType, DamageProperty

Çıktı

Hesaplanmış sütunlar oluşturma

Hem proje hem de genişletme işleçleri hesaplanmış sütunlar oluşturabilir.

Yalnızca görüntülemek istediğiniz sütunları belirtmek için kullanın project ve hesaplanan sütunu tablonun sonuna eklemek için kullanın extend .

Aşağıdaki sorgu, ve Durationarasındaki StartTime farka sahip bir hesaplanmış EndTime sütun oluşturur. Yalnızca birkaç seçme sütununu görüntülemek istediğimizden, project kullanmak bu durumda daha iyi bir seçimdir.

StormEvents
| where State == 'TEXAS' and EventType == 'Flood'
| top 5 by DamageProperty desc
| project StartTime, EndTime, Duration = EndTime - StartTime, DamageProperty

Çıktı

Hesaplanan Duration sütuna bakarsanız en çok hasara neden olan selin aynı zamanda en uzun sel olduğunu fark edebilirsiniz.

Hesaplanan extend sütunu diğer tüm sütunlarla birlikte görüntülemek için kullanınDuration. Sütun Duration son sütun olarak eklenir.

StormEvents
| where State == 'TEXAS' and EventType == 'Flood'
| top 5 by DamageProperty desc
| extend Duration = EndTime - StartTime

Çıktı

Değerleri bir kümeden diğerine eşleme

Statik eşleme, sonuçlarınızın sunumunu değiştirmek için kullanışlı bir tekniktir. KQL'de statik eşleme gerçekleştirmenin bir yolu, değerleri bir kümeden diğerine eşlemek için dinamik sözlük ve erişimciler kullanmaktır.

let sourceMapping = dynamic(
  {
    "Emergency Manager" : "Public",
    "Utility Company" : "Private"
  });
StormEvents
| where Source == "Emergency Manager" or Source == "Utility Company"
| project EventId, Source, FriendlyName = sourceMapping[Source]

Çıktı

Sonraki adım

Kusto sorguları yazmanın temellerini öğrendiğinize göre, bir sonraki öğreticiye gidin ve verileriniz hakkında daha derin içgörüler elde etmek için toplama işlevlerini kullanmayı öğrenin.