標準日期和時間格式字串

標準日期和時間格式字串會使用單一字元做為格式規範，以定義時間和日期值的文字表示。 包含多個字元的任何日期和時間格式字串，包括空格符，會解譯為 自定義日期和時間格式字串。 標準或自定義格式字串可用來定義格式化作業所產生的文字表示。

格式規範的表格

下表描述標準日期和時間的格式規範。

標準格式字串的運作方式

在格式化作業中，標準格式字串只是自訂格式字串的別名。 使用別名來表示自訂格式字串的好處是，儘管別名保持不變，自訂格式字串本身則可有變化。 這點非常重要，因為日期和時間值的字串表示通常會因文化特性而不同。 例如，"d" 標準格式字串表示日期和時間值將使用簡短日期模式顯示。 在不因文化特性而異 (Invariant Culture) 的情況下，此模式為 "MM/dd/yyyy"。 若為 fr-FR 文化特性，則是 "dd/MM/yyyy"。 若為 ja-JP 文化特性，則是 "yyyy/MM/dd"。

如果格式化作業中的標準格式字串對應至特定文化特性的自訂格式字串，您的應用程式可以定義特定文化特性，以下列其中一種方式使用自訂格式字串：

• 您可以使用預設 (或目前的) 文化特性。 下列範例顯示的日期使用了目前文化特性的簡短日期格式。 在此例中，目前的文化特性是 en-US。

  let
      Source =
      {
          Date.ToText(#date(2024, 3, 15), [Format = "d"])
          //Displays 3/15/2024
      }
  in
      Source
  

• 您可以根據該特定文化特性的規則傳遞用來格式化日期的文化特性。 下列範例顯示的日期使用了 pt-BR 文化特性的簡短日期格式。

  let
      Source =
      {
          Date.ToText(#date(2024, 3, 15), [Format = "d", Culture = "pt-BR"])
          //Displays 15/03/2024
     }
  in
      Source
  

在某些情況下，標準格式字串可做為不變之長自訂格式字串的簡便縮寫。 有四個標準格式字串屬於此分類："O" (或 "o")、"R" (或 "r")、"s" 和 "u"。 這些字串相當於不因文化特性而異所定義的自訂格式字串。 它們針對日期和時間值所產生的字串表示在各文化特性中都相同。 下表提供這四種標準日期和時間格式字串的相關資訊。

標準格式字串也可用於剖析作業，這需要輸入字串完全符合特定模式，剖析作業才能成功。 許多標準格式字串會對應至多個自定義格式字串，因此日期和時間值可以用各種格式表示，剖析作業仍會成功。

下列各節說明 Date、DateTime、DateTimeZone 和 Time 值的標準格式規範。

日期格式

此群組包含下列格式：

• 簡短日期 （“d”） 格式規範
• 完整日期 （“D”） 格式規範

簡短日期 ("d")

“d” 標準格式規範代表由特定文化特性定義的自定義日期格式。 例如，非變異文化特性傳回的自定義格式文字是 「MM/dd/yyyy」。。

下列範例使用 「d」 格式規範來顯示日期值。

let
    Source =
    {
        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = ""]),
        // Displays 04/10/2024

        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = "en-US"]),
        // Displays 4/10/2024

        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = "en-NZ"]),
        // Displays 10/4/2024

        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = "de-DE"])
        // Displays 10.4.2024
    }
in
    Source

回到表格

完整日期 ("D") 格式規範

“D” 標準格式規範代表由特定文化特性定義的自定義日期格式。 例如，不因文化特性而異的自訂格式字串為 "dddd, dd MMMM yyyy"。

下列範例使用 "D" 格式規範來顯示日期和時間值。

let
    Source =
    {
        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = ""]),
        // Displays Wednesday, 10 April, 2024

        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = "en-US"]),
        // Displays Wednesday, April 10, 2024

        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = "pt-BR"]),
        // Displays quarta-feira, 10 de abril de 2024

        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = "es-MX"])
        // Displays miércoles, 10 de abril de 2024
    }
in
    Source

回到表格

日期和時間格式

此群組包含下列格式：

• 完整日期短時間 （“f”） 格式規範
• 完整日期長時間 （“F”） 格式規範
• 一般日期短時間 （“g”） 格式規範
• 一般日期長時間 （“G”） 格式規範
• 來回行程 （“O”， “o”） 格式規範
• RFC1123 （“R”， “r”） 格式規範
• 可排序的格式規範
• 通用可排序 （“u”） 格式規範

完整日期簡短時間 ("f") 格式規範

"f" 標準格式規範表示完整日期 ("D") 和簡短時間 ("t") 模式的組合，以空格分隔。

