ButtonDesigner.GetDesignTimeHtml Método

Referência

Definição

Namespace:: System.Web.UI.Design.WebControls

Assembly:: System.Design.dll

Importante

Algumas informações se referem a produtos de pré-lançamento que podem ser substancialmente modificados antes do lançamento. A Microsoft não oferece garantias, expressas ou implícitas, das informações aqui fornecidas.

Obtém a marcação usada para renderizar o controle associado em tempo de design.

public:
 override System::String ^ GetDesignTimeHtml();

public override string GetDesignTimeHtml ();

override this.GetDesignTimeHtml : unit -> string

Public Overrides Function GetDesignTimeHtml () As String

Retornos

String

Um String que contém a marcação usada para renderizar o Button em tempo de design.

Exemplos

O exemplo de código a seguir demonstra como substituir o GetDesignTimeHtml método para alterar a marcação gerada.

Se a BorderStyle propriedade não tiver sido definida anteriormente (ou seja, ela tem o valor do NotSet campo), uma chamada para o método a GetDesignTimeHtml definirá como uma borda tracejada azul com uma largura de três pixels e exibirá essa borda na superfície de design. Se a BorderStyle propriedade tiver sido definida, os valores de propriedade de borda existentes serão exibidos.

Normalmente, o chama seu GetDesignTimeHtml método base, ControlDesigner.GetDesignTimeHtml, que chama o Control.RenderControl método do controle associado para gerar a marcação.

' Create a class that derives from ButtonDesigner
' and displays the custom SampleButton control
' on the design surface.
Imports System.Web.UI.Design
Imports System.Drawing
Imports System.ComponentModel
Imports System.Web.UI.WebControls
Imports System.Web.UI.Design.WebControls

Namespace Examples.AspNet 

    
    Public Class SampleButtonDesigner
        Inherits ButtonDesigner

        ' Override the GetDesignTimeHtml method.
        Public Overrides Function GetDesignTimeHtml() As String

            Dim sampleButton As SampleButton = CType(Component, SampleButton)
            Dim designTimeHtml As String = Nothing

            ' Check the control's BorderStyle property
            ' to conditionally render design-time HTML.
            If (sampleButton.BorderStyle = BorderStyle.NotSet) Then

                ' Create variables to hold current property settings.
                Dim oldBorderStyle As BorderStyle = sampleButton.BorderStyle
                Dim oldBorderWidth As Unit = sampleButton.BorderWidth
                Dim oldBorderColor As Color = sampleButton.BorderColor

                ' Set properties and the design-time HTML.
                Try
                    sampleButton.BorderStyle = BorderStyle.Dashed
                    sampleButton.BorderWidth = Unit.Pixel(3)
                    sampleButton.BorderColor = Color.Blue
                    designTimeHtml = MyBase.GetDesignTimeHtml()

                    ' If an exception occurs, call the GetErrorDesignTimeHtml
                    ' method.
                Catch ex As Exception
                    designTimeHtml = GetErrorDesignTimeHtml(ex)

                    ' Return properties to their original settings.
                Finally
                    sampleButton.BorderStyle = oldBorderStyle
                    sampleButton.BorderWidth = oldBorderWidth
                    sampleButton.BorderColor = oldBorderColor
                End Try

            Else
                designTimeHtml = MyBase.GetDesignTimeHtml()
            End If

            Return designTimeHtml

        End Function

    End Class
End Namespace

Comentários

O GetDesignTimeHtml método substituirá a Text propriedade pela ID propriedade do Button controle se o Text não contiver caracteres exibicionáveis. Em seguida, o GetDesignTimeHtml método chama seu método base, ControlDesigner.GetDesignTimeHtml, que chama o Control.RenderControl método para gerar a marcação.

Notas aos Herdeiros

Se você estiver substituindo o GetDesignTimeHtml() método, normalmente modificará os valores de propriedade selecionados, chamará o método base para gerar a marcação e, em seguida, restaurará as propriedades para seus valores originais.

Aplica-se a

Partilhar via