Azure Arc tarafından etkinleştirilen SQL Server'ı yapılandırma

Şunlar için geçerlidir: SQL Server

Azure Arc özellikli her sunucu, o sunucuda yüklü tüm SQL Server örnekleri için geçerli olan bir özellik kümesi içerir. Makineye SQL Server için Azure Uzantısı yüklendikten sonra bu özellikleri yapılandırabilirsiniz. Ancak, özellikler yalnızca bir SQL Server örneği veya örnekleri yüklüyse geçerlilik kazanır. Azure portalında, Azure Arc tarafından etkinleştirilen SQL Server için Genel Bakış bölmesi, SQL Server yapılandırmasının belirli bir örneği nasıl etkilediğini yansıtır.

Önkoşullar

• Kuruluşunuzun oluşturduğu Azure aboneliklerinden en az birinde Katkıda Bulunan rolünüz vardır. yeni faturalama aboneliği oluşturmayı öğrenin.

• SQL Server'ın bir örneğinin kaydedileceği kaynak grubunda katkıda bulunan rolüne sahipsiniz. Ayrıntılar için bkz. Yönetilen Azure kaynak grupları.

• Microsoft.AzureArcData ve Microsoft.HybridCompute kaynak sağlayıcıları, SQL Server kullandıkça öde faturalaması için kullandığınız her aboneliğe kaydedilir.

Kaynak sağlayıcılarını kaydetme

Kaynak sağlayıcılarını kaydetmek için aşağıdaki yöntemlerden birini kullanın:

Register-AzResourceProvider -ProviderNamespace Microsoft.AzureArcData

az provider register --namespace 'Microsoft.AzureArcData'

SQL Server yapılandırmasını değiştirme

Belirli bir Azure Arc özellikli sunucudaki yapılandırma ayarlarının tümünü veya bazılarını istenen duruma değiştirmek için Azure portalını, Azure PowerShell'i veya Azure CLI'yi kullanabilirsiniz.

Tek bir komutla daha büyük bir kapsama (kaynak grubu, abonelik veya birden çok abonelik gibi) yönelik SQL Server yapılandırmasını değiştirmek için modify-license-type.ps1 PowerShell betiğini kullanın. Açık kaynak SQL Server örneği olarak yayımlanır ve adım adım yönergeler içerir.

Aşağıdakilerden dolayı betiği Azure Cloud Shell'den çalıştırmanızı öneririz:

• Gerekli Azure PowerShell modülleri önceden yüklenmiştir.
• Otomatik olarak kimliğinizi doğrular.

Cloud Shell kullanarak betiği çalıştırma hakkında ayrıntılar için bkz. .

# Updated settings object
$Settings = @{
    SqlManagement = @{ IsEnabled = $true };
    ExcludedSqlInstances = @( "Foo", "Bar");
    LicenseType = "PAYG";
    enableExtendedSecurityUpdates = $True;
    esuLastUpdatedTimestamp = [DateTime]::UtcNow.ToString('yyyy-MM-ddTHH:mm:ss.fffZ')
}

# Command stays the same as before; only Settings is changed
New-AzConnectedMachineExtension -Name "WindowsAgent.SqlServer" -ResourceGroupName { your resource group name } -MachineName { your machine name } -Location { azure region } -Publisher "Microsoft.AzureData" -Settings $Settings -ExtensionType "WindowsAgent.SqlServer"

az connectedmachine extension update --machine-name "simple-vm" -g "<resource-group>" --name "WindowsAgent.SqlServer" --type "WindowsAgent.SqlServer" --publisher "Microsoft.AzureData" --settings '{"LicenseType":"PAYG", "SqlManagement": {"IsEnabled":true}}'

Azure İlkesi'ni kullanarak büyük ölçekte Genişletilmiş Güvenlik Güncelleştirmelerine abone olma

ESU aboneliğini birden çok Azure Arc özellikli makinede etkinleştirmek için Uygun Arc özellikli SQL Server örneklerini Genişletilmiş Güvenlik Güncelleştirmelerine aboneadlı bir Azure İlkesi tanımı kullanabilirsiniz.

Bu ilke tanımının atamasını istediğiniz bir kapsama oluşturduğunuzda, SQL Server için Azure Uzantısı'nın yüklü olduğu tüm Azure Arc özellikli makinelerde ESU'ları etkinleştirir. Bu makinelerden herhangi birinin nitelikli bir SQL Server örneği varsa, ESU aboneliği hemen etkinleştirilir.