結果字串會受到特定文化特性的格式資訊所影響。

下列範例使用 "f" 格式規範來顯示日期和時間值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "f", Culture = "en-US"]),
        // Displays Wednesday, April 10, 2024 6:30 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "f", Culture = "fr-FR"])
        // Displays mercredi 10 avril 2024 06:30
    }
in
    Source

回到表格

完整日期完整時間 ("F") 格式規範

“F” 標準格式規範代表由特定文化特性定義的自定義日期和時間格式。 例如，不因文化特性而異的自訂格式字串為 "dddd, dd MMMM yyyy HH:mm:ss"。

結果字串會受到特定文化特性的格式資訊所影響。

下列範例使用 "F" 格式規範來顯示日期和時間值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "F", Culture = ""]),
        // Displays Wednesday, 10 April, 2024 06:30:00

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "F", Culture = "en-US"]),
        // Displays Wednesday, April 10, 2024 6:30:00 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "F", Culture = "fr-FR"])
        // Displays mercredi 10 avril 2024 06:30:00
    }
in
    Source

回到表格

一般日期簡短時間 ("g") 格式規範

"g" 標準格式規範表示簡短日期 ("d") 和簡短時間 ("t") 模式的組合，以空格分隔。 產生的文字會受到特定文化特性的格式資訊所影響。

結果字串會受到特定文化特性的格式資訊所影響。

下列範例使用 "g" 格式規範來顯示日期和時間值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "g", Culture = ""]),
        // Displays 04/10/2024 06:30

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "g", Culture = "en-US"]),
        // Displays 4/10/2024 6:30 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "g", Culture = "fr-BE"])
        // Displays 10-04-24 06:30
    }
in
    Source

回到表格

一般日期完整時間 ("G") 格式規範

"G" 標準格式規範表示簡短日期 ("d") 和完整時間 ("T") 模式的組合，以空格分隔。 產生的文字會受到特定文化特性的格式資訊所影響。

結果字串會受到特定文化特性的格式資訊所影響。

下列範例使用 "G" 格式規範來顯示日期和時間值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "G", Culture = ""]),
        // Displays 04/10/2024 06:30:00

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "G", Culture = "en-US"]),
        // Displays 4/10/2024 6:30:00 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "G", Culture = "nl-BE"])
        // Displays 10/04/2024 6:30:00
    }
in
    Source

回到表格

來回行程 ("O"、"o") 格式規範

"O" 或 "o" 標準格式規範可表示使用保存時區資訊之模式的自訂日期和時間格式字串，並發出符合 ISO 8601 的結果字串。 對於 DateTimeZone 值，此格式規範是設計來保留文字中的日期、時間和時區值。

“O” 或 “o” 標準格式規範對應於 “yyyy'-'MM'-'dd'T'HH'：'mm'：'ss''。DateTimeZone 值的 fffffffxxx“ 自定義格式字串。 在此文字中，分隔個別字元的單引號組，例如連字元、冒號和字母 「T」，表示個別字元是無法變更的常值。 單引號不會出現在輸出字串中。

“O” 或 “o” 標準格式規範（以及 “yyyy'-'MM'-'dd'T'HH'：'mm'：'ss'' 。fffffffxxx“ 自定義格式） 利用 ISO 8601 代表時區資訊的方式，以保留 DateTimeZone 值：

• DateTimeZone.ToLocal 日期和時間值的時區元件是UTC的位移（例如 +01：00、-07：00）。

• DateTimeZone.ToUtc 日期和時間值的時區元件會使用 +00.00 來表示 UTC。

因為 "O" 或 "o" 標準格式規範符合國際標準，所以使用該規範的格式化或剖析作業一律使用不因國別而異的文化特性和西曆。

下列範例會使用 「o」 格式規範，在美國太平洋時區的系統上顯示一系列 DateTimeZone 值。

let
    date1 = #datetimezone(2024, 6, 15, 13, 45, 30, 0, 0),
    Source =
    {
        Text.Format("#{0} (Unspecified) --> #{1}", {date1, DateTimeZone.ToText(date1, [Format = "O"])}),
        Text.Format("#{0} (Utc) --> #{1}", {date1, DateTimeZone.ToText(DateTimeZone.ToUtc(date1), [Format = "O"])}),
        Text.Format("#{0} (Local) --> #{1}", {date1, DateTimeZone.ToText(DateTimeZone.ToLocal(date1), [Format = "O"])})
    }
in
    Source

// The example displays the following output:
//    6/15/2024 1:45:30 PM +00:00 (Unspecified) --> 2024-06-15T13:45:30.0000000+00:00
//    6/15/2024 1:45:30 PM +00:00 (Utc) --> 2024-06-15T13:45:30.0000000+00:00
//    6/15/2024 1:45:30 PM +00:00 (Local) --> 2024-06-15T08:45:30.0000000-07:00

