Méthode ConfiguredObject.GetAllSections

Récupère toutes les sections de configuration sous un objet configuré.

Syntaxe

ConfiguredObject.GetAllSections(Sections);  

ConfiguredObject.GetAllSections Sections  

Paramètres

Valeur de retour

Cette méthode ne retourne pas de valeur.

Notes

La méthode GetAllSections est utile pour découvrir l’ensemble complet de sections disponibles pour un objet configuré. Pour connaître les paramètres réguliers et l’obtention des propriétés de configuration, consultez la méthode ConfiguredObject.GetSection.

Exemple

L’exemple suivant récupère l’objet Site pour le site internet par défaut et utilise la méthode GetAllSections pour récupérer et énumérer les objets de section de configuration du site.

Une seule instance de chaque section est retournée. Les valeurs retournées sont la configuration effective pour le niveau de ConfiguredObject utilisé. Le chemin d’accès de tous les objets retournés correspond à celui du ConfiguredObject.

' Connect to the WMI WebAministration namespace.  
Set oWebAdmin = _  
    GetObject("winmgmts:root\WebAdministration")  
  
' Get the default Web site.  
Set oSite = oWebAdmin.Get("Site.Name='Default Web Site'")  
  
' Retrieve all configuration sections for the default Web  
' site and place them into an array variable.  
oSite.GetAllSections arySect  
  
' Display the number of configuration sections.  
WScript.Echo "There are " & UBound(arySect) + 1 & _  
    " configuration sections for [" & oSite.Name & "]."  
WScript.Echo vbCrLf  
  
' Iterate through the sections.  
For aryIdx = 0 To UBound(arySect)  
  
    ' Number the section for display.  
    WScript.Echo aryIdx + 1 & "."  
  
    ' Show the section name.  
    WScript.Echo "[" & arySect(aryIdx).Path_.Class & "]"  
  
    ' Show the section path and location.  
    WScript.Echo "Path: " & arySect(aryIdx).Path  
    WScript.Echo "Location: " & arySect(aryIdx).Location  
  
    ' Show the SectionInformation properties.  
    WScript.Echo "SectionInformation.OverrideMode: " & _  
        arySect(aryIdx).SectionInformation.OverrideMode  
    WScript.Echo _  
        "SectionInformation.EffectiveOverrideMode: " & _  
        arySect(aryIdx).SectionInformation.EffectiveOverrideMode  
    WScript.Echo "SectionInformation.IsLocked: " & _  
        arySect(aryIdx).SectionInformation.IsLocked  
    WScript.Echo "SectionInformation.LockItem: " & _  
        arySect(aryIdx).SectionInformation.LockItem  
  
    WScript.Echo vbCrLf  
Next  
  

Spécifications

Voir aussi

Classe ConfiguredObject
Méthode ConfiguredObject.GetSection