Aracılığıyla paylaş

Hızlı Başlangıç: AzAPI Terraform sağlayıcısıyla ilk Azure güncelleştirme kaynağınızı dağıtma

  • Makale

Makale, aşağıdaki Terraform ve Terraform sağlayıcı sürümleriyle test edilmiştir:

Terraform , bulut altyapısının tanımlanmasını, önizlemesini ve dağıtımını sağlar. Terraform kullanarak HCL söz dizimlerini kullanarak yapılandırma dosyaları oluşturursunuz. HCL söz dizimi, Azure gibi bulut sağlayıcısını ve bulut altyapınızı oluşturan öğeleri belirtmenize olanak tanır. Yapılandırma dosyalarınızı oluşturduktan sonra, altyapı değişikliklerinizin dağıtılmadan önce önizlemesini görüntülemenizi sağlayan bir yürütme planı oluşturursunuz. Değişiklikleri doğruladıktan sonra, altyapıyı dağıtmak için yürütme planını uygularsınız.

Bu makalede, AzAPI Terraform sağlayıcısını kullanarak AzureRM sağlayıcısı tarafından şu anda desteklenmeyen bir Azure hizmetinin yeni bir özelliğini yönetmeyi öğreneceksiniz. bir azapi_update_resource Azure EventHub ağ kural kümesini yönetmek için kullanılır.

  • AzureRM ve AzAPI sağlayıcılarını tanımlama ve yapılandırma
  • Event Hubs ad alanı için rastgele bir ad oluşturma
  • AzureRM sağlayıcısını kullanarak bir Azure kaynak grubu ve gerekli ağ ile Event Hubs kaynakları oluşturma
  • Kaynaklara ağ kuralı kümesi eklemek için AzAPI sağlayıcısını azurerm_eventhub_namespace kullanma

Not

Bu makaledeki örnek kod, Azure Terraform GitHub deposunda bulunur.

Önkoşullar

  • Azure aboneliği: Azure aboneliğiniz yoksa başlamadan önce ücretsiz bir hesap oluşturun.

Terraform kodunu uygulama

  1. Örnek Terraform kodunu test etmek ve geçerli dizin yapmak için bir dizin oluşturun.

  2. adlı providers.tf bir dosya oluşturun ve aşağıdaki kodu ekleyin:

    terraform {
  required_providers {
    azapi = {
      source  = "azure/azapi"
      version = "=0.1.0"
    }

    azurerm = {
      source  = "hashicorp/azurerm"
      version = "=3.0.2"
    }

    random = {
      source  = "hashicorp/random"
      version = "=3.1.2"
    }
  }
}

provider "azapi" {
}

provider "azurerm" {
  features {}
}

provider "random" {
}

  3. adlı main.tf bir dosya oluşturun ve aşağıdaki kodu ekleyin:

    resource "azurerm_resource_group" "qs101" {
  name     = "rg-qs101-eh-rules"
  location = "westus2"
}

resource "azurerm_virtual_network" "qs101" {
  name                = "myvnet"
  location            = azurerm_resource_group.qs101.location
  resource_group_name = azurerm_resource_group.qs101.name
  address_space       = ["172.17.0.0/16"]
  dns_servers         = ["10.0.0.4", "10.0.0.5"]
}

resource "azurerm_subnet" "qs101" {
  name                 = "default"
  resource_group_name  = azurerm_resource_group.qs101.name
  virtual_network_name = azurerm_virtual_network.qs101.name
  address_prefixes     = ["172.17.0.0/24"]

  service_endpoints = ["Microsoft.EventHub"]
}

resource "random_pet" "qs101_namespace" {
  length    = 3
  separator = ""
}

resource "azurerm_eventhub_namespace" "qs101" {
  name                = random_pet.qs101_namespace.id
  location            = azurerm_resource_group.qs101.location
  resource_group_name = azurerm_resource_group.qs101.name
  sku                 = "Standard"
  capacity            = 2
}

  4. adlı main-generic.tf bir dosya oluşturun ve aşağıdaki kodu ekleyin:

    # AzAPI update resource is used to enable Network Rule sets on Event Hub namespace