下列範例會使用 「o」 格式規範來建立格式化字串，然後藉由呼叫日期和時間剖析例程來還原原始日期和時間值。

let
    // Round-trip a local time
    #"Origin Local Date" = DateTimeZone.ToLocal(
        #datetimezone(2024, 4, 10, 6, 30, 0, 0, 0)
    ),
    #"Local Date Text" = DateTimeZone.ToText(
        #"Origin Local Date", [Format = "o"]
    ),
    #"New Local Date" = DateTimeZone.FromText(#"Local Date Text"),
    #"Local Round Trip" = Text.Format(
        "Round-tripped #{0} Local to #{1} Local.", 
        {
            DateTimeZone.ToText(#"Origin Local Date"), 
            DateTimeZone.ToText(#"New Local Date")
        }
    ),

    // Round-trip a UTC time
    #"Origin UTC Date" = DateTimeZone.ToUtc(
        #datetimezone(2024, 4, 12, 9, 30, 0, 0, 0)
    ),
    #"UTC Date Text" = DateTimeZone.ToText(
        #"Origin UTC Date", [Format = "o"]
    ),
    #"New UTC Date" = DateTimeZone.FromText(#"UTC Date Text"),
    #"UTC Round Trip" = Text.Format(
        "Round-tripped #{0} UTC to #{1} UTC.", 
        {
            DateTimeZone.ToText(#"Origin UTC Date"), 
            DateTimeZone.ToText(#"New UTC Date")
        }
    ),

    // Round-trip an 18 hour offset time
    #"Origin Offset Date" = DateTimeZone.ToLocal(
        #datetimezone(2024, 4, 10, 6, 30, 0, 0, 0) + #duration(0, 18, 0, 0)
    ),
    #"Offset Date Text" = DateTimeZone.ToText(
        #"Origin Offset Date", [Format = "o"]
    ),
    #"New Offset Date" = DateTimeZone.FromText(#"Offset Date Text"),
    #"Offset Round Trip" = Text.Format(
        "Round-tripped #{0} to #{1}.", 
        {
            DateTimeZone.ToText(#"Origin Offset Date"), 
            DateTimeZone.ToText(#"New Offset Date")
        }
    ),

    #"Round Trip Results" = 
        {#"Local Round Trip", #"UTC Round Trip", #"Offset Round Trip"}
in
    #"Round Trip Results"

// The example displays the following output in Power Query Desktop:
//    Round-tripped 4/9/2024 11:30:00 PM -07:00 Local to 4/9/2024 11:30:00 PM -07:00 Local.
//    Round-tripped 4/12/2024 9:30:00 AM +00:00 UTC to 4/12/2024 9:30:00 AM +00:00 UTC.
//    Round-tripped 4/10/2024 5:30:00 PM -07:00 to 4/10/2024 5:30:00 PM -07:00.

// The example displays the following output in Power Query Online:
//    Round-tripped 4/10/2024 6:30:00 AM +00:00 Local to 4/10/2024 6:30:00 AM +00:00 Local.
//    Round-tripped 4/12/2024 9:30:00 AM +00:00 UTC to 4/12/2024 9:30:00 AM +00:00 UTC.
//    Round-tripped 4/11/2024 12:30:00 AM +00:00 to 4/11/2024 12:30:00 AM +00:00.

回到表格

RFC1123 ("R"、"r") 格式規範

“R” 或 “r” 標準格式規範代表不是由特定文化特性定義的自定義日期和時間格式字串。 不論所使用的文化特性或提供的格式提供者為何，它一律相同。 自訂格式字串為 "ddd, dd MMM yyyy HH':'mm':'ss 'GMT'"。 使用這個標準格式規範時，格式或剖析作業一律使用不因文化特性而異。

雖然 RFC 1123 標準以國際標準時間表示時間（UTC），但格式化作業不會修改格式化日期和時間的值。 因此，在執行格式化作業之前，您必須先呼叫 DateTimeZone.ToUtc 函式方法，將 DateTime 值轉換成 UTC。

下列範例會使用 「r」 格式規範，在美國太平洋時區的系統上顯示時間和日期值（UTC 落後 7 小時）。

let
    date1 = #datetimezone(2024, 4, 10, 6, 30, 0, -7, 0),
    dateOffset = DateTimeZone.ToUtc(date1),
    Source = 
    {
        DateTimeZone.ToText(date1, [Format = "r"]),
        // Displays Wed, 10 Apr 2024 13:30:00 GMT

        DateTimeZone.ToText(dateOffset, [Format = "r"])
        // Displays Wed, 10 Apr 2024 13:30:00 GMT
    }
in
    Source

回到表格

可排序 ("s") 格式規範

“s” 標準格式規範代表自定義日期和時間格式字串，反映已定義的標準 （ISO 8601），而且是只讀的。 因此，不論所使用的文化特性或提供的格式提供者為何，它一定會是相同的。 自訂格式字串為 "yyyy'-'MM'-'dd'T'HH':'mm':'ss"。 "s" 格式規範的目的在於產生結果字串時，能夠根據日期和時間值，一致地以遞增或遞減順序排序。

使用這個標準格式規範時，格式或剖析作業一律使用不因文化特性而異。

下列範例會使用 「s」 格式規範，在美國太平洋時區的系統上顯示日期和時間值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "s", Culture = "en-US"])
        // Displays 2024-04-10T06:30:00
    }
