materialize()

S’applique à : ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Capture la valeur d’une expression tabulaire pendant la durée de l’exécution de la requête afin qu’elle puisse être référencée plusieurs fois par la requête sans recalcul.

Syntaxe

materialize(expression)

En savoir plus sur les conventions de syntaxe.

Paramètres

Notes

La materialize() fonction est utile dans les scénarios suivants :

• Pour accélérer les requêtes qui effectuent des calculs lourds dont les résultats sont utilisés plusieurs fois dans la requête.
• Pour évaluer une expression tabulaire une seule fois et l’utiliser plusieurs fois dans une requête. Cela est généralement nécessaire si l’expression tabulaire n’est pas déterministe. Par exemple, si l’expression utilise les rand() fonctions ou les dcount() fonctions.

Exemples d’amélioration des performances des requêtes

L’exemple suivant montre comment materialize() être utilisé pour améliorer les performances de la requête. L’expression _detailed_data est définie à l’aide de materialize() la fonction et est donc calculée une seule fois.

let _detailed_data = materialize(StormEvents | summarize Events=count() by State, EventType);
_detailed_data
| summarize TotalStateEvents=sum(Events) by State
| join (_detailed_data) on State
| extend EventPercentage = Events*100.0 / TotalStateEvents
| project State, EventType, EventPercentage, Events
| top 10 by EventPercentage

Sortie

L’exemple suivant génère un ensemble de nombres aléatoires et de calculs :

• Nombre de valeurs distinctes dans l’ensemble (Dcount)
• Les trois premières valeurs de l’ensemble
• Somme de toutes ces valeurs dans l’ensemble

Cette opération peut être effectuée à l’aide de lots et de matérialiser :

let randomSet = 
    materialize(
        range x from 1 to 3000000 step 1
        | project value = rand(10000000));
randomSet | summarize Dcount=dcount(value);
randomSet | top 3 by value;
randomSet | summarize Sum=sum(value)

Jeu de résultats 1 :

Jeu de résultats 2 :

Jeu de résultats 3 :

Exemples d’utilisation de matérialiser()

Pour utiliser l’instruction let avec une valeur que vous utilisez plusieurs fois, utilisez la fonction materialize(). Essayez d’envoyer (push) tous les opérateurs possibles qui réduisent le jeu de données matérialisé et conservent toujours la sémantique de la requête. Par exemple, utilisez des filtres ou projet uniquement des colonnes requises.

    let materializedData = materialize(Table
    | where Timestamp > ago(1d));
    union (materializedData
    | where Text !has "somestring"
    | summarize dcount(Resource1)), (materializedData
    | where Text !has "somestring"
    | summarize dcount(Resource2))

Le filtre activé Text est mutuel et peut être envoyé (push) à l’expression matérialisée. La requête a uniquement besoin de colonnes Timestamp, Text, Resource1et Resource2. Projetez ces colonnes à l’intérieur de l’expression matérialisée.

    let materializedData = materialize(Table
    | where Timestamp > ago(1d)
    | where Text !has "somestring"
    | project Timestamp, Resource1, Resource2, Text);
    union (materializedData
    | summarize dcount(Resource1)), (materializedData
    | summarize dcount(Resource2))

Si les filtres ne sont pas identiques, comme dans la requête suivante :

    let materializedData = materialize(Table
    | where Timestamp > ago(1d));
    union (materializedData
    | where Text has "String1"
    | summarize dcount(Resource1)), (materializedData
    | where Text has "String2"
    | summarize dcount(Resource2))

Lorsque le filtre combiné réduit considérablement le résultat matérialisé, combinez les deux filtres sur le résultat matérialisé par une expression logique or comme dans la requête suivante. Toutefois, conservez les filtres dans chaque jambe union pour conserver la sémantique de la requête.

    let materializedData = materialize(Table
    | where Timestamp > ago(1d)
    | where Text has "String1" or Text has "String2"
    | project Timestamp, Resource1, Resource2, Text);
    union (materializedData
    | where Text has "String1"
    | summarize dcount(Resource1)), (materializedData
    | where Text has "String2"
    | summarize dcount(Resource2))