표준 날짜 및 시간 형식 문자열

표준 날짜 및 시간 형식 문자열은 단일 문자를 형식 지정자로 사용하여 시간 및 날짜 값의 텍스트 표현을 정의합니다. 공백을 포함하여 문자를 둘 이상 포함하는 날짜 및 시간 서식은 사용자 지정 날짜 및 시간 서식 문자열로 해석됩니다. 표준 또는 사용자 지정 서식 문자열을 사용하여 서식 작업에서 발생하는 텍스트 표현을 정의할 수 있습니다.

서식 지정자 테이블

다음 표에서는 표준 날짜 및 시간 서식 지정자에 대해 설명합니다.

표준 서식 문자열의 작동 방법

서식 지정 작업에서 표준 서식 문자열은 단순히 사용자 지정 서식 문자열에 대한 별칭입니다. 별칭을 사용하여 사용자 지정 서식 문자열을 참조할 경우 별칭은 변하지 않지만 사용자 지정 서식 문자열 자체는 변경될 수 있다는 장점이 있습니다. 이는 날짜 및 시간 값에 대한 문자열 표현이 일반적으로 문화권마다 다르다는 점을 감안했을 때 매우 중요한 기능입니다. 예를 들어, "d" 표준 서식 문자열은 날짜 및 시간 값을 간단한 날짜 패턴을 사용하여 표시함을 나타냅니다. 고정 문화권의 경우 이 패턴이 "MM/dd/yyyy"이고 fr-FR 문화권의 경우 "dd/MM/yyyy"이며 ja-JP 문화권의 경우 "yyyy/MM/dd"입니다.

서식 지정 작업에서 표준 서식 문자열이 특정 문화권의 사용자 지정 서식 문자열에 매핑되는 경우 애플리케이션에서는 다음 방법 중 하나로 사용할 사용자 지정 서식 문자열이 포함된 특정 문화권을 정의할 수 있습니다.

• 기본 또는 현재 문화권을 사용할 수 있습니다. 다음 예제에서는 현재 문화권의 간단한 날짜 서식을 사용하여 날짜를 표시합니다. 이 예제의 경우 현재 문화권이 en-US입니다.

  let
      Source =
      {
          Date.ToText(#date(2024, 3, 15), [Format = "d"])
          //Displays 3/15/2024
      }
  in
      Source
  

• 특정 문화권의 규칙에 따라 날짜 형식을 지정하는 데 사용되는 문화권을 전달할 수 있습니다. 다음 예제에서는 pt-BR 문화권의 간단한 날짜 서식을 사용하여 날짜를 표시합니다.

  let
      Source =
      {
          Date.ToText(#date(2024, 3, 15), [Format = "d", Culture = "pt-BR"])
          //Displays 15/03/2024
     }
  in
      Source
  

표준 서식 문자열을 보다 긴 고정 사용자 지정 서식 문자열에 대한 약식 표현으로 사용하는 경우도 있습니다. 표준 서식 문자열은 "O"(또는 "o"), "R"(또는 "r"), "s" 및 "u"라는 네 범주로 나뉩니다. 이 문자열은 고정 문화권에 정의된 사용자 지정 서식 문자열에 대응되며, 문화권마다 동일하게 인식되는 날짜 및 시간 값에 대한 문자열 표현을 생성합니다. 다음 표에서는 이러한 네 가지 표준 날짜 및 시간 서식 문자열에 대해 설명합니다.

또한 구문 분석 작업에 표준 형식 문자열을 사용할 수 있습니다. 구문 분석 작업이 성공하려면 입력 문자열이 특정 패턴을 정확하게 준수해야 합니다. 많은 표준 서식 문자열이 여러 사용자 지정 형식 문자열에 매핑되므로 날짜 및 시간 값을 다양한 형식으로 나타낼 수 있으며 구문 분석 작업은 여전히 성공합니다.

다음 섹션에서는 Date, DateTime, DateTimeZone 및 시간 값에 대한 표준 형식 지정자에 대해 설명합니다.

날짜 서식

이 그룹에는 다음 서식이 포함됩니다.

• 간단한 날짜("d") 서식 지정자
• 자세한 날짜("D") 서식 지정자

간단한 날짜("d") 서식 지정자

"d" 표준 형식 지정자는 특정 문화권에서 정의한 사용자 지정 날짜 형식을 나타냅니다. 예를 들어 고정 문화권에서 반환된 사용자 지정 서식 텍스트는 "MM/dd/yyyy"입니다.

다음 예제에서는 "d" 형식 지정자를 사용하여 날짜 값을 표시합니다.

let
    Source =
    {
        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = ""]),
        // Displays 04/10/2024

        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = "en-US"]),
        // Displays 4/10/2024

        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = "en-NZ"]),
        // Displays 10/4/2024

        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = "de-DE"])
        // Displays 10.4.2024
    }
