Operatori e identificatori in Power Apps

Si applica a: App Canvas App basate su modello Power Pages

Alcuni di questi operatori dipendono dalla lingua dell'autore. Per ulteriori informazioni sul supporto della lingua nelle app canvas, vedi App globali.

Operatori in ed exactin

Usa gli operatori in e exactin per trovare una stringa in un'origine dati, ad esempio una raccolta o una tabella importata. L'operatore in identifica le corrispondenze indipendentemente dalle maiuscole/minuscole e l'operatore exactin identifica le corrispondenze solo se l'uso delle maiuscole è uguale. Ecco un esempio:

1. Crea o importa una raccolta denominata Inventory e visualizzala in una raccolta, come illustrato nella prima procedura relativa alla visualizzazione di immagini e testo in una raccolta.

2. Imposta la proprietà Items della raccolta su questa formula:
   Filter(Inventario, "E" in ProductName)

   La raccolta include tutti i prodotti tranne Callisto perché il nome del prodotto è l'unico che non contiene la lettera specificata.

3. Cambia la proprietà Items della raccolta su questa formula:
   Filter(Inventario, "E" esatto ProductName)

   La raccolta riporta solo Europa perché solo questo nome contiene la lettera specificata in base all'uso di maiuscole/minuscole specificato.

Operatori ThisItem, ThisRecord e As

Alcuni controlli e funzioni applicano le formule ai singoli record di una tabella. Per fare riferimento al singolo record in una formula, utilizza una delle seguenti opzioni:

Operatore ThisItem

Ad esempio, nel seguente controllo Gallery, la proprietà Items è impostata sull'origine dati Dipendenti (come la tabella Dipendenti inclusa con l'esempio Northwind Traders):

Employees

Il primo elemento nella raccolta è un modello che viene replicato per ogni dipendente. Nel modello la formula per l'immagine usa ThisItem per fare riferimento all'elemento corrente:

ThisItem.Picture

Allo stesso modo, anche la formula per il nome usa ThisItem:

ThisItem.'First Name' & " " & ThisItem.'Last Name'

Operatore ThisRecord

ThisRecord viene utilizzato nelle funzioni che hanno un ambito record. Ad esempio, possiamo usare la funzione Filter con la proprietà Items della raccolta per mostrare solo i nomi che iniziano con M:

Filter( Employees, StartsWith( ThisRecord.Employee.'First Name', "M" ) )

ThisRecord è facoltativo e implicito nell'uso diretto dei campi, ad esempio, in questo caso, avremmo potuto scrivere:

Filter( Employees, StartsWith( 'First Name', "M" ) )

Sebbene facoltativo, l'utilizzo di ThisRecord può rendere le formule più facili da capire e può essere richiesto in situazioni ambigue in cui un nome di campo può anche essere un nome di relazione. ThisRecord è facoltativo mentre ThisItem è sempre obbligatorio.

Usa ThisRecord per fare riferimento all'intero record con Patch, Collect e altre funzioni dell'ambito del record. Ad esempio, la seguente formula imposta lo stato di tutti i dipendenti inattivi su attivo:

With( { InactiveEmployees: Filter( Employees, Status = 'Status (Employees)'.Inactive ) },
      ForAll( InactiveEmployees,
              Patch( Employees, ThisRecord, { Status: 'Status (Employees)'.Active } ) ) )

Operatore As

Utilizza l'operatore As per denominare un record in una raccolta o una funzione di ambito del record, ignorando il valore predefinito ThisItem o ThisRecord. L'assegnazione di un nome al record può semplificare la comprensione delle formule e può essere necessario in situazioni nidificate per accedere ai record in altri ambiti.

Ad esempio, puoi modificare la proprietà Items della raccolta per utilizzare As per identificare che stiamo lavorando con un dipendente:

Employees As Employee

Le formule per l'immagine e il nome vengono modificate per utilizzare questo nome per il record corrente:

