다음을 통해 공유

사용자 지정 날짜 및 시간 형식 문자열

  • 아티클

날짜 및 시간 서식 문자열은 서식 작업으로 인해 발생하는 Date, DateTime, DateTimeZone 또는 시간 값의 텍스트 표현을 정의합니다. 또한 문자열을 날짜 및 시간으로 성공적으로 변환하기 위해 구문 분석 작업에 필요한 날짜 및 시간 값의 표현을 정의할 수 있습니다. 사용자 지정 형식 문자열은 하나 이상의 사용자 지정 날짜 및 시간 형식 지정자로 구성됩니다. 표준 날짜 및 시간 형식 문자열이 아닌 문자열은 사용자 지정 날짜 및 시간 형식 문자열로 해석됩니다.

서식 지정 작업에서 날짜 및 시간 및 표준 시간대 인스턴스의 메서드와 함께 ToText 사용자 지정 날짜 및 시간 형식 문자열을 사용할 수 있습니다. 다음 예제에서는 해당 용도를 보여 줍니다.

let
    Source = 
    {
        Text.From("Today is " & Date.ToText(#date(2011, 6, 10), [Format = "MMMM dd yyyy"]) & "."),
        Text.Format("The current date and time: #{0}", {DateTimeZone.ToText(
            #datetimezone(2011, 6, 10, 15, 24, 16, 0, 0), [Format = "MM/dd/yy H:mm:ss zzz"])}
        )
    }
in
    Source

// The example displays the following output:
//    Today is June 10, 2011.
//    The current date and time: 06/10/11 15:24:16 +00:00

구문 분석 작업에서 사용자 지정 날짜 및 시간 형식 문자열을 Date, DateTime, Time 및 DateTimeZone 함수와 함께 사용할 수 있습니다. 이러한 함수를 사용하려면 구문 분석 작업이 성공하려면 입력 문자열이 특정 패턴을 정확하게 준수해야 합니다. 다음 예제에서는 DateTime.FromText 함수를 호출하여 월, 일 및 두 자리 연도를 포함해야 하는 날짜를 구문 분석하는 방법을 보여 줍니다.

let
    dateValues = { "30-12-2011", "12-30-2011", "30-12-11", "12-30-11"},
    pattern = "MM-dd-yy",
    convertedDates = List.Transform(dateValues, (dateValue) => 
        try Text.Format("Converted '#{0}' to #{1}.", {dateValue, DateTime.FromText(dateValue, [Format=pattern])}) 
        otherwise Text.Format("Unable to convert '#{0}' to a date and time.", {dateValue}))
in
    convertedDates

// The example displays the following output:
//    Unable to convert '30-12-2011' to a date and time.
//    Unable to convert '12-30-2011' to a date and time.
//    Unable to convert '30-12-11' to a date and time.
//    Converted '12-30-11' to 12/30/2011.

다음 표에서는 사용자 지정 날짜 및 시간 형식 지정자에 대해 설명하고 각 형식 지정자가 생성한 결과 문자열을 표시합니다. 기본적으로 결과 문자열은 en-US 문화권의 형식 규칙을 반영합니다. 특정 형식 지정자가 지역화된 결과 문자열을 생성하는 경우 결과 문자열에 적용되는 문화권의 예도 보여 줍니다. 사용자 지정 날짜 및 시간 형식 문자열을 사용하는 방법에 대한 자세한 내용은 Notes 섹션을 참조하세요.

형식 지정자 설명 예제
"d" 1에서 31까지의 월의 날입니다.

추가 정보: "d" 사용자 지정 형식 지정자입니다.		 2009-06-01T13:45:30 -> 1

2009-06-15T13:45:30 -> 15
"dd" 01에서 31까지의 월의 날짜입니다.

추가 정보: "dd" 사용자 지정 형식 지정자입니다.		 2009-06-01T13:45:30 -> 01

2009-06-15T13:45:30 -> 15
"ddd" 요일의 약식 이름입니다.

추가 정보: "ddd" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30 -> 월(en-US)

2009-06-15T13:45:30 -> Пн(ru-RU)

2009-06-15T13:45:30 -> lun. (fr-FR)
"dddd" 요일의 전체 이름입니다.

추가 정보: "dddd" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30 -> 월요일(en-US)

2009-06-15T13:45:30 -> понедельник(ru-RU)

2009-06-15T13:45:30 -> lundi(fr-FR)
"f" 날짜 및 시간 값에서 1/10초입니다.

추가 정보: "f" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30.6170000 -> 6

2009-06-15T13:45:30.05 -> 0
"ff" 날짜 및 시간 값의 1/100초입니다.

추가 정보: "ff" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30.6170000 -> 61

2009-06-15T13:45:30.0050000 -> 00
"fff" 날짜 및 시간 값의 1/1000초입니다.

추가 정보: "fff" 사용자 지정 형식 지정자입니다.		 6/15/2009 13:45:30.617 -> 617

6/15/2009 13:45:30.0005 -> 000
"ffff" 날짜 및 시간 값의 1/10000초입니다.

추가 정보: "ffff" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30.6175000 -> 6175

2009-06-15T13:45:30.0000500 -> 0000
"fffff" 날짜 및 시간 값의 1/100000초입니다.

추가 정보: "fffff" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30.6175400 -> 61754

2009년 6월 15일 13:45:30.000005 -> 00000
"ffffff" 날짜 및 시간 값의 1/1000000초입니다.

추가 정보: "ffffff" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30.6175420 -> 617542

2009-06-15T13:45:30.0000005 -> 000000
"fffffff" 날짜 및 시간 값의 1/10000000초입니다.

추가 정보: "fffffff" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30.6175425 -> 6175425

2009-06-15T13:45:30.0001150 -> 0001150
"F" 0이 아닌 경우 날짜 및 시간 값의 1/10초입니다.

추가 정보: "F" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30.6170000 -> 6

2009-06-15T13:45:30.0500000 -> (출력 없음)
"FF" 0이 아닌 경우 날짜 및 시간 값의 1/100초입니다.

추가 정보: "FF" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30.6170000 -> 61

2009-06-15T13:45:30.0050000 -> (출력 없음)
"FFF" 0이 아닌 경우 날짜 및 시간 값의 1/1000초입니다.

추가 정보: "FFF" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30.6170000 -> 617

2009-06-15T13:45:30.0005000 -> (출력 없음)
"FFFF" 0이 아닌 경우 날짜 및 시간 값의 1/10000초입니다.

추가 정보: "FFFF" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30.5275000 -> 5275

2009-06-15T13:45:30.0000500 -> (출력 없음)
"FFFFF" 0이 아닌 경우 날짜 및 시간 값의 1/100000초입니다.

추가 정보: "FFFFF" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30.6175400 -> 61754

2009-06-15T13:45:30.0000050 -> (출력 없음)
"FFFFFF" 0이 아닌 경우 날짜 및 시간 값의 1/1000000초입니다.

추가 정보: "FFFFFF" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30.6175420 -> 617542

2009-06-15T13:45:30.0000005 -> (출력 없음)
"FFFFFFF" 0이 아닌 경우 날짜 및 시간 값의 1/10000000초입니다.

추가 정보: "FFFFFFF" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30.6175425 -> 6175425

2009-06-15T13:45:30.0001150 -> 000115
"g", "gg" 서기 또는 연대입니다.

추가 정보: "g" 또는 "gg" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30.6170000 -> A.D.
"h" 12시간 형식을 사용하는 1부터 12까지의 시간입니다.

추가 정보: "h" 사용자 지정 형식 지정자입니다.		 2009-06-15T01:45:30 -> 1

2009-06-15T13:45:30 -> 1
"hh" 12시간 형식을 사용하는 01부터 12까지의 시간입니다.

추가 정보: "hh" 사용자 지정 형식 지정자입니다.		 2009-06-15T01:45:30 -> 01

2009-06-15T13:45:30 -> 01
"H" 24시간 형식을 사용하는 0부터 23까지의 시간입니다.

추가 정보: "H" 사용자 지정 형식 지정자입니다.		 2009-06-15T01:45:30 -> 1

2009-06-15T13:45:30 -> 13
"HH" 24시간 형식을 사용하는 00부터 23까지의 시간입니다.

추가 정보: "HH" 사용자 지정 형식 지정자입니다.		 2009-06-15T01:45:30 -> 01

2009-06-15T13:45:30 -> 13
"K" 표준 시간대 정보입니다.

추가 정보: "K" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30, 지정되지 않음 ->

2009-06-15T13:45:30, Utc -> +00:00

2009-06-15T13:45:30, 로컬 -> -07:00(로컬 또는 클라우드 컴퓨터 설정에 따라 다름)
"m" 0에서 59까지의 분입니다.

추가 정보: "m" 사용자 지정 형식 지정자입니다.		 2009-06-15T01:09:30 -> 9

2009-06-15T13:29:30 -> 29
"mm" 분, 00에서 59까지.

추가 정보: "mm" 사용자 지정 형식 지정자입니다.		 2009-06-15T01:09:30 -> 09

2009-06-15T01:45:30 -> 45
"M" 1에서 12까지의 월입니다.

추가 정보: "M" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30 -> 6
"MM" 01에서 12까지의 월입니다.

추가 정보: "MM" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30 -> 06
"MMM" 월의 약식 이름입니다.

추가 정보: "MMM" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30 -> 6월(en-US)

2009-06-15T13:45:30 -> juin(fr-FR)

2009-06-15T13:45:30 -> 6월(zu-ZA)
"MMMM" 월의 전체 이름입니다.

추가 정보: "MMMM" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30 -> 6월(en-US)

2009-06-15T13:45:30 -> juni(da-DK)

2009-06-15T13:45:30 -> Juni(zu-ZA)
"s" 두 번째, 0에서 59까지입니다.

추가 정보: "s" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:09 -> 9
"ss" 두 번째, 00에서 59까지입니다.

추가 정보: "ss" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:09 -> 09
"t" AM/PM 지정자의 첫 문자입니다.

추가 정보: "t" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30 -> P(en-US)

2009-06-15T13:45:30 -> 午(ja-JP)

2009-06-15T13:45:30 -> (fr-FR)
"tt" AM/PM 지정자입니다.

추가 정보: "tt" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30 -> 오후(en-US)

2009-06-15T13:45:30 -> 午後(ja-JP)

2009-06-15T13:45:30 -> (fr-FR)
"y" 0부터 99까지의 연도입니다.

추가 정보: "y" 사용자 지정 형식 지정자입니다.		 0001-01-01T00:00:00 -> 1

0900-01-01T00:00:00 -> 0

1900-01-01T00:00:00 -> 0

2009-06-15T13:45:30 -> 9

2019-06-15T13:45:30 -> 19
"yy" 00부터 99까지의 연도입니다.

추가 정보: "yy" 사용자 지정 형식 지정자입니다.		 0001-01-01T00:00:00 -> 01

0900-01-01T00:00:00 -> 00

1900-01-01T00:00:00 -> 00

2019-06-15T13:45:30 -> 19
"yyy" 최소 세 자리 숫자로 된 연도입니다.

추가 정보: "yyy" 사용자 지정 형식 지정자입니다.		 0001-01-01T00:00:00 -> 001

0900-01-01T00:00:00 -> 900

1900-01-01T00:00:00 -> 1900

2009-06-15T13:45:30 -> 2009
"yyyy" 네 자리 숫자로 된 연도입니다.

추가 정보: "yyyy" 사용자 지정 형식 지정자입니다.		 0001-01-01T00:00:00 -> 0001

0900-01-01T00:00:00 -> 0900

1900-01-01T00:00:00 -> 1900

2009-06-15T13:45:30 -> 2009
"yyyyy" 다섯 자리 숫자로 된 연도입니다.

추가 정보: "yyyyy" 사용자 지정 형식 지정자입니다.		 0001-01-01T00:00:00 -> 00001

2009-06-15T13:45:30 -> 02009
"z" 앞에 0이 표시되지 않는 UTC에서의 시간 오프셋입니다.

추가 정보: "z" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30-07:00 -> -7
"zz" 한 자리 값의 경우 앞에 0이 표시되는 UTC에서의 시간 오프셋입니다.

추가 정보: "zz" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30-07:00 -> -07
"zzz" UTC에서의 시간 및 분 오프셋입니다.

추가 정보: "zzz" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30-07:00 -> -07:00
":" 시간 구분 기호입니다.

추가 정보: ":" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30 -> : (en-US)

2009-06-15T13:45:30 -> . (it-IT)

2009-06-15T13:45:30 -> : (ja-JP)
"/" 날짜 구분 기호입니다.

추가 정보: "/" 사용자 지정 형식 지정자입니다.		 2009-06-15T13:45:30 -> / (en-US)

2009-06-15T13:45:30 -> (ar-DZ)

2009-06-15T13:45:30 -> . (tr-TR)
"string"

'string'		 리터럴 문자열 구분 기호입니다.

추가 정보: 리터럴 문자		 2009-06-15T13:45:30 ("arr:"" h:m t) -> arr: 1:45 P

2009-06-15T13:45:30 ('arr:' h:m t) -> arr: 1:45 P
% 뒤에 오는 문자를 사용자 지정 형식 지정자로 정의합니다.

추가 정보: 단일 사용자 지정 형식 지정자 사용		 2009-06-15T13:45:30 (%h) -> 1
\, "", ' 이스케이프 시퀀스입니다.

추가 정보: 문자 리터럴 및 이스케이프 시퀀스 사용		 2009-06-15T13:45:30 (h \h) -> 1 h

2009-06-15T13:45:30 (h "h"") -> 1 h

2009-06-15T13:45:30 (h 'h') -> 1 h
기타 문자 문자가 변경되지 않은 상태로 결과 문자열에 복사됩니다.

추가 정보: 리터럴 문자		 2009-06-15T01:45:30 (arr hh:mm t) -> arr 01:45 A

다음 단원에서는 각 사용자 지정 날짜 및 시간 형식 지정자에 대한 추가 정보를 제공합니다. 달리 명시되지 않는 한 각 지정자는 Date, DateTime, DateTimeZone 또는 시간 값과 함께 사용되는지 여부에 관계없이 동일한 문자열 표현을 생성합니다.

일 “d” 형식 지정자

"d" 사용자 지정 형식 지정자

"d" 사용자 지정 형식 지정자는 해당 월의 일을 1에서 31까지의 숫자로 나타냅니다. 한 자리 일의 경우 앞에 0이 표시되지 않습니다.

다른 사용자 지정 형식 지정자 없이 “d” 형식 지정자만 사용되면 “d” 표준 날짜 및 시간 형식 지정자로 해석됩니다. 단일 형식 지정자를 사용하는 방법에 대한 자세한 내용은 이 문서의 뒷부분에 있는 단일 사용자 지정 형식 지정자를 사용하세요.

다음 예제에서는 여러 개의 형식 문자열에 "d" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15), [Format = "d, M", Culture = ""]),
        // Displays 29, 8 

        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15), [Format = "d, MMMM", Culture = "en-US"]),
        // Displays 29, August

        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15), [Format = "d, MMMM", Culture = "es-MX"])
        // Displays 29, agosto
    }