in
    Source

표로 이동

자세한 날짜("D") 서식 지정자

"D" 표준 형식 지정자는 특정 문화권에서 정의한 사용자 지정 날짜 형식을 나타냅니다. 예를 들어, 고정 문화권에 대한 사용자 지정 서식 문자열은 "dddd, dd MMMM yyyy"입니다.

다음 예제에서는 "D" 서식 지정자를 사용하여 날짜 및 시간 값을 표시합니다.

let
    Source =
    {
        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = ""]),
        // Displays Wednesday, 10 April, 2024

        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = "en-US"]),
        // Displays Wednesday, April 10, 2024

        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = "pt-BR"]),
        // Displays quarta-feira, 10 de abril de 2024

        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = "es-MX"])
        // Displays miércoles, 10 de abril de 2024
    }
in
    Source

표로 이동

날짜 및 시간 형식

이 그룹에는 다음 서식이 포함됩니다.

• 전체 날짜 간단한 시간("f") 서식 지정자
• 전체 날짜 자세한 시간("F") 서식 지정자
• 일반 날짜 간단한 시간("g") 서식 지정자
• 일반 날짜 자세한 시간("G") 서식 지정자
• 왕복("O", "o") 서식 지정자
• RFC1123("R", "r") 서식 지정자
• 정렬 가능한("s") 서식 지정자
• 정렬 가능한 유니버설("u") 서식 지정자

전체 날짜 간단한 시간("f") 서식 지정자

"f" 표준 서식 지정자는 공백으로 구분된 자세한 날짜("D")와 간단한 시간("t") 패턴의 조합입니다.

결과 문자열은 특정 문화권의 서식 지정 정보의 영향을 받습니다.

다음 예제에서는 "f" 서식 지정자를 사용하여 날짜 및 시간 값을 표시합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "f", Culture = "en-US"]),
        // Displays Wednesday, April 10, 2024 6:30 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "f", Culture = "fr-FR"])
        // Displays mercredi 10 avril 2024 06:30
    }
in
    Source

표로 이동

전체 날짜 자세한 시간("F") 서식 지정자

"F" 표준 형식 지정자는 특정 문화권에서 정의한 사용자 지정 날짜 및 시간 형식을 나타냅니다. 예를 들어, 고정 문화권에 대한 사용자 지정 서식 문자열은 "dddd, dd MMMM yyyy HH:mm:ss"입니다.

결과 문자열은 특정 문화권의 서식 지정 정보의 영향을 받습니다.

다음 예제에서는 "F" 서식 지정자를 사용하여 날짜 및 시간 값을 표시합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "F", Culture = ""]),
        // Displays Wednesday, 10 April, 2024 06:30:00

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "F", Culture = "en-US"]),
        // Displays Wednesday, April 10, 2024 6:30:00 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "F", Culture = "fr-FR"])
        // Displays mercredi 10 avril 2024 06:30:00
    }
in
    Source

표로 이동

