共用方式為

geo_azimuth()

  • 發行項

適用於：✅Microsoft網狀架構✅Azure 數據✅總管 Azure 監視器✅Microsoft Sentinel

計算從point1到 true 北線與從point1到地球 point2 之間的順時針角度。

語法

geo_azimuth(,p1_longitude p1_latitude,p2_longitude p2_latitude,)

深入瞭解 語法慣例。

參數

姓名 類型​​ 必要 描述
p1_longitude real ✔️ 第一個地理空間座標的經度值。 有效的值位於範圍 [-180， +180]。
p1_latitude real ✔️ 第一個地理空間座標的緯度值。 有效的值位於範圍 [-90， +90]。
p2_longitude real ✔️ 第二個地理空間座標的經度值。 有效的值位於範圍 [-180， +180]。
p2_latitude real ✔️ 第二個地理空間座標的緯度值。 有效的值位於範圍 [-90， +90]。

傳回

從點 p1 到 true 北線與線條 [p1， p2] 之間的弧度角度。 角度會順時針測量。

注意

  • 地理空間座標會解譯為 WGS-84 座標參考系統所代表。
  • 用來測量地球上距離的 地緣日期 是球體。 線條邊緣是 球體上的地理區域 。
  • 阿齊穆斯北 0 分。 阿齊穆斯皮/2 點東。 阿齊穆特·皮指向南。 阿齊穆斯 3Pi/2 點西部。
  • 如果座標無效，查詢將會產生 Null 結果。
  • 如果 point1 等於 point2，查詢將會產生 Null 結果。
  • 如果 point1 和 point2 為反腳架，查詢將會產生 Null 結果。

範例

下列範例會以弧度計算 azimuth。

print azimuth_in_radians = geo_azimuth(5, 10, 10, -40)

輸出

azimuth_in_radians
3.05459939796449

下列範例會以度為單位計算 azimuth。

let azimuth_in_radians = geo_azimuth(5, 10, 10, -40);
print azimuth_in_degrees = degrees(azimuth_in_radians);

輸出

azimuth_in_degrees
175.015653606568

下列範例會考慮在貨車行駛時發出其位置遙測，並尋找其行進方向。

let get_direction = (azimuth:real)
{
    let pi = pi();
    iff(azimuth < pi/2,   "North-East",
    iff(azimuth < pi,     "South-East",
    iff(azimuth < 3*pi/2, "South-West",
                          "North-West")));
};
datatable(timestamp:datetime, lng:real, lat:real)
[
    datetime(2024-01-01T00:01:53.048506Z), -115.4036607693417, 36.40551631046261,
    datetime(2024-01-01T00:02:53.048506Z), -115.3256807623232, 36.34102142760111,
    datetime(2024-01-01T00:03:53.048506Z), -115.2732290602112, 36.28458914829917,
    datetime(2024-01-01T00:04:53.048506Z), -115.2513186233914, 36.27622394664352,
    datetime(2024-01-01T00:05:53.048506Z), -115.2352055633212, 36.27545547038515,
    datetime(2024-01-01T00:06:53.048506Z), -115.1894341934856, 36.28266934431671,
    datetime(2024-01-01T00:07:53.048506Z), -115.1054318118468, 36.28957085435267,
    datetime(2024-01-01T00:08:53.048506Z), -115.0648614339413, 36.28110743285072,
    datetime(2024-01-01T00:09:53.048506Z), -114.9858032867736, 36.29780696509714,
    datetime(2024-01-01T00:10:53.048506Z), -114.9016966527561, 36.36556196813566,
]
| sort by timestamp asc 
| extend prev_lng = prev(lng), prev_lat = prev(lat)
| where isnotnull(prev_lng) and isnotnull(prev_lat)
| extend direction = get_direction(geo_azimuth(prev_lng, prev_lat, lng, lat))
| project direction, lng, lat
| render scatterchart with (kind = map)

輸出

連續兩個位置之間的 Azimuth。

下列範例會傳 true 回 ，因為第一個點等於第二個點。

print is_null = isnull(geo_azimuth(5, 10, 5, 10))

輸出

is_null
true