Bu ilkeyi etkinleştirmek için aşağıdaki adımları kullanın:

1. Azure portalında Azure İlkesigidin ve ardındanTanımları'nı seçin.

2. Uygun Arc özellikli SQL Server örneklerini Genişletilmiş Güvenlik Güncelleştirmelerine abone yapın arayın ve ilkeye sağ tıklayın.

3. İlke ataseçin.

4. Kapsam olarak bir abonelik ve isteğe bağlı olarak bir kaynak grubu seçin.

5. İlke zorlamasının Etkinolarak ayarlandığından emin olun.

6. Parametreleri sekmesinde Genişletilmiş Güvenlik Güncelleştirmelerini Etkinleştir değerini Trueolarak ayarlayın.

7. Düzeltme sekmesinde:

   1. Bu ilkenin var olan kaynaklara uygulanması için düzeltme görevi oluştur seçin. Bu seçeneği belirlemezseniz, ilke yalnızca yeni oluşturulan kaynaklara uygulanır.
   2. Yönetilen KimlikOluştur'u seçin ve ardından SQL Server Dağıtımı için Azure Uzantısı ve Okuyucu izinlerine sahip olan Sistem tarafından atanan yönetilen kimlik (önerilir) veya Kullanıcı tarafından atanan yönetilen kimlikseçin.
   3. Kimliğin konumunu seçin.

8. Gözden Geçir +Oluştur'u seçin.

9. Oluştur'u seçin.

SQL Server yapılandırmasını sorgulama

Azure Kaynak Grafı kullanarak seçilen kapsam içindeki SQL Server yapılandırma ayarlarını sorgulayabilirsiniz. Aşağıdaki örneklere bakın.

Lisans türüne göre sayıyı alma

Bu örnek, lisans türüne göre sayıyı döndürür:

resources
| where type == "microsoft.hybridcompute/machines/extensions"
| where properties.type in ("WindowsAgent.SqlServer","LinuxAgent.SqlServer")
| extend licenseType = iff(properties.settings.LicenseType == '', 'Configuration needed', properties.settings.LicenseType)
| summarize count() by tostring(licenseType)

Lisans türünün tanımsız olduğu örnekleri tanımlama

Bu sorgu, lisans türünün nullolduğu örneklerin listesini döndürür:

resources
| where type == "microsoft.hybridcompute/machines/extensions"
| where properties.type in ("WindowsAgent.SqlServer","LinuxAgent.SqlServer")
| where isnull(properties.settings.LicenseType)
| project ['id'], resourceGroup, subscriptionId

Her SQL Server örneği için yapılandırma ayrıntılarını listeleme

Bu sorgu lisans türü, ESU ayarı ve etkinleştirilmiş özellikler dahil olmak üzere her örnekle ilgili birçok ayrıntıyı tanımlar:

resources
| where type == "microsoft.hybridcompute/machines"
| where properties.detectedProperties.mssqldiscovered == "true"
| extend machineIdHasSQLServerDiscovered = id
| project name, machineIdHasSQLServerDiscovered, resourceGroup, subscriptionId
| join kind= leftouter (
    resources
    | where type == "microsoft.hybridcompute/machines/extensions"    | where properties.type in ("WindowsAgent.SqlServer","LinuxAgent.SqlServer")
    | extend machineIdHasSQLServerExtensionInstalled = iff(id contains "/extensions/WindowsAgent.SqlServer" or id contains "/extensions/LinuxAgent.SqlServer", substring(id, 0, indexof(id, "/extensions/")), "")
    | project Extension_State = properties.provisioningState,
    License_Type = properties.settings.LicenseType,
    ESU = iff(notnull(properties.settings.enableExtendedSecurityUpdates), iff(properties.settings.enableExtendedSecurityUpdates == true,"enabled","disabled"), ""),
    Extension_Version = properties.instanceView.typeHandlerVersion,
    Excluded_instances = properties.ExcludedSqlInstances,
    Purview = iff(notnull(properties.settings.ExternalPolicyBasedAuthorization),"enabled",""),
    Entra = iff(notnull(properties.settings.AzureAD),"enabled",""),
    BPA = iff(notnull(properties.settings.AssessmentSettings),"enabled",""),
    machineIdHasSQLServerExtensionInstalled)on $left.machineIdHasSQLServerDiscovered == $right.machineIdHasSQLServerExtensionInstalled