Employee.Picture

Employee.'First Name' & " " & Employee.'Last Name'

As può essere utilizzato anche con le funzioni di ambito record per sostituire il nome predefinito ThisRecord. Possiamo applicarlo al nostro esempio precedente per chiarire il record con cui stiamo lavorando:

With( { InactiveEmployees: Filter( Employees, Status = 'Status (Employees)'.Inactive ) },
      ForAll( InactiveEmployees As Employee,
              Patch( Employees, Employee, { Status: 'Status (Employees)'.Active } ) ) )

Quando si annidano raccolte e funzioni di ambito del record ThisItem e ThisRecord fanno sempre riferimento all'ambito più interno, lasciando i record negli ambiti esterni non disponibili. Usa As per rendere disponibili tutti gli ambiti del record assegnando a ciascuno un nome univoco.

Ad esempio, questa formula produce un modello scacchiera come stringa di testo nidificando due funzioni ForAll:

Concat(
    ForAll( Sequence(8) As Rank,
        Concat(
            ForAll( Sequence(8) As File,
                    If( Mod(Rank.Value + File.Value, 2) = 1, " X ", " . " )
            ),
            Value
        ) & Char(10)
    ),
    Value
)

L'impostazione della proprietà Text di un controllo Label su questa formula visualizza:

Spieghiamo ciò che sta accadendo qui:

• Iniziamo scorrendo una tabella senza nome di 8 record numerati dalla funzione Sequence. Questo ciclo è per ogni riga della scheda, che viene comunemente chiamata rank e quindi gli diamo questo nome.
• Per ogni riga, scorriamo un'altra tabella senza nome di 8 colonne e diamo il nome comune File.
• Se Rank.Value + File.Value è un numero dispari, il quadrato ottiene una X, altrimenti un punto. Questa parte della formula fa riferimento a entrambi i cicli ForAll, reso possibile utilizzando l'operatore As.
• Concat viene utilizzato due volte, prima per assemblare le colonne e poi le righe, con un Char(10) inserito per creare una nuova riga.

Un esempio simile è possibile con i controlli Gallery nidificati invece delle funzioni ForAll. Cominciamo con la raccolta verticale per rank. Questo controllo gallery avrà un formula Items di:

Sequence(8) as Rank

All'interno di questa raccolta, inseriremo una raccolta orizzontale per File che verrà replicato per ogni rank, con una proprietà Items di:

Sequence(8) as File

E infine, all'interno di questa raccolta, aggiungeremo un controllo Label che verrà replicato per ciascun File e Rank. Lo ridimensioneremo per riempire l'intero spazio e useremo la proprietà Fill per fornire il colore con questa formula:

If( Mod( Rank.Value + File.Value, 2 ) = 1, Green, Beige )

Operatori Self e Parent

Esistono tre modi per fare riferimento a un controllo e alle relative proprietà in una formula:

Self e padre sono operatori e non proprietà dei controlli stessi. Il riferimento a Parent.Parent, Self.Parent o Parent.Self non è supportato.

Nomi di identificatore

I nomi di variabili, origini dati, colonne e altri oggetti possono contenere qualsiasi Unicode.

Usa le virgolette singole per racchiudere un nome che contiene uno spazio o un altro carattere speciale.
Utilizza due virgolette singole per rappresentare una singola virgoletta nel nome. I nomi che non contengono caratteri speciali non richiedono virgolette singole.

Ecco alcuni esempi di nomi di colonne che potresti incontrare in una tabella e come sono rappresentati in una formula:

Le virgolette doppie sono usate per designare le stringhe di testo.

Nomi visualizzati e nomi logici

Alcune origini dati come SharePoint e Microsoft Dataverse hanno due nomi diversi per fare riferimento alla stessa tabella o colonna di dati:

