ButtonDesigner.GetDesignTimeHtml Méthode

Référence

Définition

Espace de noms:: System.Web.UI.Design.WebControls

Assembly:: System.Design.dll

Important

Certaines informations portent sur la préversion du produit qui est susceptible d’être en grande partie modifiée avant sa publication. Microsoft exclut toute garantie, expresse ou implicite, concernant les informations fournies ici.

Obtient le balisage utilisé pour afficher le contrôle associé au moment de la conception.

public:
 override System::String ^ GetDesignTimeHtml();

public override string GetDesignTimeHtml ();

override this.GetDesignTimeHtml : unit -> string

Public Overrides Function GetDesignTimeHtml () As String

Retours

String

String qui contient le balisage utilisé pour afficher Button au moment de la conception.

Exemples

L’exemple de code suivant montre comment remplacer la GetDesignTimeHtml méthode pour modifier le balisage généré.

Si la BorderStyle propriété n’a pas été définie précédemment (autrement dit, elle a la NotSet valeur de champ), un appel à la GetDesignTimeHtml méthode la définit sur une bordure en pointillés bleus d’une largeur de trois pixels, puis affiche cette bordure sur l’aire de conception. Si la BorderStyle propriété a été définie, les valeurs de propriété de bordure existantes s’affichent.

En règle générale, le GetDesignTimeHtml appelle sa méthode de base, ControlDesigner.GetDesignTimeHtml, qui appelle dans la Control.RenderControl méthode du contrôle associé pour générer le balisage.

' Create a class that derives from ButtonDesigner
' and displays the custom SampleButton control
' on the design surface.
Imports System.Web.UI.Design
Imports System.Drawing
Imports System.ComponentModel
Imports System.Web.UI.WebControls
Imports System.Web.UI.Design.WebControls

Namespace Examples.AspNet 

    
    Public Class SampleButtonDesigner
        Inherits ButtonDesigner

        ' Override the GetDesignTimeHtml method.
        Public Overrides Function GetDesignTimeHtml() As String

            Dim sampleButton As SampleButton = CType(Component, SampleButton)
            Dim designTimeHtml As String = Nothing

            ' Check the control's BorderStyle property
            ' to conditionally render design-time HTML.
            If (sampleButton.BorderStyle = BorderStyle.NotSet) Then

                ' Create variables to hold current property settings.
                Dim oldBorderStyle As BorderStyle = sampleButton.BorderStyle
                Dim oldBorderWidth As Unit = sampleButton.BorderWidth
                Dim oldBorderColor As Color = sampleButton.BorderColor

                ' Set properties and the design-time HTML.
                Try
                    sampleButton.BorderStyle = BorderStyle.Dashed
                    sampleButton.BorderWidth = Unit.Pixel(3)
                    sampleButton.BorderColor = Color.Blue
                    designTimeHtml = MyBase.GetDesignTimeHtml()

                    ' If an exception occurs, call the GetErrorDesignTimeHtml
                    ' method.
                Catch ex As Exception
                    designTimeHtml = GetErrorDesignTimeHtml(ex)

                    ' Return properties to their original settings.
                Finally
                    sampleButton.BorderStyle = oldBorderStyle
                    sampleButton.BorderWidth = oldBorderWidth
                    sampleButton.BorderColor = oldBorderColor
                End Try

            Else
                designTimeHtml = MyBase.GetDesignTimeHtml()
            End If

            Return designTimeHtml

        End Function

    End Class
End Namespace

Remarques

La GetDesignTimeHtml méthode remplace la propriété par Text la ID propriété du contrôle si Text le Button ne contient aucun caractère pouvant être affiché. Ensuite, la GetDesignTimeHtml méthode appelle sa méthode de base, ControlDesigner.GetDesignTimeHtml, qui appelle la Control.RenderControl méthode pour générer le balisage.

Notes pour les héritiers

Si vous remplacez la GetDesignTimeHtml() méthode, vous modifiez généralement les valeurs de propriété sélectionnées, puis appelez la méthode de base pour générer le balisage, puis restaurez les propriétés à leurs valeurs d’origine.

S’applique à

Partager via