| where isnotempty(machineIdHasSQLServerExtensionInstalled)
| project-away machineIdHasSQLServerDiscovered, machineIdHasSQLServerExtensionInstalled

SQL Server örnekleriyle Azure Arc özellikli sunucuları listeleme

Bu sorgu, üzerinde SQL Server örnekleri bulunan Azure Arc özellikli sunucuları tanımlar:

resources
| where type == "microsoft.hybridcompute/machines"
| where properties.detectedProperties.mssqldiscovered == "true"
//| summarize count()

Bu sorgu SQL Server örnekleri olan Azure Arc özellikli sunucuları döndürür, ancak Azure Arc SQL Server uzantısı yüklenmez. Bu sorgu yalnızca Windows sunucuları için geçerlidir.

resources
| where type == "microsoft.hybridcompute/machines"
| where properties.detectedProperties.mssqldiscovered == "true"
| project machineIdHasSQLServerDiscovered = id
| join kind= leftouter (
    resources
    | where type == "microsoft.hybridcompute/machines/extensions"
    | where properties.type == "WindowsAgent.SqlServer"
    | project machineIdHasSQLServerExtensionInstalled = substring(id, 0, indexof(id, "/extensions/WindowsAgent.SqlServer")))
on $left.machineIdHasSQLServerDiscovered == $right.machineIdHasSQLServerExtensionInstalled
| where isempty(machineIdHasSQLServerExtensionInstalled)
| project machineIdHasSQLServerDiscoveredButNotTheExtension = machineIdHasSQLServerDiscovered

Azure Kaynak Grafı sorguları hakkında daha fazla örnek için bkz. Starter Kaynak Grafı sorgu örnekleri.

ESU'lara abone olan Azure Arc özellikli SQL Server örneklerini listeleme

Aşağıdaki örnek, tüm uygun SQL Server 2012 (11.x) veya SQL Server 2014 (12.x) örneklerini ve bunların ESU abonelik durumunu nasıl görüntüleyebileceğinizi gösterir:

resources
| where type == 'microsoft.azurearcdata/sqlserverinstances'
| extend Version = properties.version
| extend Edition = properties.edition
| extend containerId = tolower(tostring (properties.containerResourceId))
| where Version in ("SQL Server 2012", "SQL Server 2014")
| where Edition in ("Enterprise", "Standard")
| where isnotempty(containerId)
| project containerId, SQL_instance = name, Version, Edition
| join kind=inner (
    resources
    | where type == "microsoft.hybridcompute/machines"
    | extend machineId = tolower(tostring(id))
    | project machineId, Machine_name = name
)
on $left.containerId == $right.machineId
| join kind=inner (
    resources
    | where type == "microsoft.hybridcompute/machines/extensions"
    | where properties.type in ("WindowsAgent.SqlServer","LinuxAgent.SqlServer")
    | extend machineIdHasSQLServerExtensionInstalled = tolower(iff(id contains "/extensions/WindowsAgent.SqlServer" or id contains "/extensions/LinuxAgent.SqlServer", substring(id, 0, indexof(id, "/extensions/")), ""))
    | project machineIdHasSQLServerExtensionInstalled,
     Extension_State = properties.provisioningState, 
     License_Type = properties.settings.LicenseType, 
     ESU = iff(notnull(properties.settings.enableExtendedSecurityUpdates), iff(properties.settings.enableExtendedSecurityUpdates == 'true',"ENABLED","disabled"), "disabled"),
     Extension_Version = properties.instanceView.typeHandlerVersion
)
on $left.machineId == $right.machineIdHasSQLServerExtensionInstalled
| project-away machineId, containerId, machineIdHasSQLServerExtensionInstalled

Faturalanabilir bir SQL Server örneğini barındıran Azure Arc özellikli sunucuları listeleme

Bu sorgu, SQL Server örneklerini barındıran ve faturalanabilir veya SQL Server yazılımı için lisans gerektiren bağlı makineleri (sanal veya fiziksel) tanımlar. Lisans türü, ESU ayarı, sanal çekirdek veya p çekirdek boyutu ve diğer ilgili parametreler de dahil olmak üzere SQL Server yapılandırmasının ayrıntılarını sağlar.

