materialize()

Aplica-se a: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

Captura o valor de uma expressão tabular durante a execução da consulta para que ela possa ser referenciada várias vezes pela consulta sem recálculo.

Sintaxe

materialize(expressão)

Saiba mais sobre as convenções de sintaxe.

Parâmetros

Comentários

A materialize() função é útil nos seguintes cenários:

• Para acelerar consultas que executam cálculos pesados cujos resultados são usados várias vezes na consulta.
• Para avaliar uma expressão tabular apenas uma vez e usá-la várias vezes em uma consulta. Isso geralmente é necessário se a expressão tabular não for determinística. Por exemplo, se a expressão usar as rand() funções ou .dcount()

Exemplos de melhoria de desempenho de consulta

O exemplo a seguir mostra como materialize() pode ser usado para melhorar o desempenho da consulta. A expressão _detailed_data é definida usando materialize() a função e, portanto, é calculada apenas uma vez.

let _detailed_data = materialize(StormEvents | summarize Events=count() by State, EventType);
_detailed_data
| summarize TotalStateEvents=sum(Events) by State
| join (_detailed_data) on State
| extend EventPercentage = Events*100.0 / TotalStateEvents
| project State, EventType, EventPercentage, Events
| top 10 by EventPercentage

Saída

O exemplo a seguir gera um conjunto de números aleatórios e calcula:

• Quantos valores distintos no conjunto (Dcount)
• Os três principais valores do conjunto
• A soma de todos esses valores no conjunto

Esta operação pode ser feita usando lotes e materializar:

let randomSet = 
    materialize(
        range x from 1 to 3000000 step 1
        | project value = rand(10000000));
randomSet | summarize Dcount=dcount(value);
randomSet | top 3 by value;
randomSet | summarize Sum=sum(value)

Conjunto de resultados 1:

Conjunto de resultados 2:

Conjunto de resultados 3:

Exemplos de uso de materialize()

Para usar a let instrução com um valor que você usa mais de uma vez, use a função materialize(). Tente enviar todos os operadores possíveis que reduzirão o conjunto de dados materializado e ainda manterão a semântica da consulta. Por exemplo, use filtros ou projete apenas colunas necessárias.

    let materializedData = materialize(Table
    | where Timestamp > ago(1d));
    union (materializedData
    | where Text !has "somestring"
    | summarize dcount(Resource1)), (materializedData
    | where Text !has "somestring"
    | summarize dcount(Resource2))

O filtro ativado Text é mútuo e pode ser enviado para a expressão materialize. A consulta só precisa das colunas Timestamp, Text, Resource1e Resource2. Projete essas colunas dentro da expressão materializada.

    let materializedData = materialize(Table
    | where Timestamp > ago(1d)
    | where Text !has "somestring"
    | project Timestamp, Resource1, Resource2, Text);
    union (materializedData
    | summarize dcount(Resource1)), (materializedData
    | summarize dcount(Resource2))

Se os filtros não forem idênticos, como na consulta a seguir:

    let materializedData = materialize(Table
    | where Timestamp > ago(1d));
    union (materializedData
    | where Text has "String1"
    | summarize dcount(Resource1)), (materializedData
    | where Text has "String2"
    | summarize dcount(Resource2))

Quando o filtro combinado reduzir drasticamente o resultado materializado, combine os dois filtros no resultado materializado por uma expressão lógica or , como na consulta a seguir. No entanto, mantenha os filtros em cada trecho de união para preservar a semântica da consulta.

    let materializedData = materialize(Table
    | where Timestamp > ago(1d)
    | where Text has "String1" or Text has "String2"
    | project Timestamp, Resource1, Resource2, Text);
    union (materializedData
    | where Text has "String1"
    | summarize dcount(Resource1)), (materializedData
    | where Text has "String2"
    | summarize dcount(Resource2))