共用方式為

ISINSCOPE

  • 發行項

適用於：導出數據行計算數據表Measure視覺計算

當指定的數據行是層級階層中的層級時，傳回 true。

語法

ISINSCOPE(<columnName>)

參數

術語 定義
columnName 使用標準 DAX 語法的現有數據行名稱。 它不能是表達式。

傳回 value

當指定的數據行是層級階層中的層級時，TRUE。

言論

在匯出數據行中使用 not 數據列層級安全性 （RLS） 規則時，支援此函式 or 用於 DirectQuery 模式。

例

DEFINE
MEASURE FactInternetSales[% of Parent] =
  SWITCH (TRUE(),
    ISINSCOPE(DimProduct[Subcategory]),
      DIVIDE(
        SUM(FactInternetSales[Sales Amount]),
        CALCULATE(
          SUM(FactInternetSales[Sales Amount]),
          ALLSELECTED(DimProduct[Subcategory]))
      ),
    ISINSCOPE(DimProduct[Category]),
      DIVIDE(
        SUM(FactInternetSales[Sales Amount]), 
        CALCULATE(
          SUM(FactInternetSales[Sales Amount]),
          ALLSELECTED(DimProduct[Category]))
      ),
    1
  ) * 100
EVALUATE
  SUMMARIZECOLUMNS
  (
    ROLLUPADDISSUBTOTAL
    (
      DimProduct[Category], "Category Subtotal",
      DimProduct[Subcategory], "Subcategory Subtotal"
    ),
    TREATAS(
      {"Bike Racks", "Bike Stands", "Mountain Bikes", "Road Bikes", "Touring Bikes"},
      DimProduct[Subcategory]),
    "Sales", SUM(FactInternetSales[Sales Amount]),
    "% of Parent", [% of Parent]
  )
  ORDER BY
    [Category Subtotal] DESC, [Category],
    [Subcategory Subtotal] DESC, [Subcategory]

返回

DimProduct[Category] DimProduct[SubCategory] [類別小計] [子類別小計] [Sales] [ parent 的%]
TRUE TRUE 28,397,095.65 100.00
輔料 FALSE TRUE 78,951.00 0.28
輔料 自行車機架 FALSE FALSE 39,360.00 49.85
輔料 自行車看臺 FALSE FALSE 39,591.00 50.15
自行車 FALSE TRUE 28,318,144.65 99.72
自行車 山地自行車 FALSE FALSE 9,952,759.56 35.15
自行車 公路自行車 FALSE FALSE 14,520,584.04 51.28
自行車 旅遊自行車 FALSE FALSE 3,844,801.05 13.58

Related 內容

SUMMARIZECOLUMNS 函式CALCULATE 函式