resources
| where type =~ 'Microsoft.HybridCompute/machines'
| extend status = tostring(properties.status)
| where status =~ 'Connected'
| extend machineID = tolower(id)
| extend VMbyManufacturer = toboolean(iff(properties.detectedProperties.manufacturer in (
        "VMware",
        "QEMU",
        "Amazon EC2",
        "OpenStack",
        "Hetzner",
        "Mission Critical Cloud",
        "DigitalOcean",
        "UpCloud",
        "oVirt",
        "Alibaba",
        "KubeVirt",
        "Parallels",
        "XEN"
    ), 1, 0))
| extend VMbyModel = toboolean(iff(properties.detectedProperties.model in (
        "OpenStack",
        "Droplet",
        "oVirt",
        "Hypervisor",
        "Virtual",
        "BHYVE",
        "KVM"
    ), 1, 0))
| extend GoogleVM = toboolean(iff((properties.detectedProperties.manufacturer =~ "Google") and (properties.detectedProperties.model =~ "Google Compute Engine"), 1, 0))
| extend NutanixVM = toboolean(iff((properties.detectedProperties.manufacturer =~ "Nutanix") and (properties.detectedProperties.model =~ "AHV"), 1, 0))
| extend MicrosoftVM = toboolean(iff((properties.detectedProperties.manufacturer =~ "Microsoft Corporation") and (properties.detectedProperties.model =~ "Virtual Machine"), 1, 0))
| extend billableCores = iff(VMbyManufacturer or VMbyModel or GoogleVM or NutanixVM or MicrosoftVM, properties.detectedProperties.logicalCoreCount, properties.detectedProperties.coreCount)
| join kind = leftouter // Join the extension
        (
        resources
        | where type =~ 'Microsoft.HybridCompute/machines/extensions'
        | where name == 'WindowsAgent.SqlServer' or name == 'LinuxAgent.SqlServer'
        | extend extMachineID = substring(id, 0, indexof(id, '/extensions'))
        | extend extensionId = id
        )
        on $left.id == $right.extMachineID
        | join kind = inner       // Join SQL Server instances
            (
            resources
            | where type =~ 'microsoft.azurearcdata/sqlserverinstances'
            | extend sqlVersion = tostring(properties.version)
            | extend sqlEdition = tostring(properties.edition)
            | extend is_Enterprise = toint(iff(sqlEdition == "Enterprise", 1, 0))
            | extend sqlStatus = tostring(properties.status)
            | extend licenseType = tostring(properties.licenseType)
            | where sqlEdition in ('Enterprise', 'Standard')
            | where licenseType !~ 'HADR'
            | extend ArcServer = tolower(tostring(properties.containerResourceId))
            | order by sqlEdition
            )
            on $left.machineID == $right.ArcServer
            | where isnotnull(extensionId)
            | summarize Edition = iff(sum(is_Enterprise) > 0, "Enterprise", "Standard") by machineID
            , name
            , resourceGroup
            , subscriptionId
            , Status = tostring(properties.status)
            , Model = tostring(properties.detectedProperties.model)
            , Manufacturer = tostring(properties.detectedProperties.manufacturer)
            , License_Type = tostring(properties1.settings.LicenseType)
            , ESU = iff(notnull(properties1.settings.enableExtendedSecurityUpdates), iff(properties1.settings.enableExtendedSecurityUpdates == true,"enabled","not enabled"), "not enabled")
            , OS = tostring(properties.osName)
            , Uses_UV = tostring(properties1.settings.UsePhysicalCoreLicense.IsApplied)
            , Cores = tostring(billableCores)
            , Version = sqlVersion
            | summarize by name, subscriptionId, resourceGroup, Model, Manufacturer, License_Type, ESU, OS, Cores, Status
            | project Name = name, Model, Manufacturer, OperatingSystem = OS, Status, HostLicenseType = License_Type, ESU, BillableCores = Cores, SubscriptionID = subscriptionId, ResourceGroup = resourceGroup
            | order by Name asc

SQL Server için sınırsız sanallaştırma avantajını yönetme

Sınırsız sanallaştırmayı etkinleştirmek için Azure Arc tarafından etkinleştirilen SQL Server özel bir kaynak türünü destekler: SQLServerLicense. Bu kaynağı, yüklü SQL Server örnekleriyle birçok sanal makinenin lisansını almak için kullanabilirsiniz. Lisanslama modeli hakkında ayrıntılı bilgi için bkz. Sınırsız Sanallaştırma ile SQL Server Örneklerini Lisanslama.

