Méthode RecurrencePattern.GetOccurrence (Outlook)
Retourne une instance spécifique de l’objet AppointmentItem à la date spécifiée.
Syntaxe
expression. GetOccurrence( _StartDate_ )
Expression Variable qui représente un objet RecurrencePattern .
Parameters
| Nom | Requis/Facultatif | Type de données | Description |
|---|---|---|---|
| StartDate | Requis | Date | Valeur Date qui représente l'heure locale. |
Valeur renvoyée
Objet AppointmentItem représentant le rendez-vous spécifique à la date spécifiée.
Remarques
La méthode GetOccurrence génère une erreur si cette série ne contient aucun rendez-vous à la date spécifiée.
Lors de l'utilisation d'éléments de rendez-vous périodique, vous devez libérer les références antérieures, le cas échéant, obtenir les nouvelles références à l'élément de rendez-vous périodique avant d'accéder à cet élément ou de le modifier, et libérer ces références dès que vous avez terminé et enregistré les modifications. Cette pratique s’applique à l’objet AppointmentItem récurrent et à tout objet Exception ou RecurrencePattern . Pour libérer une référence dans Visual Basic pour Applications (VBA) ou Visual Basic, définissez cet objet existant sur Nothing. Dans C#, libérez explicitement la mémoire pour cet objet. Pour obtenir un exemple de code, consultez la rubrique relative à l’objet AppointmentItem .
Notez que même après avoir libéré votre référence et tenté d’obtenir une nouvelle référence, s’il existe encore une référence active détenue par un autre complément ou par Outlook vers un des objets mentionnés ci-dessus, votre nouvelle référence pointera encore vers une copie périmée de l’objet. Il est donc important de libérer vos références dès que vous en avez terminé avec le rendez-vous périodique.
Exemple
Cet exemple Visual Basic pour Applications (VBA) utilise CreateItem pour créer un objet AppointmentItem . La propriété RecurrencePattern est obtenue pour cet élément à l’aide de la méthode GetRecurrencePattern . En définissant les propriétés RecurrencePattern, RecurrenceType, PatternStartDate et PatternEndDate, les rendez-vous apparaissent dorénavant en séries récurrentes sur une base quotidienne pendant une période d'un an.
Un objet Exception est créé lorsqu’une instance de ce rendez-vous périodique est obtenue à l’aide de la méthode GetOccurrence et que les propriétés de cette instance sont modifiées. Cette exception à la série de rendez-vous est obtenue à l’aide de la méthode GetRecurrencePattern pour accéder à la collection Exceptions associée à cette série. Les zones de message affichent l’objet et la date d’origine pour cette exception à la série de rendez-vous, ainsi que la date, l’heure et l’objet actuels de cette exception.
Public Sub cmdExample()
Dim myApptItem As Outlook.AppointmentItem
Dim myRecurrPatt As Outlook.RecurrencePattern
Dim myNamespace As Outlook.NameSpace
Dim myFolder As Outlook.Folder
Dim myItems As Outlook.Items
Dim myDate As Date
Dim myOddApptItem As Outlook.AppointmentItem
Dim saveSubject As String
Dim newDate As Date
Dim myException As Outlook.Exception
Set myApptItem = Application.CreateItem(olAppointmentItem)
myApptItem.Start = #2/2/2003 3:00:00 PM#
myApptItem.End = #2/2/2003 4:00:00 PM#
myApptItem.Subject = "Meet with Boss"
'Get the recurrence pattern for this appointment
'and set it so that this is a daily appointment
'that begins on 2/2/03 and ends on 2/2/04
'and save it.
Set myRecurrPatt = myApptItem.GetRecurrencePattern
myRecurrPatt.RecurrenceType = olRecursDaily
myRecurrPatt.PatternStartDate = #2/2/2003#
myRecurrPatt.PatternEndDate = #2/2/2004#
myApptItem.Save
'Access the items in the Calendar folder to locate
'the master AppointmentItem for the new series.
Set myNamespace = Application.GetNamespace("MAPI")
Set myFolder = myNamespace.GetDefaultFolder(olFolderCalendar)
Set myItems = myFolder.Items
Set myApptItem = myItems("Meet with Boss")
'Get the recurrence pattern for this appointment
'and obtain the occurrence for 3/12/03.
myDate = #3/12/2003 3:00:00 PM#
Set myRecurrPatt = myApptItem.GetRecurrencePattern
Set myOddApptItem = myRecurrPatt.GetOccurrence(myDate)
'Save the existing subject. Change the subject and
'starting time for this particular appointment
'and save it.
saveSubject = myOddApptItem.Subject
myOddApptItem.Subject = "Meet NEW Boss"
newDate = #3/12/2003 3:30:00 PM#
myOddApptItem.Start = newDate
myOddApptItem.Save
'Release references to the appointment series
Set myApptItem = Nothing
Set myRecurrPatt = Nothing
'Get the recurrence pattern for the master
'AppointmentItem. Access the collection of
'exceptions to the regular appointments.
Set myItems = myFolder.Items
Set myApptItem = myItems("Meet with Boss")
Set myRecurrPatt = myApptItem.GetRecurrencePattern
Set myException = myRecurrPatt.Exceptions.Item(1)
'Display the original date, time, and subject
'for this exception.
MsgBox myException.OriginalDate & ": " & saveSubject
'Display the current date, time, and subject
'for this exception.
MsgBox myException.AppointmentItem.Start & ": " & _
myException.AppointmentItem.Subject
End Sub
Voir aussi
Assistance et commentaires
Avez-vous des questions ou des commentaires sur Office VBA ou sur cette documentation ? Consultez la rubrique concernant l’assistance pour Office VBA et l’envoi de commentaires afin d’obtenir des instructions pour recevoir une assistance et envoyer vos commentaires.