resource "azapi_update_resource" "qs101" {
  type      = "Microsoft.EventHub/namespaces/networkRuleSets@2021-11-01"
  name      = "default"
  parent_id = azurerm_eventhub_namespace.qs101.id

  body = jsonencode({
    properties = {
      defaultAction       = "Deny"
      publicNetworkAccess = "Enabled"
      virtualNetworkRules = [
        {
          ignoreMissingVnetServiceEndpoint = false
          subnet = {
            # API bug, returned id replaced `resourceGroups` with `resourcegroups`
            id = replace(azurerm_subnet.qs101.id, "resourceGroups", "resourcegroups")
          }
        }
      ]
      ipRules = [
        {
          action = "Allow"
          ipMask = "1.1.1.1"
        }
      ]
    }
  })
}

Terraform'u başlatma

Terraform dağıtımını başlatmak için terraform init komutunu çalıştırın. Bu komut, Azure kaynaklarınızı yönetmek için gereken Azure sağlayıcısını indirir.

terraform init -upgrade

Önemli noktalar:

  • -upgrade parametresi, gerekli sağlayıcı eklentilerini yapılandırmanın sürüm kısıtlamalarına uygun en yeni sürüme yükseltir.

Terraform yürütme planı oluşturma

Terraform planını çalıştırarak yürütme planı oluşturun.

terraform plan -out main.tfplan

Önemli noktalar:

  • komutu terraform plan bir yürütme planı oluşturur ancak yürütmez. Bunun yerine, yapılandırma dosyalarınızda belirtilen yapılandırmayı oluşturmak için hangi eylemlerin gerekli olduğunu belirler. Bu düzen, gerçek kaynaklarda değişiklik yapmadan önce yürütme planının beklentilerinizle eşleşip eşleşmediğini doğrulamanızı sağlar.
  • İsteğe bağlı -out parametresi, plan için bir çıkış dosyası belirtmenize olanak tanır. parametresinin -out kullanılması, gözden geçirdiğiniz planın tam olarak uygulanan plan olmasını sağlar.

Terraform yürütme planı uygulama

Yürütme planını bulut altyapınıza uygulamak için terraform apply komutunu çalıştırın.

terraform apply main.tfplan

Önemli noktalar:

  • Örnek terraform apply komut, daha önce komutunu çalıştırdığınızı terraform plan -out main.tfplanvarsayar.
  • parametresi için -out farklı bir dosya adı belirttiyseniz, çağrısında terraform applyaynı dosya adını kullanın.
  • parametresini -out kullanmadıysanız, parametresiz olarak çağırın terraform apply .

Sonuçları doğrulama

Event Hubs Ad Alanı ağ kurallarını görüntülemek için az eventhubs ad alanı ağ kuralı listesini çalıştırın.

az eventhubs namespace network-rule list --resource-group <resource_group_name> --namespace-name <namespace_name>

Önemli noktalar:

  • Kaynak grubu adı ve Event Hubs ad alanı adı çıktıda terraform apply görüntülenir.

Kaynakları temizleme

Terraform aracılığıyla oluşturulan kaynaklara artık ihtiyacınız kalmadığında aşağıdaki adımları uygulayın:

  1. terraform planını çalıştırın ve bayrağını destroy belirtin.

    terraform plan -destroy -out main.destroy.tfplan

    Önemli noktalar:

    • komutu terraform plan bir yürütme planı oluşturur ancak yürütmez. Bunun yerine, yapılandırma dosyalarınızda belirtilen yapılandırmayı oluşturmak için hangi eylemlerin gerekli olduğunu belirler. Bu düzen, gerçek kaynaklarda değişiklik yapmadan önce yürütme planının beklentilerinizle eşleşip eşleşmediğini doğrulamanızı sağlar.
    • İsteğe bağlı -out parametresi, plan için bir çıkış dosyası belirtmenize olanak tanır. parametresinin -out kullanılması, gözden geçirdiğiniz planın tam olarak uygulanan plan olmasını sağlar.

  2. Yürütme planını uygulamak için terraform apply komutunu çalıştırın.

    terraform apply main.destroy.tfplan

Azure'da Terraform sorunlarını giderme

Azure'da Terraform kullanırken karşılaşılan yaygın sorunları giderme

Sonraki adımlar

Azure'da Terraform kullanma hakkında daha fazla bilgi edinin