Önkoşullar

Rol tabanlı erişim denetimi (RBAC) rolünüz aşağıdaki izinleri içerir:

• Microsoft.AzureArcData/SqlLicenses/read
• Microsoft.AzureArcData/SqlLicenses/write
• Microsoft.Management/managementGroups/read
• Microsoft.Resources/subscriptions/read
• Microsoft.Resources/subscriptions/resourceGroups/read
• Microsoft.Support/supporttickets/write

SQL Server lisansı oluşturma

SQL Server lisans kaynağı oluşturmak için aşağıdaki yöntemlerden birini kullanın:

$subscriptionId="<sub id>"
$apiVersion="2024-03-01-preview"
$templateFile="sqlserverlicense.json"

$resourceGroupName="<rg-name>"
$uri = "https://management.azure.com/subscriptions/{0}/resourceGroups/{1}/providers/Microsoft.AzureArcData/sqlserverlicenses/{2}?api-version={3}" -f $subscriptionId, $resourceGroupName, $serverName, $apiVersion

az rest --method put --uri "$uri" --body "@$templateFile" --headers "Content-Type=application/json"

"location": "westeurope",
"properties": {
    "billingPlan": "PAYG",
    "physicalCores": 32,
    "activationState": "Deactivated",
    "scopeType": "ResourceGroup",
    "licenseCategory": "Core"
}

SQL Server lisans kaynağını güncelleştirme

SQL Server lisans özelliğini değiştirmek için (örneğin, daha sonraki bir tarihte etkinleştirin), aşağıdaki yöntemlerden birini kullanın:

$subscriptionId="<sub id>"
$apiVersion="2024-03-01-preview"
$templateFile="activate.json"

$resourceGroupName="<rg-name>"
$uri = "https://management.azure.com/subscriptions/{0}/resourceGroups/{1}/providers/Microsoft.AzureArcData/sqlserverlicenses/{2}?api-version={3}" -f $subscriptionId, $resourceGroupName, $serverName, $apiVersion

az rest --method patch --uri "$uri" --body "@$templateFile" --headers "Content-Type=application/json"

{
  "activationState": "Activated"
}

P-core lisansı kapsamındaki kaynakları yönetme

Aşağıdaki adımları kullanarak belirli bir SQL Server fiziksel çekirdek lisansı kapsamındaki kaynakları yönetebilirsiniz:

Azure Arc özellikli sunucuları SQL Server lisansı kapsamında listeleme

Bu sorgu, lisans kapsamındaki tüm Azure Arc özellikli sunucuları ve her birinin ilgili özelliklerini listeler:

resources
        | where type =~ 'Microsoft.HybridCompute/machines'
        | where ('${scopeType}'!= 'Subscription' or subscriptionId == '${subscription}')
        | where ('${scopeType}' != 'ResourceGroup' or (resourceGroup == '${resourceGroup.toLowerCase()}' and subscriptionId == '${subscription}'))
        | extend status = tostring(properties.status)
        | where status =~ 'Connected'
        | join kind = leftouter
        (
        resources
        | where type =~ 'Microsoft.HybridCompute/machines/extensions'
        | where name == 'WindowsAgent.SqlServer' or name == 'LinuxAgent.SqlServer'
        | extend machineId = substring(id, 0, indexof(id, '/extensions'))
        | extend extensionId = id
        )
        on $left.id == $right.machineId
        | where isnotnull(extensionId)
        | project id, name, properties.status, resourceGroup, subscriptionId, Model = properties.detectedProperties.model, Manufacturer = properties.detectedProperties.manufacturer, kind, OSE = properties.osName, License_applied = properties1.settings.UsePhysicalCoreLicense.IsApplied
        |order by name asc

SQL Server ESU aboneliği için sınırsız sanallaştırma avantajını yönetme

ESU aboneliğinde sınırsız sanallaştırmayı etkinleştirmek için, Azure Arc tarafından etkinleştirilen SQL Server özel bir kaynak türünü destekler: SQLServerEsuLicense. Destek dışı SQL Server örneklerini çalıştıran sınırsız sayıda sanal makineye sahip bir dizi fiziksel konak için ESU aboneliğini etkinleştirmek için bu kaynağı kullanabilirsiniz. Lisanslama modeli hakkında ayrıntılı bilgi için bkz. sınırsız sanallaştırmafiziksel çekirdek kullanarak SQL Server ESU'larına abone olma .