in
    Source

표로 이동

"dd" 사용자 지정 형식 지정자

"dd" 사용자 지정 서식 문자열은 월의 일을 01에서 31까지의 숫자로 나타냅니다. 한 자리 일의 경우 앞에 0이 표시됩니다.

다음 예제에서는 사용자 지정 형식 문자열에 "dd" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 1, 2, 6, 30, 15), [Format = "dd, MM", Culture = ""])
        // Displays 02, 01 
    }
in
    Source

표로 이동

"ddd" 사용자 지정 형식 지정자

"ddd" 사용자 지정 형식 지정자는 요일의 약식 이름을 나타냅니다. 요일의 지역화된 약어 이름은 현재 또는 지정된 문화권에서 검색됩니다.

다음 예제에서는 사용자 지정 형식 문자열에 "ddd" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15), [Format = "ddd d MMM", Culture = "en-US"]),
        // Displays Thu 29 Aug

        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15), [Format = "ddd d MMM", Culture = "fr-FR"])
        // Displays jeu. 29 août
    }
in
    Source

표로 이동

"dddd" 사용자 지정 형식 지정자

"dddd" 사용자 지정 형식 지정자는 임의 개수의 추가 "d" 지정자와 함께 요일의 전체 이름을 나타냅니다. 요일의 지역화된 이름은 현재 또는 지정된 문화권에서 검색됩니다.

다음 예제에서는 사용자 지정 형식 문자열에 "dddd" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15), [Format = "dddd dd MMMM", Culture = "en-US"]),
        // Displays Thursday 29 August

        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15), [Format = "dddd dd MMMM", Culture = "it-IT"])
        // Displays giovedì 29 agosto
    }
in
    Source

표로 이동

소문자 초 “f” 분수 지정자

"f" 사용자 지정 형식 지정자

"f" 사용자 지정 형식 지정자는 초의 소수 부분에 대한 최대 유효 자릿수를 나타냅니다. 즉, 날짜 및 시간 값에서 1/10초까지 표시합니다.

다른 형식 지정자 없이 “f” 형식 지정자만 사용되면 “f” 표준 날짜 및 시간 형식 지정자로 해석됩니다. 단일 형식 지정자를 사용하는 방법에 대한 자세한 내용은 이 문서의 뒷부분에 있는 단일 사용자 지정 형식 지정자를 사용하세요.

"f" 서식 지정자를 제공된 서식 문자열의 일부로 사용하여 소수 자릿수 초 수를 구문 분석하는 경우 "f" 서식 지정자의 수는 문자열을 성공적으로 구문 분석하기 위해 존재해야 하는 초 분수의 가장 중요한 자릿수를 나타냅니다.

다음 예제에서는 사용자 지정 형식 문자열에 "f" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15.018), [Format = "hh:mm:ss:f", Culture = ""]),
        // Displays 07:27:15:0

        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15.018), [Format = "hh:mm:ss:F", Culture = ""])
        // Displays 07:27:15:
    }
in
    Source

표로 이동

"ff" 사용자 지정 형식 지정자