일반 날짜 간단한 시간("g") 서식 지정자

"g" 표준 서식 지정자는 공백으로 구분된 간단한 날짜("d")와 간단한 시간("t") 패턴의 조합입니다. 결과 텍스트는 특정 문화권의 서식 지정 정보의 영향을 받습니다.

결과 문자열은 특정 문화권의 서식 지정 정보의 영향을 받습니다.

다음 예제에서는 "g" 서식 지정자를 사용하여 날짜 및 시간 값을 표시합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "g", Culture = ""]),
        // Displays 04/10/2024 06:30

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "g", Culture = "en-US"]),
        // Displays 4/10/2024 6:30 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "g", Culture = "fr-BE"])
        // Displays 10-04-24 06:30
    }
in
    Source

표로 이동

일반 날짜 자세한 시간("G") 서식 지정자

"G" 표준 서식 지정자는 공백으로 구분된 간단한 날짜("d")와 자세한 시간("T") 패턴의 조합입니다. 결과 텍스트는 특정 문화권의 서식 지정 정보의 영향을 받습니다.

결과 문자열은 특정 문화권의 서식 지정 정보의 영향을 받습니다.

다음 예제에서는 "G" 서식 지정자를 사용하여 날짜 및 시간 값을 표시합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "G", Culture = ""]),
        // Displays 04/10/2024 06:30:00

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "G", Culture = "en-US"]),
        // Displays 4/10/2024 6:30:00 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "G", Culture = "nl-BE"])
        // Displays 10/04/2024 6:30:00
    }
in
    Source

표로 이동

왕복("O", "o") 서식 지정자

"O" 또는 "o" 표준 서식 지정자는 표준 시간대 정보를 유지하는 패턴을 사용하여 사용자 지정 날짜 및 시간 서식 문자열을 나타내고 ISO 8601을 준수하는 결과 문자열을 생략합니다. DateTimeZone 값의 경우 이 형식 지정자는 텍스트에서 날짜, 시간 및 표준 시간대 값을 유지하도록 설계되었습니다.

"O" 또는 "o" 표준 형식 지정자는 "yyyy'-'MM'-'dd'T'HH':'mm':'ss'에 해당합니다.' DateTimeZone 값에 대한 fffffffxxx" 사용자 지정 형식 문자열입니다. 이 텍스트에서 하이픈, 콜론 및 문자 "T"와 같은 개별 문자를 구분하는 작은따옴표 쌍은 개별 문자가 변경할 수 없는 리터럴임을 나타냅니다. 아포스트로피는 출력 문자열에 나타나지 않습니다.

"O" 또는 "o" 표준 형식 지정자(및 "yyyy'-'MM'-'dd'T'HH':'mm':'ss'.' fffffffxxx" 사용자 지정 형식)은 ISO 8601이 표준 시간대 정보를 나타내는 방식을 활용하여 DateTimeZone 값을 유지합니다.

• DateTimeZone.ToLocal 날짜 및 시간 값의 표준 시간대 구성 요소는 UTC의 오프셋입니다(예: +01:00, -07:00).

• DateTimeZone.ToUtc 날짜 및 시간 값의 표준 시간대 구성 요소는 +00.00을 사용하여 UTC를 나타냅니다.

"O" 또는 "o" 표준 서식 지정자는 국제 표준을 준수하므로, 이 지정자를 사용하는 서식 지정 또는 구문 분석 작업에서는 항상 고정 문화권 및 양력을 사용합니다.

다음 예제에서는 "o" 형식 지정자를 사용하여 미국 태평양 표준 시간대의 시스템에 일련의 DateTimeZone 값을 표시합니다.

let
    date1 = #datetimezone(2024, 6, 15, 13, 45, 30, 0, 0),
    Source =
    {
        Text.Format("#{0} (Unspecified) --> #{1}", {date1, DateTimeZone.ToText(date1, [Format = "O"])}),
        Text.Format("#{0} (Utc) --> #{1}", {date1, DateTimeZone.ToText(DateTimeZone.ToUtc(date1), [Format = "O"])}),
        Text.Format("#{0} (Local) --> #{1}", {date1, DateTimeZone.ToText(DateTimeZone.ToLocal(date1), [Format = "O"])})
    }
