快速入門：使用 Bicep 建立及部署 Azure Functions 資源

在本文中，您會使用 Azure Functions搭配 Bicep，在 Azure 中建立函數應用程式和相關資源。 函數應用程式會為函式程式碼執行提供執行內容。

完成本快速入門後，您的 Azure 帳戶中會產生幾美分或更少的少許費用。

Bicep 是使用宣告式語法來部署 Azure 資源的特定領域語言 (DSL)。 其提供簡潔的語法、可靠的類型安全，並支援程式碼重複使用。 Bicep 能夠為您在 Azure 中的基礎結構即程式碼解決方案，提供最佳的製作體驗。

建立函數應用程式之後，您可以將 Azure Functions 專案程式碼部署至該應用程式。

必要條件

Azure 帳戶

開始之前，您必須擁有具備作用中訂用帳戶的 Azure 帳戶。 免費建立帳戶。

檢閱 Bicep 檔案

此快速入門中使用的 Bicep 檔案是來自 Azure 快速入門範本。

@description('The name of the function app that you wish to create.')
param appName string = 'fnapp${uniqueString(resourceGroup().id)}'

@description('Storage Account type')
@allowed([
  'Standard_LRS'
  'Standard_GRS'
  'Standard_RAGRS'
])
param storageAccountType string = 'Standard_LRS'

@description('Location for all resources.')
param location string = resourceGroup().location

@description('Location for Application Insights')
param appInsightsLocation string

@description('The language worker runtime to load in the function app.')
@allowed([
  'node'
  'dotnet'
  'java'
])
param runtime string = 'node'

var functionAppName = appName
var hostingPlanName = appName
var applicationInsightsName = appName
var storageAccountName = '${uniqueString(resourceGroup().id)}azfunctions'
var functionWorkerRuntime = runtime

resource storageAccount 'Microsoft.Storage/storageAccounts@2022-05-01' = {
  name: storageAccountName
  location: location
  sku: {
    name: storageAccountType
  }
  kind: 'Storage'
  properties: {
    supportsHttpsTrafficOnly: true
    defaultToOAuthAuthentication: true
  }
}

resource hostingPlan 'Microsoft.Web/serverfarms@2021-03-01' = {
  name: hostingPlanName
  location: location
  sku: {
    name: 'Y1'
    tier: 'Dynamic'
  }
  properties: {}
}

resource functionApp 'Microsoft.Web/sites@2021-03-01' = {
  name: functionAppName
  location: location
  kind: 'functionapp'
  identity: {
    type: 'SystemAssigned'
  }
  properties: {
    serverFarmId: hostingPlan.id
    siteConfig: {
      appSettings: [
        {
          name: 'AzureWebJobsStorage'
          value: 'DefaultEndpointsProtocol=https;AccountName=${storageAccountName};EndpointSuffix=${environment().suffixes.storage};AccountKey=${storageAccount.listKeys().keys[0].value}'
        }
        {
          name: 'WEBSITE_CONTENTAZUREFILECONNECTIONSTRING'
          value: 'DefaultEndpointsProtocol=https;AccountName=${storageAccountName};EndpointSuffix=${environment().suffixes.storage};AccountKey=${storageAccount.listKeys().keys[0].value}'
        }
        {
          name: 'WEBSITE_CONTENTSHARE'
          value: toLower(functionAppName)
        }
        {
          name: 'FUNCTIONS_EXTENSION_VERSION'
          value: '~4'
        }
        {
          name: 'WEBSITE_NODE_DEFAULT_VERSION'
          value: '~14'
        }
        {
          name: 'APPINSIGHTS_INSTRUMENTATIONKEY'
          value: applicationInsights.properties.InstrumentationKey
        }
        {
          name: 'FUNCTIONS_WORKER_RUNTIME'
          value: functionWorkerRuntime
        }
      ]
      ftpsState: 'FtpsOnly'
      minTlsVersion: '1.2'
    }
    httpsOnly: true
  }
}

resource applicationInsights 'Microsoft.Insights/components@2020-02-02' = {
  name: applicationInsightsName
  location: appInsightsLocation
  kind: 'web'
  properties: {
    Application_Type: 'web'
    Request_Source: 'rest'
  }
}

此 Bicep 檔案會建立下列四個 Azure 資源：

• Microsoft.Storage/storageAccounts：建立 Functions 所需的 Azure 儲存體帳戶。
• Microsoft.Web/serverfarms：為函式應用程式建立無伺服器使用量主控方案。
• Microsoft.Web/sites：建立函式應用程式。
• microsoft.insights/components：建立用於監視的 Application Insights 執行個體。

部署 Bicep 檔案

1. 將 Bicep 檔案以 main.bicep 儲存至本機電腦。

2. 使用 Azure CLI 或 Azure PowerShell 部署 Bicep 檔案。

   • CLI
   • PowerShell

   az group create --name exampleRG --location eastus
   az deployment group create --resource-group exampleRG --template-file main.bicep --parameters appInsightsLocation=<app-location>
   

   注意

   將<應用程式位置>取代為 Application Insights 的區域，這通常與資源群組相同。

   當部署完成時，您應該會看到指出部署成功的訊息。

驗證部署

使用 Azure CLI 或 Azure PowerShell 驗證部署。

az resource list --resource-group exampleRG

Get-AzResource -ResourceGroupName exampleRG

前往函數應用程式歡迎頁面

1. 使用上一個驗證步驟的輸出，擷取為函數應用程式所建立的唯一名稱。

2. 開啟瀏覽器並輸入下列 URL：<https://<appName.azurewebsites.net>。 請務必使用為函數應用程式建立的唯一名稱取代 <\appName>。

   當您前往該 URL 時，應會看到類似如下的頁面：

   

清除資源

如果您要繼續進行下一個步驟並新增 Azure 儲存體佇列輸出繫結，請保留您所有的資源，因為在後續的工作還會用到。

否則，如果您不再需要資源，請使用 Azure CLI、PowerShell 或 Azure 入口網站來刪除資源群組及其資源。

az group delete --name exampleRG

Remove-AzResourceGroup -Name exampleRG

下一步

現在您已在 Azure 中建立函數應用程式資源，您即可使用下列其中一個工具將程式碼部署至現有的應用程式：

• Visual Studio Code
• Visual Studio
• Azure Functions Core Tools