"ff" 사용자 지정 형식 지정자는 초의 소수 부분에 대한 최대 유효 자릿수 2개를 나타냅니다. 즉, 날짜 및 시간 값에서 1/100초까지 표시합니다.

다음 예제에서는 사용자 지정 형식 문자열에 "ff" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15.018), [Format = "hh:mm:ss:ff", Culture = ""]),
        // Displays 07:27:15:01

        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15.018), [Format = "hh:mm:ss:FF", Culture = ""])
        // Displays 07:27:15:01
    }
in
    Source

표로 이동

"fff" 사용자 지정 형식 지정자

"fff" 사용자 지정 형식 지정자는 초의 소수 부분에 대한 최대 유효 자릿수 3개를 나타냅니다. 즉, 날짜 및 시간 값에서 1/1000초까지 표시합니다.

다음 예제에서는 사용자 지정 형식 문자열에 "fff" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15.018), [Format = "hh:mm:ss:fff", Culture = ""]),
        // Displays 07:27:15:018

        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15.018), [Format = "hh:mm:ss:FFF", Culture = ""])
        // Displays 07:27:15:018
    }
in
    Source

표로 이동

"ffff" 사용자 지정 형식 지정자

"ffff" 사용자 지정 형식 지정자는 초의 소수 부분에 대한 최대 유효 자릿수 4개를 나타냅니다. 즉, 날짜 및 시간 값에서 1/10000초까지 표시합니다.

시간 값의 두 번째 구성 요소 중 1만 분의 1을 표시할 수 있지만 해당 값은 의미가 없을 수 있습니다. 날짜 및 시간 값의 자릿수는 시스템 시계의 정밀도에 따라 달라집니다. Windows Server 2019 및 Windows 11 운영 체제에서 클록의 해상도는 약 1밀리초입니다.

표로 이동

"fffff" 사용자 지정 형식 지정자

"fffff" 사용자 지정 형식 지정자는 초의 소수 부분에 대한 최대 유효 자릿수 다섯 개를 나타냅니다. 즉, 날짜 및 시간 값에서 1/100000초까지 표시합니다.

시간 값의 두 번째 구성 요소의 10만 분의 1을 표시할 수 있지만 해당 값은 의미가 없을 수 있습니다. 날짜 및 시간 값의 자릿수는 시스템 시계의 정밀도에 따라 달라집니다. Windows Server 2019 및 Windows 11 운영 체제에서 클록의 해상도는 약 1밀리초입니다.

표로 이동

"ffffff" 사용자 지정 형식 지정자

"ffffff" 사용자 지정 형식 지정자는 초의 소수 부분에 대한 최대 유효 자릿수 6개를 나타냅니다. 즉, 날짜 및 시간 값에서 1/1000000초까지 표시합니다.

시간 값의 두 번째 구성 요소 중 백만 번째 구성 요소를 표시할 수 있지만 해당 값은 의미가 없을 수 있습니다. 날짜 및 시간 값의 자릿수는 시스템 시계의 정밀도에 따라 달라집니다. Windows Server 2019 및 Windows 11 운영 체제에서 클록의 해상도는 약 1밀리초입니다.

표로 이동

"fffffff" 사용자 지정 형식 지정자

"fffffff" 사용자 지정 형식 지정자는 초의 소수 부분에 대한 최대 유효 자릿수 7개를 나타냅니다. 즉, 날짜 및 시간 값에서 1/10000000초까지 표시합니다.

시간 값의 두 번째 구성 요소 중 1,000만 번째 구성 요소를 표시할 수 있지만 해당 값은 의미가 없을 수 있습니다. 날짜 및 시간 값의 자릿수는 시스템 시계의 정밀도에 따라 달라집니다. Windows Server 2019 및 Windows 11 운영 체제에서 클록의 해상도는 약 1밀리초입니다.

표로 이동

대문자 초 “F” 분수 지정자

"F" 사용자 지정 형식 지정자

"F" 사용자 지정 형식 지정자는 초의 소수 부분에 대한 최대 유효 자릿수를 나타냅니다. 즉, 날짜 및 시간 값에서 1/10초까지 표시합니다. 숫자가 0이면 아무 것도 표시되지 않으며 초 수를 따르는 소수점도 표시되지 않습니다.

다른 형식 지정자 없이 “F” 형식 지정자만 사용되면 “F” 표준 날짜 및 시간 형식 지정자로 해석됩니다. 단일 형식 지정자를 사용하는 방법에 대한 자세한 내용은 이 문서의 뒷부분에 있는 단일 사용자 지정 형식 지정자를 사용하세요.

구문 분석 시 사용되는 "F" 형식 지정자의 수는 문자열을 성공적으로 구문 분석하기 위해 표시될 수 있는 초 분수의 최대 유효 자릿수를 나타냅니다.

다음 예제에서는 사용자 지정 형식 문자열에 "F" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15.018), [Format = "hh:mm:ss:f", Culture = ""]),
        // Displays 07:27:15:0

        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15.018), [Format = "hh:mm:ss:F", Culture = ""])
        // Displays 07:27:15:
    }
in
    Source

표로 이동

"FF" 사용자 지정 형식 지정자

"FF" 사용자 지정 형식 지정자는 초의 소수 부분에 대한 최대 유효 자릿수 2개를 나타냅니다. 즉, 날짜 및 시간 값에서 1/100초까지 표시합니다. 후행 0은 표시되지 않습니다. 두 개의 유효 자릿수가 0이면 아무 것도 표시되지 않으며, 이 경우 초 수를 따르는 소수점도 표시되지 않습니다.

다음 예제에서는 사용자 지정 형식 문자열에 "FF" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15.018), [Format = "hh:mm:ss:ff", Culture = ""]),
        // Displays 07:27:15:01

        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15.018), [Format = "hh:mm:ss:FF", Culture = ""])
        // Displays 07:27:15:01
    }
in
    Source

표로 이동

"FFF" 사용자 지정 형식 지정자

"FFF" 사용자 지정 형식 지정자는 초의 소수 부분에 대한 최대 유효 자릿수 3개를 나타냅니다. 즉, 날짜 및 시간 값에서 1/1000초까지 표시합니다. 후행 0은 표시되지 않습니다. 세 개의 유효 자릿수가 0이면 아무 것도 표시되지 않으며, 이 경우 초 수를 따르는 소수점도 표시되지 않습니다.

다음 예제에서는 사용자 지정 형식 문자열에 "FFF" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15.018), [Format = "hh:mm:ss:fff", Culture = ""]),
        // Displays 07:27:15:018

        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15.018), [Format = "hh:mm:ss:FFF", Culture = ""])
        // Displays 07:27:15:018
    }
in
    Source

표로 이동

"FFFF" 사용자 지정 형식 지정자

"FFFF" 사용자 지정 형식 지정자는 초의 소수 부분에 대한 최대 유효 자릿수 4개를 나타냅니다. 즉, 날짜 및 시간 값에서 1/10000초까지 표시합니다. 후행 0은 표시되지 않습니다. 4개의 유효 자릿수가 0이면 아무 것도 표시되지 않으며, 이 경우 초 수를 따르는 소수점도 표시되지 않습니다.

시간 값의 두 번째 구성 요소 중 1만 분의 1을 표시할 수 있지만 해당 값은 의미가 없을 수 있습니다. 날짜 및 시간 값의 자릿수는 시스템 시계의 정밀도에 따라 달라집니다. Windows Server 2019 및 Windows 11 운영 체제에서 클록의 해상도는 약 1밀리초입니다.

표로 이동

"FFFFF" 사용자 지정 형식 지정자

"FFFFF" 사용자 지정 형식 지정자는 초의 소수 부분에 대한 최대 유효 자릿수 5개를 나타냅니다. 즉, 날짜 및 시간 값에서 1/100000초까지 표시합니다. 후행 0은 표시되지 않습니다. 5개의 유효 자릿수가 0이면 아무 것도 표시되지 않으며, 이 경우 초 수를 따르는 소수점도 표시되지 않습니다.

시간 값의 두 번째 구성 요소의 10만 분의 1을 표시할 수 있지만 해당 값은 의미가 없을 수 있습니다. 날짜 및 시간 값의 자릿수는 시스템 시계의 정밀도에 따라 달라집니다. Windows Server 2019 및 Windows 11 운영 체제에서 클록의 해상도는 약 1밀리초입니다.

표로 이동

"FFFFFF" 사용자 지정 형식 지정자

"FFFFFF" 사용자 지정 형식 지정자는 초의 소수 부분에 대한 최대 유효 자릿수 6개를 나타냅니다. 즉, 날짜 및 시간 값에서 1/1000000초까지 표시합니다. 후행 0은 표시되지 않습니다. 6개의 유효 자릿수가 0이면 아무 것도 표시되지 않으며, 이 경우 초 수를 따르는 소수점도 표시되지 않습니다.

시간 값의 두 번째 구성 요소 중 백만 번째 구성 요소를 표시할 수 있지만 해당 값은 의미가 없을 수 있습니다. 날짜 및 시간 값의 자릿수는 시스템 시계의 정밀도에 따라 달라집니다. Windows Server 2019 및 Windows 11 운영 체제에서 클록의 해상도는 약 1밀리초입니다.

