共用方式為

array_sort_asc()

  • 發行項

適用於：✅Microsoft網狀架構✅Azure 數據✅總管 Azure 監視器✅Microsoft Sentinel

接收一或多個陣列。 以遞增順序排序第一個數位列。 排序其餘陣列以符合重新排序的第一個陣列。

語法

array_sort_asc(array1[， ...， arrayN][, nulls_last])

如果未 提供nulls_last ，則會使用的預設值 true 。

深入瞭解 語法慣例。

參數

姓名 類型​​ 必要 描述
array1...arrayN dynamic ✔️ 要排序的陣列或陣列清單。
nulls_last bool 判斷 是否 null應是最後一個。

傳回

傳回與輸入中相同的陣列數目，第一個陣列會以遞增順序排序，而剩餘的陣列會排序以符合重新排序的第一個數位。

null 會針對長度與第一個數位不同的每個數位傳回 。

如果陣列包含不同類型的元素，則會依下列順序排序：

  • 數值、 datetime、 和 timespan 元素
  • 字串元素
  • Guid 元素
  • 所有其他元素

範例 1 - 排序兩個陣列

let array1 = dynamic([1,3,4,5,2]);
let array2 = dynamic(["a","b","c","d","e"]);
print array_sort_asc(array1,array2)

輸出

array1_sorted array2_sorted
[1,2,3,4,5] [“a”，“e”，“b”，“c”，“d”]

注意

輸出數據行名稱會根據函式的自變數自動產生。 若要將不同的名稱指派給輸出資料列，請使用下列語法： ... | extend (out1, out2) = array_sort_asc(array1,array2)

範例 2 - 排序子字串

let Names = "John,Paul,George,Ringo";
let SortedNames = strcat_array(array_sort_asc(split(Names, ",")), ",");
print result = SortedNames

輸出

result
喬治，約翰，保羅，林戈

範例 3 - 合併摘要和array_sort_asc

datatable(command:string, command_time:datetime, user_id:string)
[
    'chmod',   datetime(2019-07-15),   "user1",
    'ls',      datetime(2019-07-02),   "user1",
    'dir',     datetime(2019-07-22),   "user1",
    'mkdir',   datetime(2019-07-14),   "user1",
    'rm',      datetime(2019-07-27),   "user1",
    'pwd',     datetime(2019-07-25),   "user1",
    'rm',      datetime(2019-07-23),   "user2",
    'pwd',     datetime(2019-07-25),   "user2",
]
| summarize timestamps = make_list(command_time), commands = make_list(command) by user_id
| project user_id, commands_in_chronological_order = array_sort_asc(timestamps, commands)[1]

輸出

user_id commands_in_chronological_order
user1 [
“ls”，
“mkdir”，
“chmod”，
“dir”，
“pwd”，
“rm”
]
user2 [
“rm”，
“pwd”
]

注意

如果您的數據可能包含 null 值，請使用 make_list_with_nulls ， 而不是make_list。

範例 4 - 控制值的位置null

根據預設， null 值會放在排序數位的最後一個。 不過，您可以將值新增為 的最後一個 bool 自變數， array_sort_asc()以明確控制它。

具有預設行為的範例：

print array_sort_asc(dynamic([null,"blue","yellow","green",null]))

輸出

print_0
[“blue”，“green”，“yellow”，null，null]

具有非預設行為的範例：

print array_sort_asc(dynamic([null,"blue","yellow","green",null]), false)

輸出

print_0
[null，null，“blue”，“green”，“yellow”]

相關內容

若要以遞減順序排序第一個陣列，請使用 array_sort_desc（）。