Let deyimi

Şunlar için geçerlidir: ✅Microsoft Fabric✅Azure Veri Gezgini✅ Azure İzleyici✅Microsoft Sentinel

Deyimlet, bir ifadeye veya işleve eşit bir değişken adı ayarlamak veya görünümler oluşturmak için kullanılır.

let deyimleri şunlar için kullanışlıdır:

• Karmaşık bir ifadeyi, her birinin bir değişkenle temsil ettiği birden çok bölüme ayırma.
• Okunabilirlik için sorgu gövdesi dışındaki sabitleri tanımlama.
• Bir değişkeni bir kez tanımlama ve sorgu içinde birden çok kez kullanma.

Değişken daha önce iç içe deyimler gibi başka bir değeri temsil ettiyse, en let içteki deyim uygulanır.

Deyimin tek bir sorgudaki let birden çok kullanımını iyileştirmek için bkz . Adlandırılmış ifadeleri kullanan sorguları iyileştirme.

Sözdizimi: Skaler veya tablosal ifadeler

letAd = İfade

Söz dizimi kuralları hakkında daha fazla bilgi edinin.

Parametreler

Söz dizimi: Görünüm veya işlev

letAd = [view] ([ Parametreler ] ) { FunctionBody }

Söz dizimi kuralları hakkında daha fazla bilgi edinin.

Parametreler

Örnekler

Skaler değerleri tanımlama

Aşağıdaki örnekte skaler ifade deyimi kullanılır.

let n = 10;  // number
let place = "Dallas";  // string
let cutoff = ago(62d); // datetime 
Events 
| where timestamp > cutoff 
    and city == place 
| take n

Aşağıdaki örnek, gösterimi kullanarak ['name'] adı some number bağlar ve ardından tablosal ifade deyiminde kullanır.

let ['some number'] = 20;
range y from 0 to ['some number'] step 5

Skaler hesaplama ile kullanıcı tanımlı işlev oluşturma

Bu örnek, skaler hesaplama için bağımsız değişkenlerle let deyimini kullanır. Sorgu, iki sayıyı çarpma işlevini MultiplyByN tanımlar.

let MultiplyByN = (val:long, n:long) { val * n };
range x from 1 to 5 step 1 
| extend result = MultiplyByN(x, 5)

Çıktı

Girişi kırpan kullanıcı tanımlı bir işlev oluşturma

Aşağıdaki örnek, girişten baştaki ve sondakileri kaldırır.

let TrimOnes = (s:string) { trim("1", s) };
range x from 10 to 15 step 1 
| extend result = TrimOnes(tostring(x))

Çıktı

Birden çok let deyimi kullanma

Bu örnek, bir deyimin () başkafoo1 bir deyimi (foo2) kullandığı iki let deyimini tanımlar.

let foo1 = (_start:long, _end:long, _step:long) { range x from _start to _end step _step};
let foo2 = (_step:long) { foo1(1, 100, _step)};
foo2(2) | count

Çıktı

Görünüm veya sanal tablo oluşturma

Bu örnekte, bir veya sanal tablo oluşturmak view için let deyiminin nasıl kullanılacağı gösterilmektedir.

let Range10 = view () { range MyColumn from 1 to 10 step 1 };
let Range20 = view () { range MyColumn from 1 to 20 step 1 };
search MyColumn == 5

Çıktı

Gerçekleştirme işlevi kullanma

işlevi, materialize() sorgu yürütme sırasında alt sorgu sonuçlarını önbelleğe almanızı sağlar. işlevini kullandığınızda materialize() veriler önbelleğe alınır ve sonucun sonraki çağrıları önbelleğe alınmış verileri kullanır.

let totalPagesPerDay = PageViews
| summarize by Page, Day = startofday(Timestamp)
| summarize count() by Day;
let materializedScope = PageViews
| summarize by Page, Day = startofday(Timestamp);
let cachedResult = materialize(materializedScope);
cachedResult
| project Page, Day1 = Day
| join kind = inner
(
    cachedResult
    | project Page, Day2 = Day
)
on Page
| where Day2 > Day1
| summarize count() by Day1, Day2
| join kind = inner
    totalPagesPerDay
on $left.Day1 == $right.Day
| project Day1, Day2, Percentage = count_*100.0/count_1

Çıktı

İç içe let deyimlerini kullanma

İç içe let deyimlerine, kullanıcı tanımlı işlev ifadesi içinde de dahil olmak üzere izin verilir. deyimlerinin ve bağımsız değişkenlerin işlev gövdesinin hem geçerli hem de iç kapsamına uygulanmasına izin verin.

let start_time = ago(5h); 
let end_time = start_time + 2h; 
T | where Time > start_time and Time < end_time | ...

Şema ile tablosal bağımsız değişken

Aşağıdaki örnek, tablo parametresinin T türünde stringbir sütunu State olması gerektiğini belirtir. Tablo T başka sütunlar da içerebilir, ancak bunlar bildirilemediğinden işlevde StateState bunlara başvurulamazsınız.

let StateState=(T: (State: string)) { T | extend s_s=strcat(State, State) };
StormEvents
| invoke StateState()
| project State, s_s

Çıktı

Joker karakterli tablosal bağımsız değişken

Tablo parametresi T herhangi bir şemaya sahip olabilir ve işlev CountRecordsInTable çalışır.

let CountRecordsInTable=(T: (*)) { T | count };
StormEvents | invoke CountRecordsInTable()

Çıktı