표로 이동

"FFFFFFF" 사용자 지정 형식 지정자

"FFFFFFF" 사용자 지정 형식 지정자는 초의 소수 부분에 대한 최대 유효 자릿수 7개를 나타냅니다. 즉, 날짜 및 시간 값에서 1/10000000초까지 표시합니다. 후행 0은 표시되지 않습니다. 7개의 유효 자릿수가 0이면 아무 것도 표시되지 않으며, 이 경우 초 수를 따르는 소수점도 표시되지 않습니다.

시간 값의 두 번째 구성 요소 중 1,000만 번째 구성 요소를 표시할 수 있지만 해당 값은 의미가 없을 수 있습니다. 날짜 및 시간 값의 자릿수는 시스템 시계의 정밀도에 따라 달라집니다. Windows Server 2019 및 Windows 11 운영 체제에서 클록의 해상도는 약 1밀리초입니다.

표로 이동

연대 “g” 형식 지정자

"g" 또는 "gg" 사용자 지정 형식 지정자

"g" 또는 "gg" 사용자 지정 형식 지정자(추가 "g" 지정자 수 포함)는 A.D와 같은 마침표 또는 연대를 나타냅니다. 서식을 지정할 날짜에 연결된 마침표 또는 연대 문자열이 없는 경우 서식 지정 작업은 이 지정자를 무시합니다.

다른 사용자 지정 형식 지정자 없이 “g” 형식 지정자만 사용되면 “g” 표준 날짜 및 시간 형식 지정자로 해석됩니다. 단일 형식 지정자를 사용하는 방법에 대한 자세한 내용은 이 문서의 뒷부분에 있는 단일 사용자 지정 형식 지정자를 사용하세요.

다음 예제에서는 사용자 지정 형식 문자열에 "g" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        Date.ToText(#date(70, 08, 04), [Format = "MM/dd/yyyy g", Culture = ""]),
        // Displays 08/04/0070 A.D.

        Date.ToText(#date(70, 08, 04), [Format = "MM/dd/yyyy g", Culture = "fr-FR"])
        // Displays 08/04/0070 ap. J.-C.
    }
in
    Source

표로 이동

소문자 시간 “h” 형식 지정자

"h" 사용자 지정 형식 지정자

"h" 사용자 지정 형식 지정자는 시간을 1에서 12까지의 숫자로 나타냅니다. 즉, 시간은 자정 또는 정오 이후의 전체 시간을 계산하는 12시간 시계로 표시됩니다. 자정 이후의 시간과 정오 이후의 같은 시간을 구별할 수 없습니다. 시간은 반올림되지 않으며, 한 자리 시간의 형식은 선행 0 없이 지정됩니다. 예를 들어, 시간이 오전 또는 오후 5:43일 경우 이 사용자 지정 형식 지정자는 "5"를 표시합니다.

다른 사용자 지정 형식 지정자 없이 "h" 형식 지정자를 사용하면 표준 날짜 및 시간 형식 지정자로 해석되고 식 오류가 throw됩니다. 단일 형식 지정자를 사용하는 방법에 대한 자세한 내용은 이 문서의 뒷부분에 있는 단일 사용자 지정 형식 지정자를 사용하세요.

다음 예제에서는 사용자 지정 형식 문자열에 "h" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 1, 1, 18, 9, 1), [Format = "h:m:s.F t", Culture = ""]),
        // Displays 6:9:1 P

        DateTime.ToText(#datetime(2024, 1, 1, 18, 9, 1), [Format = "h:m:s.F t", Culture = "el-GR"]),
        // Displays 6:9:1 μ

        DateTime.ToText(#datetime(2024, 1, 1, 9, 18, 1.500), [Format = "h:m:s.F t", Culture = ""]),
        // Displays 9:18:1.5 A

        DateTime.ToText(#datetime(2024, 1, 1, 9, 18, 1.500), [Format = "h:m:s.F t", Culture = "el-GR"])
        // Displays 9:18:1.5 π
    }
in
    Source

표로 이동

"hh" 사용자 지정 형식 지정자

"hh" 사용자 지정 형식 지정자(추가 "h" 지정자 수 포함)는 시간을 01에서 12까지의 숫자로 나타냅니다. 즉, 시간은 자정 또는 정오 이후의 전체 시간을 계산하는 12시간 시계로 표시됩니다. 자정 이후의 시간과 정오 이후의 같은 시간을 구별할 수 없습니다. 시간은 반올림되지 않으며 한 자리 시간의 서식은 선행 0으로 지정됩니다. 예를 들어, 시간이 오전 또는 오후 5:43일 경우 이 형식 지정자는 "05"를 표시합니다.

다음 예제에서는 사용자 지정 형식 문자열에 "hh" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 1, 1, 18, 9, 1), [Format = "hh:mm:ss tt", Culture = ""]),
        // Displays 06:09:01 PM

        DateTime.ToText(#datetime(2024, 1, 1, 18, 9, 1), [Format = "hh:mm:ss tt", Culture = "hu-HU"]),
        // Displays 06:09:01 du.

        DateTime.ToText(#datetime(2024, 1, 1, 9, 18, 1.500), [Format = "hh:mm:ss.ff tt", Culture = ""]),
        // Displays 09:18:01.50 AM

        DateTime.ToText(#datetime(2024, 1, 1, 9, 18, 1.500), [Format = "hh:mm:ss.ff tt", Culture = "hu-HU"])
        // Displays 09:18:01.50 de.
    }
in
    Source

표로 이동

대문자 시간 “H” 형식 지정자

"H" 사용자 지정 형식 지정자

"H" 사용자 지정 형식 지정자는 시간을 0에서 23까지의 숫자로 나타냅니다. 즉, 시간은 자정 이후 시간을 계산하는 0부터 시작하는 24시간 시계로 표시됩니다. 한 자리 시간의 경우 앞에 0이 표시되지 않습니다.

다른 사용자 지정 형식 지정자 없이 "H" 형식 지정자를 사용하면 표준 날짜 및 시간 형식 지정자로 해석되고 식 오류가 throw됩니다. 단일 형식 지정자를 사용하는 방법에 대한 자세한 내용은 이 문서의 뒷부분에 있는 단일 사용자 지정 형식 지정자를 사용하세요.

다음 예제에서는 사용자 지정 형식 문자열에 "H" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 1, 1, 6, 9, 1), [Format = "H:mm:ss", Culture = ""])
        // Displays 6:09:01
    }
in
    Source

표로 이동

"HH" 사용자 지정 형식 지정자

"HH" 사용자 지정 형식 지정자(추가 "H" 지정자 수 포함)는 시간을 00에서 23까지의 숫자로 나타냅니다. 즉, 시간은 자정 이후 시간을 계산하는 0부터 시작하는 24시간 시계로 표시됩니다. 한 자리 시간의 경우 앞에 0이 표시됩니다.

다음 예제에서는 사용자 지정 형식 문자열에 "HH" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 1, 1, 6, 9, 1), [Format = "HH:mm:ss", Culture = ""])
        // Displays 06:09:01
    }
in
    Source

표로 이동

표준 시간대 “K” 형식 지정자

"K" 사용자 지정 형식 지정자

"K" 사용자 지정 형식 지정자는 날짜 및 시간 값의 표준 시간대 정보를 나타냅니다. DateTimeZone 값과 함께 이 형식 지정자를 사용하면 결과 문자열이 다음과 같이 정의됩니다.

  • 로컬 표준 시간대의 경우 이 지정자는 쿼리가 파워 쿼리 데스크톱에서 실행되는 경우 UTC(협정 세계시)의 로컬 오프셋을 포함하는 결과 문자열(예: "-07:00")을 생성합니다. 쿼리가 파워 쿼리 Online에서 실행되는 경우 결과 문자열은 UTC 시간(즉, "+00:00")에서 오프셋을 생성하지 않습니다.

  • UTC 시간 동안 결과 문자열은 UTC 시간에서 오프셋을 생성하지 않습니다. 즉, UTC 날짜를 나타내는 "+00:00입니다.

  • 지정되지 않은 표준 시간대의 시간 동안 결과는 비어 있습니다.

다른 사용자 지정 형식 지정자 없이 "K" 형식 지정자를 사용하면 표준 날짜 및 시간 형식 지정자로 해석되고 식 오류가 throw됩니다. 단일 형식 지정자를 사용하는 방법에 대한 자세한 내용은 이 문서의 뒷부분에 있는 단일 사용자 지정 형식 지정자를 사용하세요.

다음 예제에서는 미국 태평양 표준 시간대의 시스템에서 다양한 값과 함께 "K" 사용자 지정 형식 지정자를 사용하여 발생하는 문자열을 표시합니다.

let
    Source =
    {
        DateTimeZone.ToText(DateTimeZone.LocalNow(),[Format="%K"]),
        // Displays -07:00 (Desktop) or +00:00 (Online)

        DateTimeZone.ToText(DateTimeZone.UtcNow(),[Format="%K"]),
        // Displays +00:00

        Text.Format("'#{0}'", {DateTime.ToText(DateTime.LocalNow(),[Format="%K"])})
        // Displays ''
    }