• Nome logico - Un nome che è garantito come univoco, che non cambia dopo essere stato creato, solitamente non ammette spazi o altri caratteri speciali e che non è localizzato in lingue diverse. Di conseguenza, il nome può essere criptico. Questi nomi sono utilizzati da sviluppatori professionisti. Per esempio, cra3a_customfield. Questo nome può anche essere definito come nome dello schema o solo nome.

• nome visualizzato - Un nome di facile utilizzo e pensato per essere visualizzato dagli utenti finali. Questo nome potrebbe non essere univoco, potrebbe cambiare nel tempo, contenere spazi e qualsiasi carattere Unicode e potrebbe essere localizzato in diverse lingue. Corrispondente all'esempio precedente, il nome visualizzato potrebbe essere Campo personalizzato con lo spazio tra le parole.

Poiché i nomi visualizzati sono più facili da comprendere, le app canvas li suggeriscono come scelte e non suggeriscono i nomi logici. Sebbene i nomi logici non siano suggeriti, possono comunque essere utilizzati se digitati indirettamente.

Ad esempio, immagina di aver aggiunto un Campo personalizzato a una tabella in Dataverse. Viene assegnato dal sistema un nome logico che puoi modificare solo durante la creazione del campo. Il risultato è simile al seguente:

Quando si crea un riferimento a un campo di Account, il suggerimento verrà creato per usare 'Custom Field' poiché questo è il nome visualizzato. Le virgolette singole devono essere utilizzate perché questo nome contiene uno spazio:

Dopo aver selezionato il suggerimento, nella barra della formula viene visualizzato 'Custom Field' e vengono recuperati i dati:

Sebbene non sia suggerito, possiamo anche usare il nome logico per questo campo. Ciò comporterà il recupero degli stessi dati. Non sono richieste virgolette singole poiché questo nome non contiene spazi o caratteri speciali:

Dietro le quinte, viene mantenuta una mappatura tra i nomi visualizzati nelle formule e i nomi logici sottostanti. Poiché i nomi logici devono essere utilizzati per interagire con l'origine dati, questa mappatura viene utilizzata per convertire automaticamente dall'attuale nome visualizzato al nome logico e questo è ciò che viene visualizzato nel traffico di rete. Questo mapping viene anche utilizzato per riconvertire in nomi logici per passare a nuovi nomi visualizzati, ad esempio, se un nome visualizzato cambia o un produttore in una lingua diversa modifica l'app.

Risoluzione ambiguità di nome

Poiché i nomi visualizzati non sono univoci, lo stesso nome visualizzato potrebbe apparire più di una volta nella stessa tabella. Quando ciò accade, il nome logico verrà aggiunto alla fine del nome visualizzato tra parentesi per uno o più nomi in conflitto. Basandoci sull'esempio sopra, se esistesse un secondo campo con lo stesso nome visualizzato Custom Field con un nome logico di cra3a_customfieldalt, i suggerimenti mostrerebbero:

Le stringhe di disambiguazione dei nomi vengono aggiunte in altre situazioni in cui si verificano conflitti di nomi, come i nomi di tabelle, scelte e altri elementi di Dataverse.

Operatore di risoluzione ambiguità

Alcune funzioni creano scope di record per accedere ai campi della tabella durante l'elaborazione di ogni record, ad esempio Filter, AddColumns e Sum. I nomi di campo aggiunti con l'ambito di record eseguono l'override degli stessi nomi da qualsiasi altra posizione nell'app. In questo caso, puoi comunque accedere ai valori dall'esterno dell'ambito di record con l'operatore di risoluzione ambiguità @:

• Per accedere ai valori da ambiti dei record nidificati, usa l'operatore @ con il nome della tabella su cui si opera usando il pattern seguente:
  Tabella[@NomeCampo]
• Per accedere ai valori globali, ad esempio origini dati, raccolte e variabili di contesto, usa il pattern [@ObjectName] (senza una definizione di tabella).

Per altre informazioni ed esempi, vedi gli ambiti dei record.