in
    Source

// The example displays the following output:
//    6/15/2024 1:45:30 PM +00:00 (Unspecified) --> 2024-06-15T13:45:30.0000000+00:00
//    6/15/2024 1:45:30 PM +00:00 (Utc) --> 2024-06-15T13:45:30.0000000+00:00
//    6/15/2024 1:45:30 PM +00:00 (Local) --> 2024-06-15T08:45:30.0000000-07:00

다음 예제에서는 "o" 형식 지정자를 사용하여 서식이 지정된 문자열을 만든 다음 날짜 및 시간 구문 분석 루틴을 호출하여 원래 날짜 및 시간 값을 복원합니다.

let
    // Round-trip a local time
    #"Origin Local Date" = DateTimeZone.ToLocal(
        #datetimezone(2024, 4, 10, 6, 30, 0, 0, 0)
    ),
    #"Local Date Text" = DateTimeZone.ToText(
        #"Origin Local Date", [Format = "o"]
    ),
    #"New Local Date" = DateTimeZone.FromText(#"Local Date Text"),
    #"Local Round Trip" = Text.Format(
        "Round-tripped #{0} Local to #{1} Local.", 
        {
            DateTimeZone.ToText(#"Origin Local Date"), 
            DateTimeZone.ToText(#"New Local Date")
        }
    ),

    // Round-trip a UTC time
    #"Origin UTC Date" = DateTimeZone.ToUtc(
        #datetimezone(2024, 4, 12, 9, 30, 0, 0, 0)
    ),
    #"UTC Date Text" = DateTimeZone.ToText(
        #"Origin UTC Date", [Format = "o"]
    ),
    #"New UTC Date" = DateTimeZone.FromText(#"UTC Date Text"),
    #"UTC Round Trip" = Text.Format(
        "Round-tripped #{0} UTC to #{1} UTC.", 
        {
            DateTimeZone.ToText(#"Origin UTC Date"), 
            DateTimeZone.ToText(#"New UTC Date")
        }
    ),

    // Round-trip an 18 hour offset time
    #"Origin Offset Date" = DateTimeZone.ToLocal(
        #datetimezone(2024, 4, 10, 6, 30, 0, 0, 0) + #duration(0, 18, 0, 0)
    ),
    #"Offset Date Text" = DateTimeZone.ToText(
        #"Origin Offset Date", [Format = "o"]
    ),
    #"New Offset Date" = DateTimeZone.FromText(#"Offset Date Text"),
    #"Offset Round Trip" = Text.Format(
        "Round-tripped #{0} to #{1}.", 
        {
            DateTimeZone.ToText(#"Origin Offset Date"), 
            DateTimeZone.ToText(#"New Offset Date")
        }
    ),

    #"Round Trip Results" = 
        {#"Local Round Trip", #"UTC Round Trip", #"Offset Round Trip"}
in
    #"Round Trip Results"

// The example displays the following output in Power Query Desktop:
//    Round-tripped 4/9/2024 11:30:00 PM -07:00 Local to 4/9/2024 11:30:00 PM -07:00 Local.
//    Round-tripped 4/12/2024 9:30:00 AM +00:00 UTC to 4/12/2024 9:30:00 AM +00:00 UTC.
//    Round-tripped 4/10/2024 5:30:00 PM -07:00 to 4/10/2024 5:30:00 PM -07:00.

// The example displays the following output in Power Query Online:
//    Round-tripped 4/10/2024 6:30:00 AM +00:00 Local to 4/10/2024 6:30:00 AM +00:00 Local.
//    Round-tripped 4/12/2024 9:30:00 AM +00:00 UTC to 4/12/2024 9:30:00 AM +00:00 UTC.
//    Round-tripped 4/11/2024 12:30:00 AM +00:00 to 4/11/2024 12:30:00 AM +00:00.

표로 이동

RFC1123("R", "r") 서식 지정자

"R" 또는 "r" 표준 형식 지정자는 특정 문화권에 의해 정의되지 않은 사용자 지정 날짜 및 시간 형식 문자열을 나타냅니다. 사용되는 문화권이나 제공된 형식 공급자에 관계없이 항상 동일합니다. 사용자 지정 서식 문자열은 "ddd, dd MMM yyyy HH':'mm':'ss 'GMT'"입니다. 이 표준 서식 지정자를 사용할 경우 서식 지정 또는 구문 분석 작업에서 항상 고정 문화권이 사용됩니다.

RFC 1123 표준은 시간을 UTC(협정 세계시)로 표현하지만 서식 지정 작업은 서식이 지정된 날짜 및 시간의 값을 수정하지 않습니다. 따라서 서식 지정 작업을 수행하기 전에 DateTimeZone.ToUtc 함수 메서드를 호출하여 DateTime 값을 UTC로 변환해야 합니다.

다음 예제에서는 "r" 형식 지정자를 사용하여 미국 태평양 표준 시간대(UTC 이후 7시간)의 시스템에 시간 및 날짜 값을 표시합니다.

let
    date1 = #datetimezone(2024, 4, 10, 6, 30, 0, -7, 0),
    dateOffset = DateTimeZone.ToUtc(date1),
    Source = 
    {
        DateTimeZone.ToText(date1, [Format = "r"]),
        // Displays Wed, 10 Apr 2024 13:30:00 GMT

        DateTimeZone.ToText(dateOffset, [Format = "r"])
        // Displays Wed, 10 Apr 2024 13:30:00 GMT
    }
in
    Source

표로 이동

정렬 가능한("s") 서식 지정자

"s" 표준 형식 지정자는 정의된 표준(ISO 8601)을 반영하는 사용자 지정 날짜 및 시간 형식 문자열을 나타내며 읽기 전용입니다. 따라서 이 패턴은 사용된 문화권이나 제공된 서식 공급자에 관계없이 항상 같습니다. 사용자 지정 서식 문자열은 "yyyy'-'MM'-'dd'T'HH':'mm':'ss"입니다. "s" 형식 지정자는 날짜 및 시간 값에 따라 오름차순 또는 내림차순으로 일관되게 정렬되는 결과 문자열을 생성하기 위한 것입니다.

이 표준 서식 지정자를 사용할 경우 서식 지정 또는 구문 분석 작업에서 항상 고정 문화권이 사용됩니다.

다음 예제에서는 "s" 형식 지정자를 사용하여 미국 태평양 표준 시간대의 시스템에 날짜 및 시간 값을 표시합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "s", Culture = "en-US"])
        // Displays 2024-04-10T06:30:00
    }