in
    Source

참고 항목

DateTimeZone.LocalNow 반환되는 값은 로컬 컴퓨터에서 파워 쿼리를 실행하는지 아니면 온라인으로 실행 중인지에 따라 달라집니다. 예를 들어 미국 태평양 표준 시간대의 시스템에 대한 위의 샘플에서 파워 쿼리 데스크톱은 로컬 컴퓨터에서 설정된 시간을 읽고 있기 때문에 반환 -07:00 합니다. 그러나 파워 쿼리 온라인은 UTC로 설정된 클라우드 가상 머신의 시간 집합을 읽고 있기 때문에 반환 +00:00 됩니다.

표로 이동

분 “m” 형식 지정자

"m" 사용자 지정 형식 지정자

"m" 사용자 지정 형식 지정자는 분을 0에서 59까지의 숫자로 나타냅니다. 분은 마지막 시간 이후 경과한 총 분 수를 나타냅니다. 한 자리 분의 경우 앞에 0이 표시되지 않습니다.

다른 사용자 지정 형식 지정자 없이 “m” 형식 지정자만 사용되면 “m” 표준 날짜 및 시간 형식 지정자로 해석됩니다. 단일 형식 지정자를 사용하는 방법에 대한 자세한 내용은 이 문서의 뒷부분에 있는 단일 사용자 지정 형식 지정자를 사용하세요.

다음 예제에서는 사용자 지정 형식 문자열에 "m" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 1, 1, 18, 9, 1), [Format = "h:m:s.F t", Culture = ""]),
        // Displays 6:9:1 P

        DateTime.ToText(#datetime(2024, 1, 1, 18, 9, 1), [Format = "h:m:s.F t", Culture = "el-GR"]),
        // Displays 6:9:1 μ

        DateTime.ToText(#datetime(2024, 1, 1, 9, 18, 1.500), [Format = "h:m:s.F t", Culture = ""]),
        // Displays 9:18:1.5 A

        DateTime.ToText(#datetime(2024, 1, 1, 9, 18, 1.500), [Format = "h:m:s.F t", Culture = "el-GR"])
        // Displays 9:18:1.5 π
    }
in
    Source

표로 이동

"mm" 사용자 지정 형식 지정자

"mm" 사용자 지정 형식 지정자(추가 "m" 지정자 수 포함)는 분을 00에서 59까지의 숫자로 나타냅니다. 분은 마지막 시간 이후 경과한 총 분 수를 나타냅니다. 한 자리 분의 경우 앞에 0이 표시됩니다.

다음 예제에서는 사용자 지정 형식 문자열에 "mm" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 1, 1, 18, 9, 1), [Format = "hh:mm:ss tt", Culture = ""]),
        // Displays 06:09:01 PM

        DateTime.ToText(#datetime(2024, 1, 1, 18, 9, 1), [Format = "hh:mm:ss tt", Culture = "hu-HU"]),
        // Displays 06:09:01 du.

        DateTime.ToText(#datetime(2024, 1, 1, 9, 18, 1.500), [Format = "hh:mm:ss.ff tt", Culture = ""]),
        // Displays 09:18:01.50 AM

        DateTime.ToText(#datetime(2024, 1, 1, 9, 18, 1.500), [Format = "hh:mm:ss.ff tt", Culture = "hu-HU"])
        // Displays 09:18:01.50 de.
    }
in
    Source

표로 이동

월 “M” 형식 지정자

"M" 사용자 지정 형식 지정자

"M" 사용자 지정 형식 지정자는 월을 1에서 12(또는 13개월인 달력의 경우 1에서 13까지)의 숫자로 나타냅니다. 한 자리 월의 경우 앞에 0이 표시되지 않습니다.

다른 사용자 지정 형식 지정자 없이 “M” 형식 지정자만 사용되면 “M” 표준 날짜 및 시간 형식 지정자로 해석됩니다. 단일 형식 지정자를 사용하는 방법에 대한 자세한 내용은 이 문서의 뒷부분에 있는 단일 사용자 지정 형식 지정자를 사용하세요.

다음 예제에서는 사용자 지정 형식 문자열에 "M" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        Date.ToText(#date(2024, 8, 18), [Format = "(M) MMM, MMMM", Culture = "en-US"]),
        // Displays (8) Aug, August

        Date.ToText(#date(2024, 8, 18), [Format = "(M) MMM, MMMM", Culture = "nl-NL"]),
        // Displays (8) aug, augustus

        Date.ToText(#date(2024, 8, 18), [Format = "(M) MMM, MMMM", Culture = "lv-LV"])
        // Displays (8) aug., augusts
    }
in
    Source

표로 이동

"MM" 사용자 지정 형식 지정자

"MM" 사용자 지정 형식 지정자는 월을 01에서 12(또는 13개월이 있는 달력의 경우 1에서 13까지)로 나타냅니다. 한 자리 월의 경우 앞에 0이 표시됩니다.

다음 예제에서는 사용자 지정 형식 문자열에 "MM" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 1, 2, 6, 30, 15), [Format = "dd, MM", Culture = ""])
        // Displays 02, 01
    }
in
    Source

표로 이동

"MMM" 사용자 지정 형식 지정자

"MMM" 사용자 지정 형식 지정자는 월의 약식 이름을 나타냅니다. 지역화된 약식 월 이름은 현재 또는 지정된 문화권의 축약된 월 이름에서 검색됩니다. 사용자 지정 형식 문자열에 "d" 또는 "dd" 사용자 지정 형식 지정자가 있는 경우 해당 월 이름은 축약된 genitive 이름에서 대신 검색됩니다.

다음 예제에서는 사용자 지정 형식 문자열에 "MMM" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15), [Format = "ddd d MMM", Culture = "en-US"]),
        // Displays Thu 29 Aug

        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15), [Format = "ddd d MMM", Culture = "fr-FR"])
        // Displays jeu. 29 août
    }
in
    Source

표로 이동

"MMMM" 사용자 지정 형식 지정자

"MMMM" 사용자 지정 형식 지정자는 월의 전체 이름을 나타냅니다. 지역화된 월 이름은 현재 또는 지정된 문화권에서 검색됩니다. 사용자 지정 형식 문자열에 "d" 또는 "dd" 사용자 지정 형식 지정자가 있는 경우 해당 월 이름은 축약된 genitive 이름에서 대신 검색됩니다.

다음 예제에서는 사용자 지정 형식 문자열에 "MMMM" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15), [Format = "dddd dd MMMM", Culture = "en-US"]),
        // Displays Thursday 29 August

        DateTime.ToText(#datetime(2024, 8, 29, 19, 27, 15), [Format = "dddd dd MMMM", Culture = "it-IT"])
        // Displays giovedì 29 agosto
    }
in
    Source

표로 이동

초 “s” 형식 지정자

"s" 사용자 지정 형식 지정자

"s" 사용자 지정 형식 지정자는 초를 0에서 59까지의 숫자로 나타냅니다. 결과는 마지막 분 이후 경과한 총 초 수를 나타냅니다. 한 자리 초의 경우 앞에 0이 표시되지 않습니다.

다른 사용자 지정 형식 지정자 없이 “s” 형식 지정자만 사용되면 “s” 표준 날짜 및 시간 형식 지정자로 해석됩니다. 단일 형식 지정자를 사용하는 방법에 대한 자세한 내용은 이 문서의 뒷부분에 있는 단일 사용자 지정 형식 지정자를 사용하세요.

