Session.Create, méthode

Crée une instance d’une ressource et retourne la référence de point de terminaison (EPR) du nouvel objet.

Syntaxe

Session.Create( _
  ByVal resourceUri, _
  ByVal resource, _
  [ ByVal flags ] _
)

Paramètres

resourceUri [in]

Identificateur de la ressource à créer.

Ce paramètre peut contenir l’un des éléments suivants :

• URI avec un ou plusieurs sélecteurs. N’oubliez pas que le plug-in WMI ne prend pas en charge la création d’une ressource autre qu’un écouteur WS-Management Protocol .
• Objet ResourceLocator qui peut contenir des sélecteurs, des fragments ou desoptions.
• Référence du point de terminaison WS-Addressing , comme décrit dans la norme de protocole WS-Management. Pour plus d’informations sur la spécification publique du protocole WS-Management, consultez Page d’index des spécifications de gestion.

resource

XML qui contient le contenu de la ressource.

indicateurs [in, facultatif]

Réservé. Doit avoir la valeur 0.

Valeur retournée

EPR de la nouvelle ressource.

Notes

Session.Create est utilisé uniquement pour créer de nouvelles instances d’une ressource. Utilisez la méthode Session.Put pour mettre à jour les instances existantes d’une ressource. Une fois que vous avez obtenu le nouvel URI de ressource, vous pouvez appeler Session.Get pour récupérer le nouvel objet. Le nouvel objet contient toutes les propriétés que le fournisseur de ressources affecte lors de la création de l’objet . Par exemple, si vous créez un écouteur de protocole WS-Management et récupérez l’objet écouteur à l’aide de Session.Get, vous obtenez également les propriétés Port, Enabled et ListeningOn .

N’oubliez pas que le plug-in WMI ne prend pas en charge la création d’une ressource autre qu’un écouteur de protocole WS-Management.

La syntaxe suivante est utilisée pour appeler cette méthode.

uri = session.Create("<resourceUri>", "<resource>")

Exemples

L’exemple de code VBScript suivant appelle Session.Create pour créer un écouteur sur l’ordinateur local.

'Create a WSMan object
Set oWsman = CreateObject( "WSMAN.Automation" )

'Create a Session object
Set oSession = oWsman.CreateSession

'Define resourceUri and inputXml 
resourceUri = "http://schemas.microsoft.com/wbem/wsman/1/"_
    & "config/Listener?Address=*+Transport=HTTP"

inputXml = _
    "<cfg:Listener xmlns:cfg=""https://schemas.dmtf.org/wbem/wsman/1/"_
    & "config/Listener.xsd"">" _
    & "<cfg:Hostname>" & GetFQDNName() & "</cfg:Hostname>" _            
    & "</cfg:Listener>"

'Perform the create operation.
response = oSession.Create( resourceUri, inputXml )
WScript.Echo "Response message: " & Chr(10) & response

Function GetFQDNName()
    Dim oShell, userDNSDomain, localComputerName
    Set oShell = CreateObject("WScript.Shell")
    userDNSDomain = oShell.ExpandEnvironmentStrings("%USERDNSDOMAIN%")

    localComputerName = _
        oShell.ExpandEnvironmentStrings("%ComputerName%")
    If userDNSDomain = "%USERDNSDOMAIN%" Then
        GetFQDNName= localComputerName
    Else
        GetFQDNName= localComputerName & "." & userDNSDomain
    End If
End Function

Spécifications

Voir aussi

session

Protocole Gestion des services web