in
    Source

표로 이동

정렬 가능한 유니버설("u") 서식 지정자

"u" 표준 형식 지정자는 사용된 문화권이나 제공된 형식 공급자에 관계없이 항상 동일한 사용자 지정 날짜 및 시간 형식 문자열을 나타냅니다. 사용자 지정 서식 문자열은 "yyyy'-'MM'-'dd HH':'mm':'ss'Z"입니다. 이 패턴은 정의된 표준을 반영하며 해당 속성은 읽기 전용입니다. 이 표준 서식 지정자를 사용할 경우 서식 지정 또는 구문 분석 작업에서 항상 고정 문화권이 사용됩니다.

결과 문자열은 시간을 UTC(협정 세계시)로 표현해야 하지만 서식 지정 작업 중에는 원래 DateTimeZone 값의 변환이 수행되지 않습니다. 따라서 서식을 지정하기 전에 DateTimeZone.ToUtc 함수를 호출하여 DateTimeZone 값을 UTC로 변환해야 합니다.

다음 예제에서는 "u" 서식 지정자를 사용하여 날짜 및 시간 값을 표시합니다.

let
    date1 = #datetimezone(2024, 4, 10, 6, 30, 0, -7, 0),
    dateOffset = DateTimeZone.ToUtc(date1),
    Source =
    {
        DateTimeZone.ToText(dateOffset, [Format = "u"]),
        // Displays 2024-04-10 13:30:00Z
    }