다음 예제에서는 사용자 지정 형식 문자열에 "s" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 1, 1, 18, 9, 1), [Format = "h:m:s.F t", Culture = ""]),
        // Displays 6:9:1 P

        DateTime.ToText(#datetime(2024, 1, 1, 18, 9, 1), [Format = "h:m:s.F t", Culture = "el-GR"]),
        // Displays 6:9:1 μ

        DateTime.ToText(#datetime(2024, 1, 1, 9, 18, 1.500), [Format = "h:m:s.F t", Culture = ""]),
        // Displays 9:18:1.5 A

        DateTime.ToText(#datetime(2024, 1, 1, 9, 18, 1.500), [Format = "h:m:s.F t", Culture = "el-GR"])
        // Displays 9:18:1.5 π
    }
in
    Source

표로 이동

"ss" 사용자 지정 형식 지정자

"ss" 사용자 지정 형식 지정자(추가 "s" 지정자 수 포함)는 초를 00에서 59까지의 숫자로 나타냅니다. 결과는 마지막 분 이후 경과한 총 초 수를 나타냅니다. 한 자리 초의 경우 앞에 0이 표시됩니다.

다음 예제에서는 사용자 지정 형식 문자열에 "ss" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 1, 1, 18, 9, 1), [Format = "hh:mm:ss tt", Culture = ""]),
        // Displays 06:09:01 PM

        DateTime.ToText(#datetime(2024, 1, 1, 18, 9, 1), [Format = "hh:mm:ss tt", Culture = "hu-HU"]),
        // Displays 06:09:01 du.

        DateTime.ToText(#datetime(2024, 1, 1, 9, 18, 1.500), [Format = "hh:mm:ss.ff tt", Culture = ""]),
        // Displays 09:18:01.50 AM

        DateTime.ToText(#datetime(2024, 1, 1, 9, 18, 1.500), [Format = "hh:mm:ss.ff tt", Culture = "hu-HU"])
        // Displays 09:18:01.50 de.
    }
in
    Source

표로 이동

오전/오후 “t” 형식 지정자

"t" 사용자 지정 형식 지정자

"t" 사용자 지정 형식 지정자는 AM/PM 지정자의 첫 문자를 나타냅니다. 적절한 지역화된 지정자는 현재 또는 특정 문화권에서 검색됩니다. AM 지정자는 0:00:00(자정)부터 11:59:59.999까지의 모든 시간에 사용되고 PM 지정자는 12:00:00(정오)부터 23:59:59.999까지의 모든 시간에 사용됩니다.

다른 사용자 지정 형식 지정자 없이 “t” 형식 지정자만 사용되면 “t” 표준 날짜 및 시간 형식 지정자로 해석됩니다. 단일 형식 지정자를 사용하는 방법에 대한 자세한 내용은 이 문서의 뒷부분에 있는 단일 사용자 지정 형식 지정자를 사용하세요.

다음 예제에서는 사용자 지정 형식 문자열에 "t" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 1, 1, 18, 9, 1), [Format = "h:m:s.F t", Culture = ""]),
        // Displays 6:9:1 P

        DateTime.ToText(#datetime(2024, 1, 1, 18, 9, 1), [Format = "h:m:s.F t", Culture = "el-GR"]),
        // Displays 6:9:1 μ

        DateTime.ToText(#datetime(2024, 1, 1, 9, 18, 1.500), [Format = "h:m:s.F t", Culture = ""]),
        // Displays 9:18:1.5 A

        DateTime.ToText(#datetime(2024, 1, 1, 9, 18, 1.500), [Format = "h:m:s.F t", Culture = "el-GR"])
        // Displays 9:18:1.5 π
    }
in
    Source

표로 이동

"tt" 사용자 지정 형식 지정자

"tt" 사용자 지정 형식 지정자는 임의 개수의 추가 "t" 지정자와 함께 전체 AM/PM 지정자를 나타냅니다. 적절한 지역화된 지정자는 현재 또는 특정 문화권에서 검색됩니다. AM 지정자는 0:00:00(자정)부터 11:59:59.999까지의 모든 시간에 사용되고 PM 지정자는 12:00:00(정오)부터 23:59:59.999까지의 모든 시간에 사용됩니다.

“tt” 지정자는 AM과 PM을 구분해야 하는 언어에만 사용해야 합니다. 예를 들어, 일본어 AM/PM 지정자의 경우 첫 번째 문자가 아니라 두 번째 문자가 서로 다릅니다.

다음 예제에서는 사용자 지정 형식 문자열에 "tt" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 1, 1, 18, 9, 1), [Format = "hh:mm:ss tt", Culture = ""]),
        // Displays 06:09:01 PM

        DateTime.ToText(#datetime(2024, 1, 1, 18, 9, 1), [Format = "hh:mm:ss tt", Culture = "hu-HU"]),
        // Displays 06:09:01 du.

        DateTime.ToText(#datetime(2024, 1, 1, 9, 18, 1.500), [Format = "hh:mm:ss.ff tt", Culture = ""]),
        // Displays 09:18:01.50 AM

        DateTime.ToText(#datetime(2024, 1, 1, 9, 18, 1.500), [Format = "hh:mm:ss.ff tt", Culture = "hu-HU"])
        // Displays 09:18:01.50 de.
    }
in
    Source

표로 이동

연도 “y” 형식 지정자

"y" 사용자 지정 형식 지정자

"y" 사용자 지정 형식 지정자는 연도를 한 자리 또는 두 자리 숫자로 나타냅니다. 연도가 두 자리를 넘으면 마지막 두 자리 숫자만 결과에 나타납니다. 2008과 같이 두 자리 연도의 첫 번째 숫자가 0으로 시작하면 앞에 0이 표시되지 않습니다.

다른 사용자 지정 형식 지정자 없이 “y” 형식 지정자만 사용되면 “y” 표준 날짜 및 시간 형식 지정자로 해석됩니다. 단일 형식 지정자를 사용하는 방법에 대한 자세한 내용은 이 문서의 뒷부분에 있는 단일 사용자 지정 형식 지정자를 사용하세요.

다음 예제에서는 사용자 지정 형식 문자열에 "y" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        Date.ToText(#date(1, 12, 1), [Format = "%y"]),
        // Displays 1

        Date.ToText(#date(2024, 1, 1), [Format = "%y"])
        // Displays 24
    }
in
    Source

표로 이동

"yy" 사용자 지정 형식 지정자

"yy" 사용자 지정 형식 지정자는 연도를 두 자리 숫자로 나타냅니다. 연도가 두 자리를 넘으면 마지막 두 자리 숫자만 결과에 나타납니다. 두 자리 연도의 유효 자릿수가 두 자리 미만인 경우 두 자리가 되도록 앞에 0이 채워집니다.

구문 분석 작업에서 "yy" 사용자 지정 형식 지정자를 사용하여 구문 분석되는 두 자리 연도는 형식 공급자의 현재 달력에 따라 해석됩니다. 다음 예제에서는 en-US 문화권(이 경우 현재 문화권)의 기본 양력을 사용하여 두 자리 년도를 갖는 날짜의 문자열 표현을 구문 분석합니다. 4자리 날짜에 대해 반환되는 값은 운영 체제에서 설정한 100년 범위에 따라 달라집니다.

let
    // Define the date format and value
    fmt = "dd-MMM-yy",

    // Convert year 49 to a 4-digit year
    firstDate = Text.Format("#{0}", { Date.FromText("24-Jan-49", [Format = fmt]) }),

    // Convert year 50 to a 4-digit year
    finalDate = Text.Format("#{0}", { Date.FromText("24-Jan-50", [Format = fmt]) }),
    Heading = "Default Two Digit Year Range: 1950 - 2049",
    result = {Heading, firstDate, finalDate}
in
    result

// The example displays the following output:
//       Default Two Digit Year Range: 1950 - 2049
//       1/24/2049
//       1/24/1950

다음 예제에서는 사용자 지정 형식 문자열에 "yy" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        Date.ToText(#date(1, 12, 1), [Format = "yy"]),
        // Displays 01

        Date.ToText(#date(2024, 1, 1), [Format = "yy"])
        // Displays 24
    }
in
    Source

표로 이동

"yyy" 사용자 지정 형식 지정자

"yyy" 사용자 지정 형식 지정자는 연도를 최소 세 자리 숫자로 나타냅니다. 연도의 유효 자릿수가 세 자리보다 많더라도 결과 문자열에 포함됩니다. 연도가 세 자리 미만인 경우 세 자리가 되도록 앞에 0이 채워집니다.

참고 항목

연도를 다섯 자리까지 표시할 수 있는 태국 불교식 달력의 경우 이 형식 지정자는 유효 자릿수를 모두 표시합니다.

다음 예제에서는 사용자 지정 형식 문자열에 "yyy" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        Date.ToText(#date(1, 12, 1), [Format = "yyy"]),
        // Displays 001

        Date.ToText(#date(2024, 1, 1), [Format = "yyy"])
        // Displays 2024
    }
in
    Source

표로 이동

"yyyy" 사용자 지정 형식 지정자

"yyyy" 사용자 지정 형식 지정자는 연도를 최소 네 자리 숫자로 나타냅니다. 연도의 유효 자릿수가 네 자리보다 많더라도 결과 문자열에 포함됩니다. 연도가 네 자리 미만인 경우 네 자리가 되도록 앞에 0이 채워집니다.

참고 항목

연도를 다섯 자리까지 표시할 수 있는 태국 불교식 달력의 경우 이 형식 지정자는 최소 네 자리 숫자를 표시합니다.

다음 예제에서는 사용자 지정 형식 문자열에 "yyyy" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        Date.ToText(#date(1, 12, 1), [Format = "yyyy"]),
        // Displays 0001

        Date.ToText(#date(2024, 1, 1), [Format = "yyyy"])
        // Displays 2024
    }
in
    Source

표로 이동

"yyyyy" 사용자 지정 형식 지정자

"yyyyy" 사용자 지정 형식 지정자는 임의 개수의 추가 "y" 지정자와 함께 연도를 최소 다섯 자리 숫자로 나타냅니다. 연도의 유효 자릿수가 다섯 자리보다 많더라도 결과 문자열에 포함됩니다. 연도가 다섯 자리 미만인 경우 다섯 자리가 되도록 앞에 0이 채워집니다.

추가 "y" 지정자가 있는 경우 "y" 지정자의 수에 맞도록 앞에 0이 필요한 만큼 채워집니다.

다음 예제에서는 사용자 지정 형식 문자열에 "yyyyy" 사용자 지정 형식 지정자를 포함합니다.

let
    Source =
    {
        Date.ToText(#date(1, 12, 1), [Format = "yyyyy"]),
        // Displays 00001

        Date.ToText(#date(2024, 1, 1), [Format = "yyyyy"])
        // Displays 02024
    }
in
    Source

표로 이동

오프셋 “z” 형식 지정자

"z" 사용자 지정 형식 지정자

DateTimeZone 값을 사용하여 "z" 사용자 지정 형식 지정자는 시간 단위로 측정된 UTC(협정 세계시)에서 지정된 표준 시간대의 부호 있는 오프셋을 나타냅니다. 오프셋은 항상 앞에 부호가 표시됩니다. 더하기 기호(+)는 UTC보다 앞선 시간을 나타내고 빼기 기호(-)는 UTC보다 늦은 시간을 나타냅니다. 한 자리 오프셋은 선행 0 없이 서식이 지정됩니다.

다음 표에서는 DateTimeZone 함수에 따라 오프셋 값이 어떻게 변경되는지 보여줍니다.

DateTimeZone 값 오프셋 값
DateTimeZone.LocalNow 파워 쿼리 데스크톱에서 UTC에서 로컬 운영 체제 표준 시간대의 서명된 오프셋입니다. 파워 쿼리 Online에서 +00.
DateTimeZone.UtcNow +0을(를) 반환합니다.

다른 사용자 지정 형식 지정자 없이 "z" 형식 지정자를 사용하면 표준 날짜 및 시간 형식 지정자로 해석되고 식 오류가 발생합니다. 단일 형식 지정자를 사용하는 방법에 대한 자세한 내용은 이 문서의 뒷부분에 있는 단일 사용자 지정 형식 지정자를 사용하세요.

다음 예제에서는 미국 태평양 표준 시간대의 시스템에서 사용자 지정 형식 문자열에 "z" 사용자 지정 형식 지정자를 포함합니다.

let
    Source = 
    {
        DateTimeZone.ToText(DateTimeZone.LocalNow(), [Format="{0:%z}"]),
        // Displays {0:-7} on Power Query Desktop
        // Displays {0:+0} on Power Query Online

        DateTimeZone.ToText(DateTimeZone.UtcNow(),[Format="{0:%z}"]),
        // Displays {0:+0}

        DateTimeZone.ToText(DateTimeZone.SwitchZone(
            #datetimezone(2024, 8, 1, 0, 0, 0, 0, 0), 6), 
            [Format = "{0:%z}"]
        )
        // Displays {0:+6}
    }
in
    Source

참고 항목

DateTimeZone.LocalNow 반환되는 값은 로컬 컴퓨터에서 파워 쿼리를 실행하는지 아니면 온라인으로 실행 중인지에 따라 달라집니다. 예를 들어 미국 태평양 표준 시간대의 시스템에 대한 위의 샘플에서 파워 쿼리 데스크톱은 로컬 컴퓨터에서 설정된 시간을 읽고 있기 때문에 반환 {0:-7} 합니다. 그러나 파워 쿼리 온라인은 UTC로 설정된 클라우드 가상 머신의 시간 집합을 읽고 있기 때문에 반환 {0:+0} 됩니다.

표로 이동

"zz" 사용자 지정 형식 지정자

DateTimeZone 값을 사용하여 "zz" 사용자 지정 형식 지정자는 시간 단위로 측정된 UTC에서 지정된 표준 시간대의 서명된 오프셋을 나타냅니다. 오프셋은 항상 앞에 부호가 표시됩니다. 더하기 기호(+)는 UTC보다 앞선 시간을 나타내고 빼기 기호(-)는 UTC보다 늦은 시간을 나타냅니다. 한 자리 오프셋은 앞에 오는 0으로 서식이 지정됩니다.

다음 표에서는 DateTimeZone 함수에 따라 오프셋 값이 어떻게 변경되는지 보여줍니다.

DateTimeZone 값 오프셋 값
DateTimeZone.LocalNow 파워 쿼리 데스크톱에서 UTC에서 로컬 운영 체제 표준 시간대의 서명된 오프셋입니다. 파워 쿼리 Online에서 +00.
DateTimeZone.UtcNow +00을(를) 반환합니다.

다음 예제에서는 미국 태평양 표준 시간대에 있는 시스템의 사용자 지정 형식 문자열에 "zz" 사용자 지정 형식 지정자를 포함합니다.

let
    Source = 
    {
        DateTimeZone.ToText(DateTimeZone.LocalNow(), [Format="{0:zz}"]),
        // Displays {0:-07} on Power Query Desktop
        // Displays {0:+00} on Power Query Online

        DateTimeZone.ToText(DateTimeZone.UtcNow(),[Format="{0:zz}"]),
        // Displays {0:+00}

        DateTimeZone.ToText(DateTimeZone.SwitchZone(
            #datetimezone(2024, 8, 1, 0, 0, 0, 0, 0), 6), 
            [Format = "{0:zz}"]
        )
        // Displays {0:+06}
    }
in
    Source

참고 항목

DateTimeZone.LocalNow 반환되는 값은 로컬 컴퓨터에서 파워 쿼리를 실행하는지 아니면 온라인으로 실행 중인지에 따라 달라집니다. 예를 들어 미국 태평양 표준 시간대의 시스템에 대한 위의 샘플에서 파워 쿼리 데스크톱은 로컬 컴퓨터에서 설정된 시간을 읽고 있기 때문에 반환 {0:-07} 합니다. 그러나 파워 쿼리 온라인은 UTC로 설정된 클라우드 가상 머신의 시간 집합을 읽고 있기 때문에 반환 {0:+00} 됩니다.

표로 이동

"zzz" 사용자 지정 형식 지정자

DateTimeZone 값을 사용하여 "zzz" 사용자 지정 형식 지정자는 시간 및 분 단위로 측정된 UTC에서 지정된 표준 시간대의 부호 있는 오프셋을 나타냅니다. 오프셋은 항상 앞에 부호가 표시됩니다. 더하기 기호(+)는 UTC보다 앞선 시간을 나타내고 빼기 기호(-)는 UTC보다 늦은 시간을 나타냅니다. 한 자리 오프셋의 경우 앞에 0이 표시됩니다.

다음 표에서는 DateTimeZone 함수에 따라 오프셋 값이 어떻게 변경되는지 보여줍니다.

DateTimeZoneValue 값 오프셋 값
DateTimeZone.LocalNow 파워 쿼리 데스크톱에서 UTC에서 로컬 운영 체제 표준 시간대의 서명된 오프셋입니다. 파워 쿼리 Online에서 +00.
DateTimeZone.UtcNow +00:00을(를) 반환합니다.

다음 예제에서는 미국 태평양 표준 시간대의 시스템에서 사용자 지정 형식 문자열에 "zzz" 사용자 지정 형식 지정자를 포함합니다.

let
    Source = 
    {
        DateTimeZone.ToText(DateTimeZone.LocalNow(), [Format="{0:zzz}"]),
        // Displays {0:-07:00} on Power Query Desktop
        // Displays {0:+00:00} on Power Query Online

        DateTimeZone.ToText(DateTimeZone.UtcNow(),[Format="{0:zzz}"]),
        // Displays {0:+00:00}

        DateTimeZone.ToText(DateTimeZone.SwitchZone(
            #datetimezone(2024, 8, 1, 0, 0, 0, 0, 0), 6), 
            [Format = "{0:zzz}"]
        )
        // Displays {0:+06:00}
    }
in
    Source

참고 항목

DateTimeZone.LocalNow 반환되는 값은 로컬 컴퓨터에서 파워 쿼리를 실행하는지 아니면 온라인으로 실행 중인지에 따라 달라집니다. 예를 들어 미국 태평양 표준 시간대의 시스템에 대한 위의 샘플에서 파워 쿼리 데스크톱은 로컬 컴퓨터에서 설정된 시간을 읽고 있기 때문에 반환 {0:-07:00} 합니다. 그러나 파워 쿼리 온라인은 UTC로 설정된 클라우드 가상 머신의 시간 집합을 읽고 있기 때문에 반환 {0:+00:00} 됩니다.

표로 이동

날짜 및 시간 구분 기호 지정자

":" 사용자 지정 형식 지정자

":" 사용자 지정 형식 지정자는 시, 분, 초를 구분하는 데 사용되는 시간 구분 기호를 나타냅니다. 적절한 지역화된 시간 구분 기호는 현재 또는 지정된 문화권에서 검색됩니다.

참고 항목

특정 날짜 및 시간 문자열의 시간 구분 기호를 변경하려면 리터럴 문자열 구분 기호 내에서 구분 기호 문자를 지정합니다. 예를 들어 사용자 지정 형식 문자열 hh_dd_ss는 "_"(밑줄)이 항상 시간 구분 기호로 사용되는 결과 문자열을 생성합니다.

다른 사용자 지정 서식 지정자 없이 ":" 형식 지정자를 사용하면 표준 날짜 및 시간 형식 지정자로 해석되고 식 오류가 throw됩니다. 단일 형식 지정자를 사용하는 방법에 대한 자세한 내용은 이 문서의 뒷부분에 있는 단일 사용자 지정 형식 지정자를 사용하세요.

표로 이동

"/" 사용자 지정 형식 지정자

"/" 사용자 지정 형식 지정자는 년, 월, 일을 구분하는 데 사용되는 날짜 구분 기호를 나타냅니다. 적절한 지역화된 날짜 구분 기호는 현재 또는 지정된 문화권에서 검색됩니다.

참고 항목

특정 날짜 및 시간 문자열의 날짜 구분 기호를 변경하려면 리터럴 문자열 구분 기호 내에서 구분 기호 문자를 지정합니다. 예를 들어 사용자 지정 형식 문자열 mm/dd/yyyy는 "/"를 항상 날짜 구분 기호로 사용하는 결과 문자열을 생성합니다.

다른 사용자 지정 형식 지정자 없이 "/" 형식 지정자를 사용하면 표준 날짜 및 시간 형식 지정자로 해석되고 식 오류가 throw됩니다. 단일 형식 지정자를 사용하는 방법에 대한 자세한 내용은 이 문서의 뒷부분에 있는 단일 사용자 지정 형식 지정자를 사용하세요.

표로 이동

문자 리터럴

사용자 지정 날짜 및 시간 형식 문자열에서 다음 문자는 예약되었으며 항상 형식 지정 문자 또는 ", ', / 및 \의 경우 특수 문자로 해석됩니다.

  • F
  • H
  • K
  • M
  • d
  • f
  • g
  • h
  • m
  • s
  • t
  • y
  • z
  • %
  • :
  • /
  • "
  • '
  • \

다른 모든 문자는 항상 문자 리터럴로 해석되며, 형식 지정 작업에서 변경되지 않고 결과 문자열에 포함됩니다. 구문 분석 작업에서는 입력 문자열의 문자와 정확히 일치해야 하며, 비교 시 대/소문자를 구분합니다.

다음 예제에는 형식 문자열에서 현지 표준 시간대를 나타내는 리터럴 문자 "PST"(태평양 표준시) 및 "PDT"(태평양 일광 절약 시간)가 포함되어 있습니다. 문자열이 결과 문자열에 포함되고, 현지 표준 시간대 문자열을 포함하는 문자열도 성공적으로 구문 분석되는 것을 확인합니다.

let
    #"Date Formats" = {"dd MMM yyyy hh:mm tt PST", "dd MMM yyyy hh:mm tt PDT"},
    Source = 
    {
        DateTime.ToText(#datetime(2024, 8, 18, 16, 50, 0), [Format = #"Date Formats"{1}]),
        try DateTime.ToText(DateTime.FromText(
            "25 Dec 2023 12:00 pm PST", [Format = #"Date Formats"{0}])) 
            otherwise "Unable to parse '" & "25 Dec 2023 12:00 pm PST" & "'"
    }
in
    Source

// The example displays the following output text:
//       18 Aug 2024 04:50 PM PDT
//       12/25/2023 12:00:00 PM

문자가 결과 문자열에 포함되거나 입력 문자열에서 성공적으로 구문 분석될 수 있도록 하기 위해 문자를 예약 문자가 아니라 리터럴 문자로 해석되도록 지정하는 두 가지 방법이 있습니다.

  • 각 예약된 문자를 이스케이프합니다. 자세한 내용은 이스케이프 시퀀스 사용으로 이동합니다.

    다음 예제에는 형식 문자열에서 현지 표준 시간대를 나타내는 리터럴 문자 "pst"(태평양 표준시)가 포함되어 있습니다. "s"와 "t"는 둘 다 사용자 지정 형식 문자열이므로 두 문자를 문자 리터럴로 해석되도록 이스케이프해야 합니다.

    let
      #"Date Format" = "dd MMM yyyy hh:mm tt p's''t'",
      Source = 
      {
          DateTime.ToText(#datetime(2024, 8, 18, 16, 50, 0), [Format = #"Date Format"]),
          try DateTime.ToText(DateTime.FromText(
              "25 Dec 2023 12:00 pm pst", [Format = #"Date Format"]))
              otherwise "Unable to parse '" & "25 Dec 2023 12:00 pm pst" & "'"
      }
in
      Source

// The example displays the following output text:
//       18 Aug 2024 04:50 PM pst
//       12/25/2016 12:00:00 PM

  • 전체 리터럴 문자열을 아포스트로피로 묶습니다. 다음 예제는 "pst"를 아포스트로피로 묶어 구분된 전체 문자열을 문자 리터럴로 해석해야 함을 나타내는 것을 제외하고 이전 예제와 같습니다.

    let
      #"Date Format" = "dd MMM yyyy hh:mm tt 'pst'",
      Source = 
      {
          DateTime.ToText(#datetime(2024, 8, 18, 16, 50, 0), [Format = #"Date Format"]),
          try DateTime.ToText(DateTime.FromText(
              "25 Dec 2023 12:00 pm pst", [Format = #"Date Format"]))
              otherwise "Unable to parse '" & "25 Dec 2023 12:00 pm pst" & "'"
      }
in
      Source

// The example displays the following output text:
//       18 Aug 2024 04:50 PM pst
//       12/25/2016 12:00:00 PM

주의

단일 사용자 지정 형식 지정자 사용

사용자 지정 날짜 및 시간 형식 문자열은 둘 이상의 문자로 구성됩니다. 날짜 및 시간 형식 지정 메서드는 단일 문자 문자열을 표준 날짜 및 시간 형식 문자열로 해석합니다. 문자를 유효한 형식 지정자로 인식하지 못하면 식 오류가 발생합니다. 예를 들어, "h" 지정자로만 구성된 형식 문자열은 표준 날짜 및 시간 형식 문자열로 해석됩니다. 그러나 이 경우 "h" 표준 날짜 및 시간 형식 지정자가 없으므로 예외가 throw됩니다.

사용자 지정 날짜 및 시간 형식 지정자 중 하나를 형식 문자열의 유일한 지정자로 사용하려면(즉, "d", "f", "F", "g", "h", "H", "K", "m", "M", "s", "t", "y", "z", ":" 또는 "/" 사용자 지정 형식 지정자를 단독으로 사용하려면) 지정자 앞이나 뒤에 공백을 포함하거나 단일 사용자 지정 날짜 및 시간 지정자 앞에 백분율("%") 형식 지정자를 포함합니다.

예를 들어 "%h"는 현재 날짜 및 시간 값이 나타내는 시간을 표시하는 사용자 지정 날짜 및 시간 형식 문자열로 해석됩니다. 결과 문자열에 시간 외에 공백이 포함되기는 하지만 " h" 또는 "h " 형식 지정자를 사용할 수도 있습니다. 다음 예제에서는 이러한 세 가지 형식 문자열을 보여 줍니다.

let
    date = #datetime(2024, 6, 15, 13, 45, 0),
    Source =
    {
        Text.Format("'#{0}'", {DateTime.ToText(date, [Format = "%h"])}),
        Text.Format("'#{0}'", {DateTime.ToText(date, [Format = " h"])}),
        Text.Format("'#{0}'", {DateTime.ToText(date, [Format = "h "])})
    }
in
    Source

// The example displays a list with the following output text, 
//   with <sp> representing a space:
//       '1'
//       ' 1'
//       '1 '

이스케이프 시퀀스 사용

형식 문자열의 "d", "f", "F", "g", "h", "H", "K", "m", "M", "s", "t", "y", "z", ":" 또는 "/" 문자는 리터럴 문자가 아닌 사용자 지정 형식 지정자로 해석됩니다.

문자가 형식 지정자로 해석되지 않도록 하려면 다음을 수행할 수 있습니다.

  • 백슬래시 앞에 섰습니다.
  • 작은따옴표로 묶습니다.
  • 두 개의 큰따옴표로 묶습니다.

이러한 각 문자는 이스케이프 시퀀스 역할을 합니다. 이스케이프 시퀀스는 다음 문자 또는 묶은 문자가 변경되지 않은 결과 문자열에 포함되어야 하는 텍스트 리터럴임을 나타냅니다.

결과 문자열에 큰따옴표를 포함하려면 다른 큰따옴표("")로 이스케이프해야 합니다.

다음 예제에서는 다른 이스케이프 시퀀스를 사용하여 서식 지정 작업이 "h" 및 "m" 문자를 형식 지정자로 해석하지 못하도록 합니다.

let
    date = #datetime(2024, 6, 15, 13, 45, 30.90),
    format1 = "h \h m \m",
    format2 = "h ""h"" m ""m""",
    format3 = "h 'h' m 'm'",
    Source = 
    {
        Text.Format("#{0} (#{1}) -> #{2}", {DateTime.ToText(date), format1, DateTime.ToText(date, format1)}),
        Text.Format("#{0} (#{1}) -> #{2}", {DateTime.ToText(date), format2, DateTime.ToText(date, format2)}),
        Text.Format("#{0} (#{1}) -> #{2}", {DateTime.ToText(date), format3, DateTime.ToText(date, format3)})
    }
in
    Source

// The example displays the following output text:
//       6/15/2024 1:45:30 PM (h \h m \m) -> 1 h 45 m
//       6/15/2024 1:45:30 PM (h "h" m "m") -> 1 h 45 m
//       6/15/2024 1:45:30 PM (h 'h' m 'm') -> 1 h 45 m

관련 콘텐츠