in 연산자
적용 대상: ✅Microsoft Fabric✅✅
대/소문자를 구분하는 문자열을 사용하여 데이터에 대한 레코드 집합을 필터링합니다.
다음 표에서는 연산자를 비교합니다 in .
| Operator | 설명 | 대/소문자 구분 | 예제(수율 true) |
|---|---|---|---|
in |
요소 중 하나와 같음 | 예 | "abc" in ("123", "345", "abc") |
!in |
어떤 요소와도 같지 않음 | 예 | "bca" !in ("123", "345", "abc") |
in~ |
모든 요소와 같음 | 아니요 | "Abc" in~ ("123", "345", "abc") |
!in~ |
어떤 요소와도 같지 않음 | 아니요 | "bCa" !in~ ("123", "345", "ABC") |
참고 항목
중첩된 배열은 단일 값 목록으로 평면화됩니다. 예를 들어 x in (dynamic([1,[2,3]]))은 x in (1,2,3)이 됩니다.
다른 연산자에 대한 자세한 내용과 쿼리에 가장 적합한 연산자를 확인하려면 데이터 형식 문자열 연산자를 참조하세요.
대/소문자를 구분하지 않는 연산자는 현재 ASCII 텍스트에 대해서만 지원됩니다. ASCII가 아닌 비교의 경우 tolower() 함수를 사용합니다.
성능 팁
참고 항목
128개 이상의 검색어를 사용하는 경우 텍스트 인덱스 조회 최적화가 비활성화되어 쿼리 성능이 저하될 수 있습니다.
참고 항목
성능은 검색 유형 및 데이터 구조에 따라 달라집니다. 모범 사례는 쿼리 모범 사례를 참조 하세요.
구문
T|wherecolin( 식 ...,)
구문 규칙에 대해 자세히 알아봅니다.
매개 변수
| 이름 | Type | 필수 | 설명 |
|---|---|---|---|
| T | string |
✔️ | 필터링할 테이블 형식 입력입니다. |
| col | string |
✔️ | 필터링할 열입니다. |
| expression | 스칼라 또는 테이블 형식 | ✔️ | 검색할 값을 지정하는 식입니다. 각 식은 스칼라 값 또는 값 집합을 생성하는 테이블 형식 식 일 수 있습니다. 테이블 형식 식에 여러 열이 있는 경우 첫 번째 열이 사용됩니다. 검색은 최대 1,000,000개의 고유 값을 고려합니다. |
반품
조건자가 인 true의 행입니다.
예제
스칼라 목록
다음 쿼리는 스칼라 값 목록과 함께 사용하는 in 방법을 보여줍니다.
StormEvents
| where State in ("FLORIDA", "GEORGIA", "NEW YORK")
| count
출력
| Count |
|---|
| 4775 |
동적 배열
다음 쿼리는 동적 배열과 함께 사용하는 in 방법을 보여줍니다.
let states = dynamic(['FLORIDA', 'ATLANTIC SOUTH', 'GEORGIA']);
StormEvents
| where State in (states)
| count
출력
| Count |
|---|
| 3218 |
테이블 형식 식
다음 쿼리는 테이블 형식 식과 함께 사용하는 in 방법을 보여줍니다.
let Top_5_States =
StormEvents
| summarize count() by State
| top 5 by count_;
StormEvents
| where State in (Top_5_States)
| count
인라인 테이블 형식 식 문을 사용하여 동일한 쿼리를 작성할 수 있습니다.
StormEvents
| where State in (
StormEvents
| summarize count() by State
| top 5 by count_
)
| count
출력
| Count |
|---|
| 14242 |
다른 예제를 사용하여 위쪽
다음 예제에서는 번개 이벤트가 있는 상위 5개 주를 식별하고 iff() 함수 및 in 연산자를 사용하여 상태 이름으로 레이블이 지정된 상위 5개 주와 "기타"로 레이블이 지정된 다른 모든 상태로 번개 이벤트를 분류합니다.
let Lightning_By_State = materialize(StormEvents
| summarize lightning_events = countif(EventType == 'Lightning') by State);
let Top_5_States = Lightning_By_State | top 5 by lightning_events | project State;
Lightning_By_State
| extend State = iff(State in (Top_5_States), State, "Other")
| summarize sum(lightning_events) by State
출력
| State(상태) | sum_lightning_events |
|---|---|
| ALABAMA | 29 |
| 위스콘신주 | 31 |
| TEXAS | 55 |
| 플로리다 | 85 |
| 그루지야 | 106 |
| 기타 | 415 |
함수에서 반환된 정적 목록 사용
다음 예제에서는 미리 정의된 흥미로운 상태 목록을 기반으로 StormEvents 테이블의 이벤트를 계산합니다. 흥미로운 상태는 InterestingStates() 함수에 의해 정의됩니다.
StormEvents
| where State in (InterestingStates())
| count
출력
| Count |
|---|
| 4775 |
다음 쿼리는 InterestingStates() 함수에서 흥미로운 것으로 간주되는 상태를 표시합니다.
.show function InterestingStates
출력
| 이름 | 매개 변수 | 본문 | 폴더 | DocString |
|---|---|---|---|---|
| InterestingStates | () | { dynamic(["WASHINGTON", "FLORIDA", "GEORGIA", "NEW YORK"]) } |
관련 콘텐츠
- ~ 연산자
- !in~ 연산자
- !in 연산자
- contains_cs 연산자
- has_cs 연산자