in
    Source

回到表格

國際可排序 ("u") 格式規範

“u” 標準格式規範代表一律相同的自定義日期和時間格式字串，不論所使用的文化特性或提供的格式提供者為何。 自訂格式字串為 "yyyy'-'MM'-'dd HH':'mm':'ss'Z'"。 此模式反映已定義的標準，且屬性為唯讀。 使用這個標準格式規範時，格式或剖析作業一律使用不因文化特性而異。

雖然結果字串應該以國際標準時間表示時間（UTC），但在格式化作業期間不會執行原始 DateTimeZone 值的轉換。 因此，您必須先呼叫 DateTimeZone.ToUtc 函式，再將 DateTimeZone 值轉換成 UTC，才能格式化它。

下列範例使用 "u" 格式規範來顯示日期和時間值。

let
    date1 = #datetimezone(2024, 4, 10, 6, 30, 0, -7, 0),
    dateOffset = DateTimeZone.ToUtc(date1),
    Source =
    {
        DateTimeZone.ToText(dateOffset, [Format = "u"]),
        // Displays 2024-04-10 13:30:00Z
    }
in
    Source

回到表格

時間格式

此群組包含下列格式：

• 短時間 （“t”） 格式規範
• 長時間 （“T”） 格式規範

簡短時間 ("t") 格式規範

“t” 標準格式規範代表由指定文化特性定義的自定義日期和時間格式字串。 例如，不因文化特性而異的自訂格式字串為 "HH:mm"。

結果字串會受到特定文化特性的格式資訊所影響。

下列範例使用 "t" 格式規範來顯示日期和時間值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "t", Culture = ""]),
        // Displays 06:30
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "t", Culture = "en-US"]),
        // Displays 6:30 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "t", Culture = "es-ES"])
        // Displays 6:30
    }
in
    Source

回到表格

完整時間 ("T") 格式規範

“T” 標準格式規範代表由特定文化特性定義的自定義日期和時間格式字串。 例如，不因文化特性而異的自訂格式字串為 "HH:mm:ss"。

下列範例使用 "T" 格式規範來顯示日期和時間值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "T", Culture = ""]),
        // Displays 06:30:00
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "T", Culture = "en-US"]),
        // Displays 6:30:00 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "T", Culture = "es-ES"])
        // Displays 6:30:00
    }
in
    Source

回到表格

部分日期格式

此群組包含下列格式：

• 月份 （“M”， “m”） 格式規範
• 年月 （“Y”， “y”） 格式規範

月 ("M"、"m") 格式規範

“M” 或 “m” 標準格式規範代表由特定文化特性定義的自定義日期和時間格式字串。 例如，不因文化特性而異的自訂格式字串為 "MMMM dd"。

下列範例使用 "m" 格式規範來顯示日期和時間值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "m", Culture = ""]),
        // Displays April 10
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "m", Culture = "en-US"]),
        // Displays April 10

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "m", Culture = "ms-MY"])
        // Displays 10 April
    }
in
    Source

回到表格

年月 ("Y"、"y") 格式規範

“Y” 或 “y” 標準格式規範代表由特定文化特性定義的自定義日期格式字串。 例如，不因文化特性而異的自訂格式字串為 "yyyy MMMM"。

下列範例使用 "y" 格式規範來顯示日期和時間值。

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "Y", Culture = ""]),
        // Displays 2024 April
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "Y", Culture = "en-US"]),
        // Displays April 2024

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "y", Culture = "af-ZA"])
        // Displays April 2024
    }
in
    Source

回到表格

相關內容

• 文化特性如何影響文字格式設定
• Date、Time、DateTime 和 DateTimeZone 類型轉換
• 日期函式
• 日期時間函式
• DateTimeZone 函式
• 時間函式
• 自訂日期和時間格式字串