series_decompose_forecast()
Aplica-se a: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel
Faz previsões com base na decomposição da série.
Usa uma expressão que contém uma série (matriz numérica dinâmica) como entrada e prevê os valores dos últimos pontos à direita. Para obter mais informações, consulte series_decompose.
Sintaxe
series_decompose_forecast(Pontos, da série, [ Tendência, de sazonalidade, Seasonality_threshold ])
Saiba mais sobre as convenções de sintaxe.
Parâmetros
| Nome | Digitar | Obrigatória | Descrição |
|---|---|---|---|
| Série | dynamic |
✔️ | Uma matriz de valores numéricos, normalmente a saída resultante de operadores make-series ou make_list . |
| Pontos | int |
✔️ | Especifica o número de pontos no final da série a serem previstos ou previstos. Esses pontos são excluídos do processo de aprendizagem ou regressão. |
| Sazonalidade | int |
Controla a análise sazonal. Os valores possíveis são: - -1: Detectar automaticamente a sazonalidade usando series_periods_detect. Este é o valor padrão.- Período: Um inteiro positivo que especifica o período esperado em número de compartimentos. Por exemplo, se a série estiver em compartimentos, um período semanal será de 1 - h 168 compartimentos.- 0: Sem sazonalidade, então pule a extração deste componente. |
|
| Tendência | string |
Controla a análise de tendências. Os valores possíveis são: - avg: Defina o componente de tendência como average(x). Esse é o padrão.- linefit: Extraia o componente de tendência usando regressão linear.- none: Sem tendência, então pule a extração deste componente. |
|
| Seasonality_threshold | real |
O limite para pontuação de sazonalidade quando Sazonalidade é definido como detecção automática. O limite de pontuação padrão é 0,6. Para obter mais informações, consulte series_periods_detect. |
Devoluções
Uma matriz dinâmica com a série prevista.
Observação
- A matriz dinâmica da série de entrada original deve incluir um número de slots de pontos a serem previstos. A previsão normalmente é feita usando make-series e especificando a hora de término no intervalo que inclui o período de tempo para a previsão.
- A sazonalidade ou a tendência devem ser habilitadas, caso contrário, a função é redundante e apenas retorna uma série cheia de zeros.
Exemplo
No exemplo a seguir, geramos uma série de quatro semanas em um grão por hora, com sazonalidade semanal e uma pequena tendência de alta. Em seguida, usamos make-series e adicionamos outra semana vazia à série. series_decompose_forecast é chamado com uma semana (24 * 7 pontos) e detecta automaticamente a sazonalidade e a tendência e gera uma previsão de todo o período de cinco semanas.
let ts=range t from 1 to 24*7*4 step 1 // generate 4 weeks of hourly data
| extend Timestamp = datetime(2018-03-01 05:00) + 1h * t
| extend y = 2*rand() + iff((t/24)%7>=5, 5.0, 15.0) - (((t%24)/10)*((t%24)/10)) + t/72.0 // generate a series with weekly seasonality and ongoing trend
| extend y=iff(t==150 or t==200 or t==780, y-8.0, y) // add some dip outliers
| extend y=iff(t==300 or t==400 or t==600, y+8.0, y) // add some spike outliers
| make-series y=max(y) on Timestamp from datetime(2018-03-01 05:00) to datetime(2018-03-01 05:00)+24*7*5h step 1h; // create a time series of 5 weeks (last week is empty)
ts
| extend y_forcasted = series_decompose_forecast(y, 24*7) // forecast a week forward
| render timechart