in
    Source

표로 이동

시간 형식

이 그룹에는 다음 서식이 포함됩니다.

• 간단한 시간("t") 서식 지정자
• 자세한 시간("T") 서식 지정자

간단한 시간("t") 서식 지정자

"t" 표준 형식 지정자는 지정된 문화권에 의해 정의된 사용자 지정 날짜 및 시간 형식 문자열을 나타냅니다. 예를 들어, 고정 문화권에 대한 사용자 지정 서식 문자열은 "HH:mm"입니다.

결과 문자열은 특정 문화권의 서식 지정 정보의 영향을 받습니다.

다음 예제에서는 "t" 서식 지정자를 사용하여 날짜 및 시간 값을 표시합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "t", Culture = ""]),
        // Displays 06:30
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "t", Culture = "en-US"]),
        // Displays 6:30 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "t", Culture = "es-ES"])
        // Displays 6:30
    }
in
    Source

표로 이동

자세한 시간("T") 서식 지정자

"T" 표준 형식 지정자는 특정 문화권에 의해 정의된 사용자 지정 날짜 및 시간 형식 문자열을 나타냅니다. 예를 들어, 고정 문화권에 대한 사용자 지정 서식 문자열은 "HH:mm:ss"입니다.

다음 예제에서는 "T" 서식 지정자를 사용하여 날짜 및 시간 값을 표시합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "T", Culture = ""]),
        // Displays 06:30:00
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "T", Culture = "en-US"]),
        // Displays 6:30:00 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "T", Culture = "es-ES"])
        // Displays 6:30:00
    }
in
    Source

표로 이동

부분적 날짜 서식

이 그룹에는 다음 서식이 포함됩니다.

• 월("M", "m") 서식 지정자
• 연도 월("Y", "y") 서식 지정자

월("M", "m") 서식 지정자

"M" 또는 "m" 표준 형식 지정자는 특정 문화권에 의해 정의된 사용자 지정 날짜 및 시간 형식 문자열을 나타냅니다. 예를 들어, 고정 문화권에 대한 사용자 지정 서식 문자열은 "MMMM dd"입니다.

다음 예제에서는 "m" 서식 지정자를 사용하여 날짜 및 시간 값을 표시합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "m", Culture = ""]),
        // Displays April 10
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "m", Culture = "en-US"]),
        // Displays April 10

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "m", Culture = "ms-MY"])
        // Displays 10 April
    }
in
    Source

표로 이동

연도 월("Y", "y") 서식 지정자

"Y" 또는 "y" 표준 형식 지정자는 특정 문화권에 의해 정의된 사용자 지정 날짜 형식 문자열을 나타냅니다. 예를 들어, 고정 문화권에 대한 사용자 지정 서식 문자열은 "yyyy MMMM"입니다.

다음 예제에서는 "y" 서식 지정자를 사용하여 날짜 및 시간 값을 표시합니다.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "Y", Culture = ""]),
        // Displays 2024 April
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "Y", Culture = "en-US"]),
        // Displays April 2024

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "y", Culture = "af-ZA"])
        // Displays April 2024
    }
in
    Source

표로 이동

관련 콘텐츠

• 문화권이 텍스트 서식에 미치는 영향
• Date, Time, DateTime 및 DateTimeZone 형식 변환
• 날짜 함수
• DateTime 함수
• DateTimeZone 함수
• 시간 함수
• 사용자 지정 날짜 및 시간 형식 문자열