Önkoşullar

RBAC rolünüz aşağıdaki izinleri içerir:

• Microsoft.AzureArcData/SqlLicenses/read
• Microsoft.AzureArcData/SqlLicenses/write
• Microsoft.Management/managementGroups/read
• Microsoft.Resources/subscriptions/read
• Microsoft.Resources/subscriptions/resourceGroups/read
• Microsoft.Support/supporttickets/write

SQL Server ESU lisans kaynağı oluşturma

SQL Server ESU lisans kaynağı oluşturmak için aşağıdaki yöntemlerden birini kullanın:

$subscriptionId="<sub id>"
$apiVersion="2024-03-01-preview"
$templateFile="sqlserverlicense.json"

$resourceGroupName="<rg-name>"
$uri = "https://management.azure.com/subscriptions/{0}/resourceGroups/{1}/providers/Microsoft.AzureArcData/SqlServerEsuLicenses/{2}?api-version={3}" -f $subscriptionId, $resourceGroupName, $serverName, $apiVersion

az rest --method put --uri "$uri" --body "@$templateFile" --headers "Content-Type=application/json"

"location": "westeurope",
"properties": {
    "billingPlan": "PAYG",
    "physicalCores": 32,
    "activationState": "Active",
    "scopeType": "ResourceGroup",
    "version": "2014"
}

SQL Server ESU lisans kaynağını güncelleştirme

SQL Server ESU lisans özelliklerini değiştirmek (örneğin, aboneliği sonlandırmak) için aşağıdaki yöntemlerden birini kullanın:

$subscriptionId="<sub id>"
$apiVersion="2024-03-01-preview"
$templateFile="terminate.json"

$resourceGroupName="<rg-name>"
$uri = "https://management.azure.com/subscriptions/{0}/resourceGroups/{1}/providers/Microsoft.AzureArcData/SqlServerEsuLicenses/{2}?api-version={3}" -f $subscriptionId, $resourceGroupName, $serverName, $apiVersion

az rest --method patch --uri "$uri" --body "@$templateFile" --headers "Content-Type=application/json"

{
  "activationState": "Terminated"
}

ESU p-core lisansı kapsamındaki kaynakları yönetme

Aşağıdaki adımları kullanarak belirli bir SQL Server ESU lisansı kapsamındaki kaynakları yönetebilirsiniz:

Azure Arc özellikli sunucuları SQL Server ESU lisansı kapsamında listeleme

Bu sorgu, lisans kapsamındaki tüm Azure Arc özellikli sunucuları ve her birinin ilgili özelliklerini listeler:

resources
        | where type =~ 'Microsoft.HybridCompute/machines'
        | where ('${scopeType}'!= 'Subscription' or subscriptionId == '${subscription}')
        | where ('${scopeType}' != 'ResourceGroup' or (resourceGroup == '${resourceGroup.toLowerCase()}' and subscriptionId == '${subscription}'))
        | extend status = tostring(properties.status)
        | where status =~ 'Connected'
        | join kind = leftouter
        (
        resources
        | where type =~ 'Microsoft.HybridCompute/machines/extensions'
        | where name == 'WindowsAgent.SqlServer' or name == 'LinuxAgent.SqlServer'
        | extend machineId = substring(id, 0, indexof(id, '/extensions'))
        | extend extensionId = id
        )
        on $left.id == $right.machineId
        | where isnotnull(extensionId)
        | project id, name, properties.status, resourceGroup, subscriptionId, Model = properties.detectedProperties.model, Manufacturer = properties.detectedProperties.manufacturer, kind, OSE = properties.osName, License_applied = properties1.settings.UseEsuPhysicalCoreLicense.IsApplied
        |order by name asc

İlgili içerik

• Azure Arc tarafından etkinleştirilen SQL Server lisanslama ve faturalamayı yönetme
• SQL Server 2022 fiyatlandırma
• SQL Server yükleme kılavuzu
• SQL Server için Genişletilmiş Güvenlik Güncelleştirmeleri nedir?
• Sık sorulan sorular
• Azure Arc tarafından etkinleştirilen SQL Server için otomatik güncelleştirmeleri yapılandırma